请教老师如何将行上下颠倒的问题

wx_22787

各位老师好，请问wps表格有一键上下颠倒的功能吗，例如我想将上面的这张表变成下面的这样：






如果没有一键颠倒功能，我知道可以插入一列添加编号后再降序排序，但问题是每次的行数都不一定，我的目的是录制一个宏，能自动识别出来有多少行数据，然后添加序号再降序排序以达到上下颠倒功能，请问可以怎么操作呢？望老师赐教！！

蓝桥玄霜

建议上传Excel表格附件来说明问题。
没有表格附件的求助帖很少能获得满意的回复。
可以按要求重新赋值给一数组，然后再赋值给单元格。

pc087

Sub test()
    Dim arr(), brr()
    Dim rng As Range
    Set rng = Application.InputBox("请选择区域", Type:=8)
    arr = rng.Value
    ReDim brr(1 To UBound(arr), 1 To UBound(arr, 2))
   
    Dim i%, j%, n%
    For i = UBound(arr) To 1 Step -1 '倒序纵向循环
        n = n + 1
        For j = 1 To UBound(arr, 2) '横向循环
            brr(n, j) = arr(i, j)
        Next
    Next
   
    rng.Cells(1).Resize(UBound(brr), UBound(brr, 2)) = brr
End Sub

gwjkkkkk

应该不难解决，建议楼主上传附件。。。

micch

一次性处理不知道，建议循环一下，当然也可以插入辅助排序后删除辅助

shiruiqiang

直接循环一下就行

chzsh

Sub diandao()
    Dim arr, brr
    Dim x, i
    arr = Sheets(1).UsedRange
    ReDim brr(1 To UBound(arr), 1 To 4)
    For x = UBound(arr) To 1 Step -1
        For i = 1 To 4
            brr(UBound(arr) + 1 - x, i) = arr(x, i)
        Next
    Next
    Sheets(1).[f1].Resize(1000, 4) = ""
    Sheets(1).[f1].Resize(UBound(brr), 4) = brr
End Sub

chzsh

将行上下颠倒

demonimissyou

Sub 顺序()
Dim i, j, k, arr, brr
i = [A65536].End(xlUp).Row
arr = Range("a1:f" & i)
ReDim brr(1 To UBound(arr), 1 To 4)
For j = UBound(arr) To 1 Step -1
For k = 1 To 4
brr(UBound(arr) + 1 - j, k) = arr(j, k)
Next
Next
Range("a1:f" & i).Clear
[a1].Resize(i, 4) = brr

End Sub

wx_22787

pc087 发表于 2023-1-28 18:43
Sub test()
    Dim arr(), brr()
    Dim rng As Range

谢谢老师！