如何在VBA代码中给查询结果按升序输出

woailijiao

求助老师如何给查询输出的的结果添加顺序按升序排列。

zxsea_7426

是这样的输出结果吗？？

zxsea_7426

如果是非功过2楼这样的输出结果，最后加一行代码就行


With Sheets("sheet1")
    .Range("c1").Resize(m, UBound(brr, 2)).NumberFormatLocal = "@"
    .Range("c1").Resize(m, UBound(brr, 2)) = brr
    .Range("c1").Resize(m, UBound(brr, 2)).Sort key1:=.[g2], Order1:=xlAscending, Header:=xlGuess

End With

woailijiao

zxsea_7426 发表于 2022-12-8 15:24
是这样的输出结果吗？？

嗯，对，姓名那里要排序，升序，

arsong

对结果数组进行排序，附我整理的二维数组冒泡排序：
'冒泡排序：【二维数组】排序
'arrSort                要进行排序的二维数组
'sortCol                排序列
'sortMode        排序模式："+" 升序，"-" 降序
Public Sub BubbleSort2(ByRef arrSort As Variant, ByVal sortCol As Integer,  _
            Optional ByVal sortMode As String = "+")
    Dim i&, j&, t&, Sorted As Boolean, temp, LastIndex&, SortBorder&
    ReDim temp(LBound(arrSort, 2) To UBound(arrSort, 2))
    SortBorder = UBound(arrSort) - 1
    If sortMode = "+" Then
        For i = LBound(arrSort) To UBound(arrSort)
            Sorted = True
            For j = LBound(arrSort) To SortBorder
                If arrSort(j, sortCol) > arrSort(j + 1, sortCol) Then
                    Sorted = False
                    For t = LBound(arrSort, 2) To UBound(arrSort, 2)
                        temp(t) = arrSort(j, t)
                        arrSort(j, t) = arrSort(j + 1, t)
                        arrSort(j + 1, t) = temp(t)
                    Next
                    LastIndex = j
                End If
            Next
            SortBorder = LastIndex
            If Sorted Then Exit For
        Next
    ElseIf sortMode = "-" Then
        For i = LBound(arrSort) To UBound(arrSort)
            Sorted = True
            For j = LBound(arrSort) To SortBorder
                If arrSort(j, sortCol) < arrSort(j + 1, sortCol) Then
                    Sorted = False
                    For t = LBound(arrSort, 2) To UBound(arrSort, 2)
                        temp(t) = arrSort(j, t)
                        arrSort(j, t) = arrSort(j + 1, t)
                        arrSort(j + 1, t) = temp(t)
                    Next
                    LastIndex = j
                End If
            Next
            SortBorder = LastIndex
            If Sorted Then Exit For
        Next
    End If
End Sub

zxsea_7426

woailijiao 发表于 2022-12-8 15:31
嗯，对，姓名那里要排序，升序，

你是按姓名排序不是按业绩排序？

woailijiao

zxsea_7426 发表于 2022-12-8 15:41
你是按姓名排序不是按业绩排序？

是的，输出结果按姓名排序

woailijiao

arsong 发表于 2022-12-8 15:31
对结果数组进行排序，附我整理的二维数组冒泡排序：
'冒泡排序：【二维数组】排序
'arrSort                要进行排序 ...

老师，请问怎么用啊，前面还有查询的VBA代码，这个怎么加进去啊？直接放在查询代码的后面码？能不能教我一下。

ykcbf1100

按姓名排序。

woailijiao

zxsea_7426 发表于 2022-12-8 15:25
如果是非功过2楼这样的输出结果，最后加一行代码就行

厉害了，我的哥！