旧式窗体域如何全选后设置

OKJSJSF

batmanbbs 发表于 2023-5-19 11:09
就你的代码应该可以不用重复，但我个人觉得这是养成良好习惯的问题。

比如我上面的提到的查询前执行.C ...

谢谢您耐心指导我，我仍把这代码放在原位，但作为注释备用。

OKJSJSF

基本定稿
Sub 窗体域打印设置()
    Dim i As Byte, ff As FormField
    With ActiveDocument
        If .ProtectionType <> wdNoProtection Then .Unprotect
        On Error Resume Next     '单击关闭、取消按钮或录入超范围数字时不出错，返回对话框重录
        Do
            i = InputBox("下框中可录数字1234与对应的打印效果：" & vbCr & "1  加灰色底纹             2  加下划线、字形加粗" & vbCr & "3  取消前二项设置      4  其它设置", "参数设置", 1)
            If i = 1 Or i = 2 Or i = 3 Or i = 4 Then Exit Do     '如果录入小数，VBA会自动取整，有点不明不白程序就执行了，所以变量类型可以改为占用系统资源更大的小数
        Loop
        Select Case i
            Case 1
                For Each ff In .FormFields
                    With ff.Range
                        .Shading.Texture = wdTexture15Percent
                        .Font.Underline = wdUnderlineNone
                        .Font.Bold = False
                    End With
                Next
            Case 2
                For Each ff In .FormFields
                    With ff.Range
                        .Shading.Texture = wdTextureNone
                        .Font.Underline = wdUnderlineSingle
                        .Font.Bold = True
                    End With
                Next
            Case 3
                For Each ff In .FormFields
                    With ff.Range
                        .Shading.Texture = wdTextureNone     '无底纹
                        .Font.Underline = wdUnderlineNone     '无下划线
                        .Font.Bold = False     '字形常规
                    End With
'                    ff.Range.Select
'                    Selection.ClearFormatting     '删除字符格式与段落格式相当于恢复默认正文样式，不行
'                    Selection.ClearCharacterDirectFormatting    '删除字符格式不会恢复默认字号
                Next
            Case Else
'                .DeleteAllEditableRanges wdEditorEveryone
                Application.ScreenUpdating = False
                For Each ff In .FormFields
                    ff.Range.Select     '当窗体域个数稍多时，一旦采用对象的.select方法，数据刷新明显可见，关闭屏幕刷新后效果稍好点
                    Selection.Range.Editors.Add wdEditorEveryone     '逐个增加用户可编辑区域
                Next
                Application.ScreenUpdating = True
                .SelectAllEditableRanges wdEditorEveryone
                .DeleteAllEditableRanges wdEditorEveryone
                .Application.Dialogs(wdDialogFormatFont).Show     '打开字体设置对话框
                .FormFields(1).Select     '我习惯于执行完毕后定位第一个窗休而不是最后一个。奇怪的是用代码sendkeys "^{home}",true不能返回文档开头，手工快捷键却可以
        End Select
        .Protect Type:=wdAllowOnlyFormFields, NoReset:=True
        MsgBox "执行完毕。"        
    End With
End Sub

OKJSJSF

初次使用WORD宏，发现与EXCEL有点区别。
一、把代码放在快速访问工具栏命令中，最方便，任何文档打开都可享用宏功能。
二、把代码放在选项卡命令中，必须加载后才能享用。这个宏代码先放在空文档中，另存为模板文件，才能被加载。这个加载是加载“模板文档”文件，不象EXCEL是加载“加载宏工作簿”文件。加载时，活动文档不能处于保护状态。所以，我前面的“窗体域打印设置”宏必须完善一下，增加：
if activedocument.formfields.count=0 then
msgbox"本文没有窗体域。"
exit sub
end if
这个问题导致我在加载我的“窗体域打印设置”宏时弄了很多次，无法加载，最后才发现是文档保护的原因造成。文档保护后，开发工具选项卡的模板组中的文档模板按钮变灰色了，无法打开“模板和加载项”对话框。既使采用手工重新选择模板文件加载，单击确定后实际仍无法加载。