求助大神：如何根据指定列的是或否输出所有结果

chipmunktianqin · 发表于 2023-5-15 12:17

输入几个列的名称，自动显示对应列中数值为“y”的所有结果，不知道怎么描述，请见图：

chipmunktianqin · 发表于 2023-5-15 12:18

chipmunktianqin · 发表于 2023-5-15 12:19

忘了上附件

solextrade · 发表于 2023-5-15 12:37

数组公式，I10右拖下拖
=OFFSET(A$2,SMALL(IF(MMULT(N($E$3:$G$16="y"),TRANSPOSE(COUNTIF($J$6:$K$6,$E$2:$G$2)))=COUNTA($J$6:$K$6),$A$3:$A$16,99),ROW(A1)),)&""

良良 · 发表于 2023-5-15 12:47

=INDEX(A:A,SMALL(IF(MMULT(($E$3:$G$16="y")*COUNTIF($J$6:$K$6,$E$2:$G$2),{1;1;1})=2,ROW($3:$16),4^8),ROW(A1)))

橒♂蝣 · 发表于 2023-5-15 13:28

=FILTER(A3:G16,(XLOOKUP(J6,E2:G2,E3:G16)="y")*(XLOOKUP(K6,E2:G2,E3:G16)="y"))

chipmunktianqin · 发表于 2023-5-15 13:41

solextrade 发表于 2023-5-15 12:37
数组公式，I10右拖下拖
=OFFSET(A$2,SMALL(IF(MMULT(N($E$3:$G$16="y"),TRANSPOSE(COUNTIF($J$6:$K$6,$E$2 ...

是拷到I10里吗？怎么显示#VALUE! ?

chipmunktianqin · 发表于 2023-5-15 13:42

良良发表于 2023-5-15 12:47
=INDEX(A:A,SMALL(IF(MMULT(($E$3:$G$16="y")*COUNTIF($J$6:$K$6,$E$2:$G$2),{1;1;1})=2,ROW($3:$16),4^8), ...

输出的第一行是对的，往下拉就都跟第一行一样，怎么改成可向下填充的呢？

chipmunktianqin · 发表于 2023-5-15 13:42

橒♂蝣发表于 2023-5-15 13:28
=FILTER(A3:G16,(XLOOKUP(J6,E2:G2,E3:G16)="y")*(XLOOKUP(K6,E2:G2,E3:G16)="y"))

这个显示该函数无效？？

橒♂蝣 · 发表于 2023-5-15 13:54

=FILTER(A3:G16,MMULT((FILTER(E3:G16,ISNUMBER(XMATCH(E2:G2,J6:L6)))=G5)*1,SEQUENCE(COUNTA(J6:L6),,1,0))=COUNTA(J6:L6))

		自动登录	找回密码
密码			免费注册

[求助] 求助大神：如何根据指定列的是或否输出所有结果