[答疑解惑]函数公式解释专用帖

idolle

我问一个小问题吧
在公式输入的时候：=和=+有什么区别呢？
比如：
A2单元格的值为78
若B3=A2，则显示为78
B3=+A2，显示也为78
难道没有区别吗？！
还是区别是在使用高级函数的时候才有用？！

gouweicao78答复：没有什么区别，只是一个操作习惯不同而已。比如财务方面的人员习惯用小键盘输入，直接先按小键盘的+号然后输入相应数值或者单元格引用等，与普通人先按=号再输入的运算结果是一致的。如果没有数字小键盘，一般不会刻意地按Shift+“=”号键来输入+号。

[ 本帖最后由 gouweicao78 于 2008-12-8 09:31 编辑 ]

hbw00

=SUMPRODUCT(($B2:$B26=G1)*($C2:$C26>=10)*($C2:$C26<20))
此公式中SUMPRODUCT函数的用法与帮助中说的有很大差别,看SUMPRODUCT函数的帮助无法理解它在这个例子中的用法,在这里乘号的意思是不是"而且"?
请帮忙解释下.
原帖:http://club.excelhome.net/thread-379552-1-1.html
包含此公式的回复在3楼附件中.
谢谢.

gouweicao78答复：这是多条件计数的基本方法。本帖第33楼已有解释。

[ 本帖最后由 gouweicao78 于 2008-12-14 17:33 编辑 ]

cynthia02

请教版主精粹 技巧110 中 在“来源”中输入的公式这两部份不懂，请给详细讲讲（我看了关于MATCH公式帮助，里面说是查找指定数在数组中的相对位置。可是书里的公式中要查找的值没有含在那个数组中。不懂了）
=MATCH($A2,Province,)     (Province相当于$A$1:$G$1)
=COUNTA(OFFSET(CITY,,MATCH($A2,Province,)-1,65535))   (city相当于$a$2)

gouweicao78回复：1、书中Province=城市列表!$A$1:$G$1，其中E1单元格说“河北省”，而公式中的A2是“河北省”，怎么会没有在Province中呢？因此，MATCH得到的是5，表示“河北省”在A1:G1的第5个位置。
2、city=城市列表!$A$2，OFFSET(CITY,,MATCH($A2,Province,)-1,65535))就等于OFFSET(城市列表!$A$2,0,5-1,65535)，也就是从城市列表!$A$2单元格偏移0行4列，高度为65535行，即引用城市列表!E2:E65536区域。
COUNTA(城市列表!E2:E65536)，统计该区域有多少个非空单元格。

[ 本帖最后由 gouweicao78 于 2008-12-17 18:02 编辑 ]

wjk122276

=COUNT(IF((E5:AK5>=C5)*(E5:AK5<=D5),E5:AK5))
那位高手帮帮忙，给看一下上面的公式怎么不统计值=C5或D5的数据呢？只统计了>和<范围内的数据。

gouweicao78答复：请传附件或链接，以便查看具体问题。该公式是数组公式，必须按Ctrl+Shift+Enter结束才能得到正确结果。另，本帖是解释公式含义，请勿回复无关话题

[ 本帖最后由 gouweicao78 于 2008-12-17 17:50 编辑 ]

kepeng100

A1 = 987612

=SUBSTITUTE(   SUM(ISNUMBER(FIND(ROW($1:$9),$A1))  *   (ROW($1:$9)*10^(9-ROW($1:$9)))),0,"")

标蓝色的这我懂 SUBSTITTUTE我也懂, 标红色的跟整个数组公式不懂,版主有空帮我解释一下,谢谢了

gouweicao78答复：请参考本帖首页“庖丁解牛”、独孤九键法对各部分按F9：
1、ISNUMBER(FIND(ROW($1:$9),$A1)) ——判断A1中数字1~9有哪些，有则返回TRUE，无则返回False。得到数组：{TRUE;TRUE;FALSE;FALSE;FALSE;TRUE;TRUE;TRUE;TRUE}
2、ROW($1:$9)*10^(9-ROW($1:$9))——数字1~9分别乘以10的8、7、……2、1、0次方，得到数组{100000000;20000000;3000000;400000;50000;6000;700;80;9}
3、SUM({TRUE;TRUE;FALSE;FALSE;FALSE;TRUE;TRUE;TRUE;TRUE}*{100000000;20000000;3000000;400000;50000;6000;700;80;9})——得到120006789
4、SUBSTITUTE把0替换掉，剩下126789
从公式的看，估计是要将A1出现的数字从小到大排序，但没考虑0也没考虑数字重复，比如：5655500031将得到1356。

[ 本帖最后由 gouweicao78 于 2008-12-18 23:34 编辑 ]

nai_ming

背景情况如下,我发帖得高手指点赐我公式：http://club.excelhome.net/viewthread.php?tid=382306&highlight=
  主要是对:0/SUBTOTAL(3,OFFSET(D2,ROW(D2:D11)-1,))
我初步根据公式分析 :0/SUBTOTAL(3,OFFSET(D2,ROW(D2:D11)-1,)) 好象是 给筛选项的最后一行 加上一个 标注 0 ,这样查到D3:D11列所在的行的数.                  具体原理 ,尤其是"0/   "我实在想不清,特请指点.   请讲解本公式思路

