从下向上查找最近一组的重复数据并提取下一组数据的个位

yhy95331

有三列数据，每列每个数据都从其上一个数据查找最近的一组重复数据，并从重复数据的下一个数据提取尾数。例如：c35的123向上找到第一个重复的数据C3的123 ，123下一个是234，则Right(Cells(4,3),1)=4,结果分别放在ghi三列[G2].Resize(i,3)，如果没有查到重复数据，则显示空。下面代码只能查询单个数据，多列多循环弄不好，求高手帮忙！

Sub test()

Dim n, t

n = 123

For j = 34 To 3 Step -1

If Cells(j, 3) = n Then

   t = Right(Cells(j + 1, 3), 1)

Cells(35, 7) = t

Exit For

End If

Next

End Sub

准提部林

Sub TEST_A1()
Dim Arr, Brr, xD, i&, j%, T$
[g:i].ClearContents
Set xD = CreateObject("Scripting.Dictionary")
Arr = Range([c1], [e65536].End(3)(2))
ReDim Brr(1 To UBound(Arr) - 1, 1 To 3)
For i = 2 To UBound(Arr) - 1
    For j = 1 To 3
        T = Arr(i, j) & "|" & j
        Brr(i - 1, j) = Right(xD(T), 1)
        xD(T) = Arr(i + 1, j)
    Next j
Next i
[g2].Resize(UBound(Brr), 3) = Brr
End Sub

zxsea_7426

yhy95331

谢谢大师指点

yhy95331

准提部林 发表于 2022-12-9 23:51
Sub TEST_A1()
Dim Arr, Brr, xD, i&, j%, T$
[g:i].ClearContents

T = Arr(i, j) & "|" & j 大师这种用法可解释一下吗

准提部林

yhy95331 发表于 2022-12-10 11:37
T = Arr(i, j) & "|" & j 大师这种用法可解释一下吗

以每列"數字"加上"列號", 做為字典的key
例如, 同行都是123, 123, 123
則分別變成 123|1, 123|2, 123|3
如此涇渭分明, 各列只比對該列上方的數字,
由上而下, 一次循環即可解決~~

gwjkkkkk

Sub TEST1()
    Dim Rng As Range, rngFind As Range
    Dim arr, Brr
   
    Set Rng = [C2].CurrentRegion
    arr = [C2].CurrentRegion
    ReDim Brr(1 To UBound(arr), 1 To UBound(arr, 2))
   
    For i = 1 To UBound(arr, 2)
         For j = UBound(arr) To 2 Step -1
            Set rngFind = Range(Rng.Cells(1, i), Rng.Cells(j - 1, i)).find(arr(j, i), , , 2, , xlPrevious)
            If Not rngFind Is Nothing Then
              Brr(j, i) = Right(rngFind.Offset(1).Value, 1)
            End If
         Next
     Next
        
    Set Rng = Nothing: Set rngFind = Nothing
    [G2].Resize(UBound(Brr), UBound(Brr, 2)) = Brr
    Beep
End Sub

gwjkkkkk

请楼主参考附件。。。

yhy95331

[quote]准提部林 发表于 2022-12-10 11:48
以每列"數字"加上"列號", 做為字典的key
例如, 同行都是123, 123, 123
則分別變成 123|1, 123|2, 123|3 ...[/
谢谢大师，的确很快

yhy95331

三位大师我把代码会在一起，比较了一下，2楼大师速度最快