两个分类要求怎么统计

准提部林

Sub TEST_A1()
Dim Arr, xD, T$, T1$, T2$, R&, i&, N&
Set xD = CreateObject("Scripting.Dictionary")
Arr = Range([c2], [a65536].End(3))
For i = 2 To UBound(Arr)
    T1 = Arr(i, 1): T2 = Arr(i, 3)
    If T1 = "" Or T2 = "" Then GoTo i01
    T = T1 & "|" & T2:  R = xD(T)
    If R > 0 Then Arr(R, 2) = Arr(R, 2) + Arr(i, 2): GoTo i01
    N = N + 1: R = N + 1: xD(T) = R
    Arr(R, 1) = T1: Arr(R, 3) = T2: Arr(R, 2) = Arr(i, 2)
i01: Next i
[e2].Resize(N + 1, 3) = Arr
End Sub

ω逆鳞々

这是纯数组写法，请参考

笨鸟飞不高

工作簿1.zip (18.87 KB, 下载次数: 10)

2023-3-10 15:16 上传

点击文件名下载附件

xwdljh

Jaofuan 发表于 2023-3-10 12:58

喜欢直接出代码，看着直观，粘贴方便，且没有任何安全忧患，明白做事，清白做人。

洋务德雷

不用字典的普通方法就是透视表

准提部林

不用字典//排序法//上下比對//
<直貼代碼>....就是要經过"大審婆"...從廣州審到杭州...
EH逼得大家去用圖片或只上傳附件~~

Sub TEST_A2()
Dim Arr, Brr, T$, T1$, T2$, TT$, i&, j%, N&
With Range([c2], [a65536].End(3))
     Brr = .Value
     .Sort Key1:=.Item(1), Order1:=xlAscending, _
           Key2:=.Item(3), Order2:=xlAscending, Header:=xlYes
     Arr = .Value
     .Value = Brr
End With
For i = 2 To UBound(Arr)
    T1 = Arr(i, 1): T2 = Arr(i, 3): T = T1 & T2
    If T1 = "" Or T2 = "" Then GoTo i01
    If T <> TT Then
       N = N + 1: TT = T
       For j = 1 To 3: Brr(N + 1, j) = Arr(i, j): Next
    Else
       Brr(N + 1, 2) = Brr(N + 1, 2) + Arr(i, 2): GoTo i01
    End If
i01: Next i
[e2].Resize(N + 1, 3) = Brr
End Sub

准提部林

傳統的迴遊法///

Sub TEST_A3()
Dim Arr, T$, T1$, T2$, TT$, i&, j%, x&, N&
Arr = Range([c2], [a65536].End(3))
For i = 2 To UBound(Arr)
    T1 = Arr(i, 1): T2 = Arr(i, 3): T = T1 & T2
    If T1 = "" Or T2 = "" Then GoTo i01
    If T <> TT Then
       N = N + 1: TT = T
       For j = 1 To 3: Arr(N + 1, j) = Arr(i, j): Next
       For x = i + 1 To UBound(Arr)
           If Arr(x, 1) & Arr(x, 3) = TT Then
              Arr(x, 1) = ""
              Arr(N + 1, 2) = Arr(N + 1, 2) + Arr(x, 2)
           End If
       Next x
    End If
i01: Next i
[e2].Resize(N + 1, 3) = Arr
End Sub

xwdljh

准提部林 发表于 2023-3-11 09:58
不用字典//排序法//上下比對//
....就是要經过"大審婆"...從廣州審到杭州...
EH逼得大家去用圖片或只上傳 ...

写的中规中矩，思路清晰，容易理解，不用字典大概这是最好的了。