gouweicao78答复：给出链接即可，节省篇幅。关于LOOKUP(1,0/(条件),查找区域)，本帖137楼等已解释，关于OFFSET(D2,ROW(D2:D11)-1,)这是函数产生的三维引用，分别引用D2、D3、D4……D11，再利用SUBSTOTAL函数对“筛选”或“隐藏”状态下被忽略，统计为0的原理，结合LOOKUP(1,0/(条件),查找区域)——查找最后一个满足条件记录的用法，实现取出“筛选”值。

[ 本帖最后由 gouweicao78 于 2008-12-24 21:04 编辑 ]

奶茶绕绕

1.请问这是不是宏表函数
2.公式中的 * 是什么意思,是乘号还是合并?,麻烦解释一下公式的意思
3.请问公式::{=SUM((E$5:E5<>E$4:E4)*(G$5:G5=G5)*(J$5:J5))}
      和公式::  =SUM((E$5:E5<>E$4:E4)*(G$5:G5=G5)*(J$5:J5))
  公式意思上有啥不同呀? 附件中 I5与I6的单元格中公式就有这样的差别,不能下拖,不明白原因
4.请问相关内容在哪里学习?
谢谢老师!

求助表.zip (30.62 KB, 下载次数: 25)

2008-12-27 16:52 上传

点击文件名下载附件

gouweicao78答复：1、您的表格中没有使用宏表函数；2、关于*号、以及两个公式的意思，本帖首页基本都讲解过，*号就是乘法运算，公式外的大括号{}是因为输入公式后按ctrl+shift+enter形成数组公式，Excel自动加上去的，而不带{}的是普通公式，请参考首页的链接

[ 本帖最后由 gouweicao78 于 2008-12-29 01:08 编辑 ]

2hf

SMALL(IF(tblDetails[Order ID]=rngOrderId,ROW(tblDetails[Order ID])-ROW(tblDetails[#标题])),ROW(1:1)),

能解释下这句话的含义么？这句话最后得到什么呢？谢谢

我理解是，如果if里的两个值相等，就ROW(tblDetails[Order ID])-ROW(tblDetails[#标题]，这句话不理解
small（array，k），k不应该是一个数值么？row（1：1）是一个数值么？一个恒值么？
谢谢

gouweicao78答复：请按Ctrl+F3，查看诸如tblDetails[Order ID]等等名称的具体公式。SMALL+ROW用法是数组公式中最常见的用法之一，比如SMALL(IF(A1:A5=1,ROW(A1:A5)),ROW(1:1))，表示如果A1:A5=1，就返回其行号，假设A1、A3满足条件，则IF返回{1;false;3;false;false}，公式在第一行Row(1:1)返回{1}，公式在第2行，就变成Row(2:2)，结合Small分别得到最小的、倒数第2小的……行号。

关于这个用法的新问题：我是希望利用index和match查找满足条件所有数据，比如如下表：d2:e11数据：
A        1
A        2
A        3
B        1
B        2
A        4
A        5
A        6
A        7
B        3
B        4

希望在A1中输入条件，比如A,在A2和B2中输出A对应所有信息，那么我在A2中输入了：
{=index(d2:e11,small(if(d2:d11=a1,row(d2:d11)),row(1:1),1)}
这时应该A2显示A，B2显示1.但是出错了。如果不用数组公式，就没问题。
不论是否使用了数组公式，当我下拉单元格的时候，我希望A3显示A,B3显示2
但是，A3是#num，出错了，
请教版主，这个是什么问题呢？什么时候该用数组公式呢？是不是row()出问题了呢？示例附件如下：

不胜感激

[ 本帖最后由 2hf 于 2009-1-4 01:25 编辑 ]

kepeng100

=LOOKUP(2,1/(D5:D20=MAX(D5:D20)),A5:A20)

请版主帮忙解释一下,这个数组公式,在此谢谢了!

gouweicao78答复：1、这个公式不需要按ctrl+shift+enter形成数组公式；2、LOOKUP(2,1/(条件),查找区域)的解释，请参考137楼。

[ 本帖最后由 gouweicao78 于 2009-1-3 14:45 编辑 ]

Ellin-依莲

假设C1:C460列区域内存放着职工的职称，D1:D460列区域存放着职工的性别。如果要统计具有高级职称的男性职工总数，可以使用公式 “=SUM（IF（C1:C460=〃高级〃，IF（D1:D460=〃男〃，1，0）））”。请问版主后面的,1,0是什么意思,为什么把这两具数字删除的话,组数是错误的没法计算?

gouweicao78答复：希望您能从本帖首页看起，这是个数组公式，需要按CTRL+SHIFT+ENTER结束形成{=公式}样式。后面的1、0是数值，表示当IF条件满足时返回1，不满足时返回0。实际上，这个公式只需要用=SUMPRODUCT((C1:C460="高级")*(D1:D460="男"))，普通公式，按Enter键即可。

[ 本帖最后由 gouweicao78 于 2009-1-12 17:10 编辑 ]