LEFT JOIN 两个工作簿

xjy426

想问一个思路。ADO可以Left join两个工作簿吗？



假设有这么两个工作簿：
工作簿1=（订单【订单号，客户，品名，数量】，客户要求【客户，包装要求】），文件地址=Path1（包含文件名）
工作簿2=（生产【品名，车台】），文件地址=Path2（包含文件名）

以下代码可以得到 （订单号，品名，包装要求）。
如何得到（订单号，品名，数量，车台，包装要求）？需要定义两个CONN和两个rs，打开后再查询吗？是的话，如何联系两个不同的conn？

    Dim conn As New ADODB.Connection
    Dim rs As New ADODB.Recordset
    Dim txtSql As String
    With conn
        If Application.Version = "11.0" Then
            .Provider = "microsoft.jet.oledb.4.0"
            .ConnectionString = "extended properties=""excel 8.0;HDR=yes;IMEX=1;"";data source=" & path1
        Else
            .Provider = "microsoft.ACE.oledb.12.0"
            .ConnectionString = "extended properties=""excel 12.0;HDR=yes;IMEX=1;"";data source=" & path1
        End If
        .Open
    End With
    txtSql = "SELECT [订单$].[订单号], [订单$].[品名], [客户要求$].[包装要求] "
    txtSql = txtSql & "FROM [订单$] LEFT JOIN [客户要求$] ON [订单$].[客户]=[客户要求$].[客户]"
    rs.Open txtSql, conn, adOpenKeyset, adLockReadOnly
    If rs.EOF Then
        MsgBox "未找到数据", , "提示"
        Exit Sub
    End If

xjy426

补一下SQL语句，应该可以用：

SELECT [订单$].订单号， [订单$].品名， [订单$].数量，[生产$].车台，[客户要求$].包装要求
FROM ([订单$] LEFT JOIN [生产$] ON  [订单$].品名 = [生产$].品名) LEFT JOIN [客户要求$] ON  [订单$].客户 = [客户要求$].客户;

就是不知道ADO应该怎么连接。

支全驰

可以先链接第一个表之后在链接第二个表
类似 select * from table1 left join table2 as tmptable1
然后
select * from tmptable1  left join table3

fzxba

Sub 据想象而写() '
  Dim strFile(1) As String
  strFile(0) = ThisWorkbook.Path & "\工作簿1.xlsx"
  strFile(1) = ThisWorkbook.Path & "\工作簿2.xlsx"
  If Dir(strFile(0)) = "" Or Dir(strFile(1)) = "" Then MsgBox "文件不存在！", 64: Exit Sub
  Dim Conn As New ADODB.Connection, rs As New ADODB.Recordset
  Dim strConn As String, SQL As String, s As String, i As Integer
  s = "Excel 12.0;HDR=Yes;IMEX=1;Database="
  If Application.Version < 12 Then
    s = Replace(s, "12.0", "8.0")
    strConn = "Provider=Microsoft.Jet.OLEDB.4.0;Extended Properties=Excel 8.0;Data Source="
  Else
    strConn = "Provider=Microsoft.ACE.OLEDB.12.0;Extended Properties=Excel 12.0;Data Source="
  End If
  Conn.Open strConn & strFile(0)
  'SELECT [订单$].订单号， [订单$].品名， [订单$].数量，[生产$].车台，[客户要求$].包装要求 FROM ([订单$] LEFT JOIN [生产$] ON  [订单$].品名 = [生产$].品名) LEFT JOIN [客户要求$] ON  [订单$].客户 = [客户要求$].客户
  SQL = "SELECT a.订单号,a.品名,a.数量,b.车台,c.包装要求 FROM ([订单$] a LEFT JOIN [" & s & strFile(1) & "].[生产$] b ON a.品名=b.品名) LEFT JOIN [客户要求$] c ON a.客户=c.客户"
  rs.Open SQL, Conn, adOpenKeyset, adLockOptimistic
  For i = 0 To rs.Fields.Count - 1
    Range("A2").Offset(0, i) = rs.Fields(i).Name
  Next
  Range("A3").CopyFromRecordset rs
  rs.Close
  Set rs = Nothing
  Conn.Close
  Set Conn = Nothing
  Beep
End Sub

fzxba

smsn

不上个附件吗

Hontyu

给个附件4楼老师分分钟帮你搞定了

xjy426

fzxba 发表于 2022-12-9 17:40
Sub 据想象而写() '
  Dim strFile(1) As String
  strFile(0) = ThisWorkbook.Path & "\工作簿1.xlsx"

感谢4楼 fzxba 老师的帮助，问题已经得到解决，代码能完美完成任务。正在学习中。

这段代码中，变量conn 和 rs 仅 dim 各一个，仅 open 一次。

在SQL语句中，用 a、b、c 各指代一个sheet名 [订单$] ,  b 指代 [生产$] , c 指代 [客户要求$]  。我重来没有见过这种指代，学到了学到了，下次也用上。我想应该还可以在SQL语句中添加条件、排序中指代吧。access中不知道能不能用，我去试试看。

conn打开的是工作簿1，包含两个sheet（a、c），然后在SQL语句中，直接将链接字符串指向工作簿2：[Excel 12.0;HDR=Yes;IMEX=1;Database=工作簿2].[生产$] b，我就是不会写这个！如何在SQL语句中嵌套其它连接！！学会这个方法，就可以在自己会写的SQL中替换、嵌套进去，连接多个表，多重链接查询！！

xjy426

已解决，怎么改帖子状态？？

xjy426

找到了。点击主题下面的编辑，再更改状态。