LAMBDA函数使用技巧继续挑战：使用LAMBDA函数从任意字符串从右边提取任意位置的数...

丁建成

一、定义函数

在Formula菜单NameManager里面定义下述名称；

下表中公式里面最后的括号及其内容无需在定义公式时录入。

Name	Formula	Results
GetLastChar	=LAMBDA(a,b,IF(b>LEN(a),a,IF(ISNUMBER(1*MID(a,LEN(a)-b+1,1)),RIGHT(a,b-1),GetLastChar(a,b+1))))("a1b2c3d4e5f",1)	f
DeleteLastChar	=LAMBDA(a,LEFT(a,LEN(a)-LEN(GetLastChar(a,1))))("a1b2c3d4e5f")	a1b2c3d4e5
GetLastNumber	=LAMBDA(a,b,IF(b>LEN(a),a,IF(MID(a,LEN(a)-b+1,1)="-",RIGHT(a,b),IF(ISNUMBER(1*RIGHT(a,b)),GetLastNumber(a,b+1),RIGHT(a,b-1)))))("a1b2c3d4e5",1)	5
DeleteLastNumber	=LAMBDA(a,LEFT(a,LEN(a)-LEN(GetLastNumber(a,1))))("a1b2c3d4e5")	a1b2c3d4e
RightFindChar	=LAMBDA(a,b,IF(b=1,GetLastChar(a,1),RightFindChar(DeleteLastNumber(DeleteLastChar(a)),b-1)))("a1b2c3d4e5f",6)	a
RightFindNumber	=LAMBDA(a,b,IF(b=1,GetLastNumber(DeleteLastChar(a),1)*1,RightFindNumber(DeleteLastNumber(DeleteLastChar(a)),b-1)))("a1b2c3d4e5f",4)	2
RightFind	=LAMBDA(a,b,c,IF(c=1,RightFindNumber(a,b),RightFindChar(a,b)))("a1b2c3d4e5f",3,1)	3

A、提取最右边字符串函数，GetLastChar(aas string,b as ID =1)

=LAMBDA

(a, b,

IF      (

          b>LEN(a),

          a,

          IF       (

                    ISNUMBER(1*MID(a,LEN(a)-b+1,1)),

                    RIGHT(a,b-1),

                    GetLastChar(a,b+1)

                    )

          )

)

1、 设置两个参数：待处理字符串，计数值1；从右边逐个递增识别字符，若为字符，则判断下一位；否则，按计数值减1从右边截取字符串。

2、 第二层判断，按当前序数值取单一字符，乘以1强制转换类型，判断是否为数值；如果是，则按当前序数值减1，从右边截取字符串；否则，当期序数值加1，调用本函数；

3、 若待处理字符串，全部为字符，当判断到最左边时，当前序数值等于字符串长度；然后序数值加1，再次调用本函数时，Mid函数将报错；因此，增加第一层判断，避免报错。

B、 删除最右边字符串函数，DeleteLastChar(aas string)解析

=LAMBDA

(a,

LEFT

          (a,

          LEN(a)-LEN        (

                                        GetLastChar(a,1)

                                        )

          )

)

·       设置一个参数：待处理字符串；基于待处理字符串，将GetLastChar函数提取的字符串，按字符串长度差异在待处理串中删除；

C、 提取最右边数值函数：GetLastNumber(aas string,b as ID =1)解析

=LAMBDA

(a,b,

IF      (b>LEN(a),

          a,

          IF       (MID(a,LEN(a)-b+1,1)="-,

                    RIGHT(a,b),

                    IF                (ISNUMBER(1*RIGHT(a,b)),

                                        GetLastNumber(a,b+1),

                                        RIGHT(a,b-1))

                    )

          )

)

·       设置两个参数：字符串参数，必须最右边为是数值；计数值1；

·       相关逻辑与GetLastChar基本相同；从右边逐个递增识别字符，若为数值，则判断下一位；否则，按计数值减1从右边截取数值字符串。

·       增加了一个特殊判断，若当前字符为“-”，则按照当期计数值返回右边的字符串。

丁建成

D、 删除最右边数值字符串函数， DeleteLastNumber(a as string)解析
=LAMBDA
(a,
LEFT(
        a,
        LEN(a)-LEN(GetLastNumber(a,1))
        )
)
•        设置一个参数：字符串参数，必须最右边为是数值；相关逻辑与GetLastChar基本相同；
•        基于待处理字符串，将GetLastNumber函数提取的数值字符串，按字符串长度差异在待处理串中删除。
E、提取右边指定位置的字符串，RightFindChar(a as String, b as ID)解析
=LAMBDA
(a,b,
        IF        (
                b=1,
                GetLastChar(a,1),
                RightFindChar(DeleteLastNumber(DeleteLastChar(a)),b-1))
)
•        设置两个参数：待处理字符串，从右边开始提取第ID位的字符串；
•        若ID为1，可直接调用GetLastChar函数；
•        若ID大于1，则调用DeleteLastChar和DeleteLastNuber分别删除最右边的字符串和数值字符串，ID减1；如此，循环调用。
F、提取右边指定位置的数值字符串，RightFindNumber(a as String, b as ID)解析
=LAMBDA
(a,b,
        IF        (
                b=1,
                GetLastNumber(DeleteLastChar(a),1)*1,
                RightFindNumber(DeleteLastNumber(DeleteLastChar(a)),b-1))
)
•        设置两个参数：待处理字符串，从右边开始提取第ID位的字符串；
•        若ID为1，可直接调用GetLastChar先删除最右边的字符串函数，再调用GetLastNumber获取对应的数值字符串；
•        若ID大于1，则调用DeleteLastChar和DeleteLastNuber分别删除最右边的字符串和数值字符串，ID减1；如此，循环调用。
G、提取右边指定位置的字符串或数值字符串，RightFind(a as String, b as ID, C as type)解析
=LAMBDA
(a,b,c,
        IF        (
                c=1,
                RightFindNumber(a,b),
                RightFindChar(a,b))
)
•        设置两个参数：待处理字符串；从右边开始提取第ID位的字符串；提取类型，1表示数值；
•        判断参数TYPE是否为1；如为1，则调用RightFindNumber函数；否则，调用RightFindChar函数。

三、运行示例

若在A1里面输入字符串s;120101.-dsisis-erwr..34--34wrwr-02-392.3394.32sdjfsls;dfj。
按下图输入相关参数和公式，查看运行结果，还是比较令人满意的。


 

shaowu459

感谢分享～建议可以将excel源文件压缩后一并上传，方便大家学习讨论，谢谢[嘻嘻]

丁建成

需要在公式菜单名称定义里面，逐个定义七个函数，注意不要把测试参数定义进去。

ipkdbr

这个lambda只能在365中用吗。 我装了2021版excel，竟然不识别lambda

高个子

ipkdbr 发表于 2022-10-31 14:06
这个lambda只能在365中用吗。 我装了2021版excel，竟然不识别lambda

当然啦，貌似得预览版才行，我有台电脑没弄到预览版都没有lambda

nqwl

我装了2024版本，也没有这个函数

众妙之门1

很实用，感谢楼主分享