请大神指教函数

lisga1103

我有一个表：


代码                 地区                 结果
220000        吉林省        吉林省
220100        长春市        吉林省长春市
220102        南关区        吉林省长春市南关区
220103        宽城区        吉林省长春市宽城区
220104        朝阳区        吉林省长春市朝阳区
220105        二道区        吉林省长春市二道区
220106        绿园区        吉林省长春市绿园区
220112        双阳区        吉林省长春市双阳区
220113        九台区        吉林省长春市九台区
220122        农安县        吉林省长春市农安县
220182        榆树市        吉林省长春市榆树市
220183        德惠市        吉林省长春市德惠市
220184        公主岭市        吉林省长春市公主岭市
A,B两列为已有数据，C列是希望通过函数取得的结果


请大神协助，万分感谢

袁勇

按邮政编码后面2位和后面3位是否全部为0来划分？

lisga1103

袁勇 发表于 2023-5-17 17:43
按邮政编码后面2位和后面3位是否全部为0来划分？

后面三位全部为0的是省

zhaojiaoyang200

抛个砖
=CONCAT(UNIQUE(INDEX(B:B,MATCH(FLOOR(A2,{10000;100;1}),A:A,))))

袁勇

lisga1103 发表于 2023-5-17 17:48
后面三位全部为0的是省

试试：

1. =IF(RIGHT(A2,3)="000",B2,IF(RIGHT(A2,2)="00",LOOKUP(1,0/(RIGHT(A$2:A2,3)="000"),B$2:B2)&B2,LOOKUP(1,0/(RIGHT(A$2:A2,3)="000"),B$2:B2)&LOOKUP(1,0/(RIGHT(A$2:A2,2)="00"),B$2:B2)&B2))

复制代码

静听溪流

=IF(ROUND(A2,-3)=A2,B2,IF(RIGHT(A2,2)="00",VLOOKUP(LEFT(A2,3)*1000,A:B,2,)&B2,VLOOKUP(LEFT(A2,4)*100,A:C,3,)&B2))

my0745

一般来说：前两位是省代码，中间两位是市代码，最后两位是区县代码（但是也有特殊，比如直辖市）
这种情况，可以增加辅助列来实现。

my0745

袁勇 发表于 2023-5-17 17:59
试试：

这个厉害了

1007890405

静听溪流 发表于 2023-5-17 18:01
=IF(ROUND(A2,-3)=A2,B2,IF(RIGHT(A2,2)="00",VLOOKUP(LEFT(A2,3)*1000,A:B,2,)&B2,VLOOKUP(LEFT(A2,4)*100 ...

向老师学习，没想到round还能这么用，但是你这个公式到最后几行的时候会出现错误，麻烦老师完善下，我想学习

丢丢表格

365 高版本的，写成：

=CONCAT(UNIQUE(LOOKUP(TRUNC(A2,-{4;2;0}),A$1:B2)))

低版本的，写成：
=SUBSTITUTE(LOOKUP(TRUNC(A2,-4),A$1:B2)&LOOKUP(TRUNC(A2,-2),A$1:B2),B2,"")&B2