请问怎么把数据去重然后输入到二维数组里面

霍泳康

举个例子，数据是


张三   10
李四   5
张三   10
李四   5

把张三和李四各自的分数都加起来，得出一个二维数组
张三    20
李四    10

582766

字典案例，论坛很多 可以搜一下

tmplinshi

1. Function 二维数组相加去重(arr())
   
2.     Dim resultArr(), i, k, v, d As Object
   
3. 
   
4.     Set d = CreateObject("Scripting.Dictionary")
   
5.     For i = 1 To UBound(arr)
   
6.         k = arr(i, 1)
   
7.         v = arr(i, 2)
   
8.         d(k) = IIf(d.Exists(k), d(k) + v, v)
   
9.     Next
   
10. 
    
11.     ReDim resultArr(1 To d.Count, 1 To 2)
    
12.     i = 0
    
13.     For Each k In d
    
14.         i = i + 1
    
15.         resultArr(i, 1) = k
    
16.         resultArr(i, 2) = d(k)
    
17.     Next
    
18.    
    
19.     二维数组相加去重 = resultArr
    
20. End Function
    
21. 
    
22. Sub test()
    
23.     Dim arr1(), arr2()
    
24.    
    
25.     arr1 = [ {"张三",10; "李四",5; "张三",10; "李四",5} ]
    
26.     arr2 = 二维数组相加去重(arr1)
    
27.    
    
28.     Print2DArray arr1
    
29.     Debug.Print "----------------------"
    
30.     Print2DArray arr2
    
31. End Sub
    
32. 
    
33. Sub Print2DArray(arr())
    
34.     Dim r%, c%, line$
    
35.    
    
36.     If Not IsArray(arr) Then Exit Sub
    
37.    
    
38.     For r = LBound(arr) To UBound(arr)
    
39.         line = ""
    
40.         
    
41.         For c = LBound(arr, 2) To UBound(arr, 2)
    
42.             line = line & vbTab & arr(r, c)
    
43.         Next
    
44.         
    
45.         Debug.Print Mid(line, 2)
    
46.     Next
    
47. End Sub
    

复制代码

东亚五金

Public Sub 条件求和()
Dim Arr, Brr(), d As Object
Set d = CreateObject("Scripting.Dictionary") '引用字典
Arr = Range("A2:B5")
For i = 1 To UBound(Arr)
    s = Arr(i, 1)
    d(s) = d(s) + Arr(i, 2) '字典关键字+数字
Next
ReDim Brr(1 To d.Count, 1 To 2) '重新定义变量
For i = 1 To d.Count  '个数
    Brr(i, 1) = d.Keys()(i - 1)
    Brr(i, 2) = d.items()(i - 1)
Next
End Sub

Learner2022

东亚五金 发表于 2022-12-21 00:18
Public Sub 条件求和()
Dim Arr, Brr(), d As Object
Set d = CreateObject("Scripting.Dictionary") '引 ...

有点没看懂 为什么arr不用加括号但是brr需要

nicleyuan

Learner2022 发表于 2023-1-1 09:25
有点没看懂 为什么arr不用加括号但是brr需要

你把最上面的brr后面的括号拿掉，看结果是不是一样。