VBA代码转换PDF为其他文件格式,如docx/jpg/xlsx/txt等

游乐缘

新版转换PDF为其他文件格式的代码，输入第二参数文件类型时更加方便准确。

1. Option Explicit
   
2. 
   
3. Private Enum Conv
   
4.   TypeDoc = 0
   
5.   TypeDocx = 1
   
6.   TypeEps = 2
   
7.   TypeHtml = 3
   
8.   TypeJpeg = 4
   
9.   TypeJpf = 5
   
10.   TypePdfA = 6
    
11.   TypePdfE = 7
    
12.   TypePdfX = 8
    
13.   TypePng = 9
    
14.   TypePs = 10
    
15.   TypeRft = 11
    
16.   TypeTiff = 12
    
17.   TypeTxtA = 13
    
18.   TypeTxtP = 14
    
19.   TypeXlsx = 15
    
20.   TypeSpreadsheet = 16
    
21.   TypeXml = 17
    
22. End Enum
    
23. 
    
24. Public Sub Sample()
    
25.   ConvertPDF "C:\Temp\testConvert.pdf", TypeJpeg
    
26. End Sub
    
27. 
    
28. Private Sub ConvertPDF(ByVal TargetFilePath As String, _
    
29.                        ByVal TargetConvType As Conv)
    
30. 
    
31.   Dim jso As Object
    
32.   Dim convid As String
    
33.   Dim ext As String
    
34.   Dim fp As String, fn As String
    
35.    
    
36.   With CreateObject("Scripting.FileSystemObject")
    
37.     fp = AddPathSeparator(.GetParentFolderName(TargetFilePath))
    
38.     fn = .GetBaseName(TargetFilePath)
    
39.   End With
    
40.    
    
41.   convid = GetConvID(TargetConvType)
    
42.   ext = GetExtension(TargetConvType)
    
43.   With CreateObject("AcroExch.PDDoc")
    
44.     If .Open(TargetFilePath) = True Then
    
45.       Set jso = .GetJSObject
    
46.       CallByName jso, "saveAs", VbMethod, _
    
47.                  fp & fn & "." & ext, convid
    
48.       .Close
    
49.     End If
    
50.   End With
    
51. End Sub
    
52. 
    
53. Private Function GetConvID(ByVal ConvType As Conv) As String
    
54.   Dim v As Variant
    
55.    
    
56.   v = Array("com.adobe.acrobat.doc", "com.adobe.acrobat.docx", "com.adobe.acrobat.eps", _
    
57.             "com.adobe.acrobat.html", "com.adobe.acrobat.jpeg", "com.adobe.acrobat.jp2k", _
    
58.             "com.callas.preflight.pdfa", "com.callas.preflight.pdfe", "com.callas.preflight.pdfx", _
    
59.             "com.adobe.acrobat.png", "com.adobe.acrobat.ps", "com.adobe.acrobat.rtf", _
    
60.             "com.adobe.acrobat.tiff", "com.adobe.acrobat.accesstext", "com.adobe.acrobat.plain-text", _
    
61.             "com.adobe.acrobat.xlsx", "com.adobe.acrobat.spreadsheet", "com.adobe.acrobat.xml-1-00")
    
62.   GetConvID = v(ConvType)
    
63. End Function
    
64. 
    
65. Private Function GetExtension(ByVal ConvType As Conv) As String
    
66.   Dim v As Variant
    
67.    
    
68.   v = Array("doc", "docx", "eps", "html", "jpeg", "jpf", "pdf", "pdf", "pdf", "png", _
    
69.             "ps", "rft", "tiff", "txt", "txt", "xlsx", "xml", "xml")
    
70.   GetExtension = v(ConvType)
    
71. End Function
    
72. 
    
73. Private Function AddPathSeparator(ByVal s As String)
    
74.   If Right(s, 1) <> ChrW(92) Then s = s & ChrW(92)
    
75.   AddPathSeparator = s
    
76. End Function

复制代码

sulli112

请问这是什么情况呢？

boy8199

sulli112 发表于 2022-3-25 08:59
请问这是什么情况呢？

acrobat 安装一下

游乐缘

sulli112 发表于 2022-3-25 08:59
请问这是什么情况呢？

请问你的电脑是否已安装Adobe Acrobat软件？

boy8199

acrobat也是个怪胎,是com竟然没有vb的接口

boy8199

你好,老师,问一下 有扫描仪方面的代码吗? 多页扫描

游乐缘

boy8199 发表于 2022-3-25 09:10
你好,老师,问一下 有扫描仪方面的代码吗? 多页扫描

扫描仪方面的知识还没涉猎过，有时间我找找相关资料学习一下

sulli112

游乐缘 发表于 2022-3-25 09:07
请问你的电脑是否已安装Adobe Acrobat软件？

已经安装了，请问为什么还是不可以呢？
还有这个后期绑定不是选择箭头那个位置吗/

游乐缘

sulli112 发表于 2022-3-25 09:28
已经安装了，请问为什么还是不可以呢？
还有这个后期绑定不是选择箭头那个位置吗/

有几点问题需要说明：1. 此代码采用后期绑定，不必手动引用库。
2. Adobe Acrobat Reader与Adobe Acrobat Pro不一样，一个是阅读器，一个是编辑器。此代码需要编辑器
3. 本机如已安装Acrobat，首次引用Acrobat库的名称如下图；引用后再次查看库时，库名称会自动匹配本机Acrobat版本，如下下图。

sulli112

游乐缘 发表于 2022-3-25 09:45
有几点问题需要说明：1. 此代码采用后期绑定，不必手动引用库。
2. Adobe Acrobat Reader与Adobe Acroba ...

请问下载Adobe Acrobat DC这个版本可以吗