使用LAMBDA函数简化公式

咔咔乱坠 · 发表于 2023-3-30 16:41

本帖最后由咔咔乱坠于 2023-3-30 22:12 编辑

参考了https://club.excelhome.net/threa ... tml?_dsign=25936d5a
已解决

补充内容 (2023-4-16 23:41):
以测试文件为例，简化前
=IFERROR(IFERROR(IFERROR(IFERROR(VLOOKUP(H6,'1'!$A$1:$B$35,2,0),VLOOKUP(H6,'2'!$A$1:$B$35,2,0)),VLOOKUP(H6,'3'!$A$1:$B$35,2,0)),VLOOKUP(H6,'4'!A1:B35,2,0)),"")

补充内容 (2023-4-16 23:42):
以测试文件为例，超版简化后
=REDUCE(0,
               {"1","2","3","4"},
               LAMBDA(x,y,x+IFERROR(
                                                                  VLOOKUP(H6,...

补充内容 (2023-4-16 23:45):
上次回复有空格，显示不完全，下为超版简化后完整公式
= REDUCE(0, {"1","2","3","4"}, LAMBDA(x, y, x + IFERROR(VLOOKUP(H6, INDIRECT(y & "!A:B"), 2, 0), )))

rakehell78 · 发表于 2023-4-21 16:09

=REDUCE(0,{"1","2","3","4"},LAMBDA(x,y,T(x)&IFERROR(VLOOKUP(H6,INDIRECT(y&"!A:B"),2,0),)))

满坛皆为吾师 · 发表于 2023-4-23 11:18

365何必那么复杂，I6下拉

=VLOOKUP(H6,VSTACK('1:4'!A$1:B$66),2,)

复制代码

满坛皆为吾师 · 发表于 2023-4-23 11:29

LAMBDA

=REDUCE(0,{1,2,3,4},LAMBDA(x,y,x+IFNA(VLOOKUP(H6,INDIRECT(y&"!A:B"),2,),)))

复制代码

=TOCOL(MAP({1,2,3,4},LAMBDA(x,VLOOKUP(H6, INDIRECT(x&"!A:B"),2,))),3)

复制代码

咔咔乱坠 · 发表于 2023-4-23 20:07

满坛皆为吾师发表于 2023-4-23 11:18
365何必那么复杂，I6下拉

竟如此简单，感谢满坛指教，我来仔细研究研究

		自动登录	找回密码
密码			免费注册

[已解决] 使用LAMBDA函数简化公式

评分

评分

评分