按照出现顺序替换

kfj000

比如word里有10个地方出现了”答案”，怎么把第三个，第六个，第九个”答案”替换为“解析”啊，每个答案之间夹杂着不少字。

daibao88

vba判断一下，是否是3的倍数，是则替换。

kfj000

daibao88 发表于 2021-12-27 21:19
vba判断一下，是否是3的倍数，是则替换。

怎么判断啊？

daibao88

Sub test()
    Dim n As Integer, myrange As Range, s As Long
    Set myrange = ActiveDocument.Range
    Do
        With myrange.Find
            .Text = "答案"
            .Execute
            If .Found = True Then
                n = n + 1
                s = .Parent.End
                If n Mod 3 = 0 Then .Parent.Text = "解析"
                myrange.SetRange s, ActiveDocument.Range.End
            Else
                Exit Do
            End If
        End With
    Loop
    ActiveDocument.Save
End Sub

limonet

Sub 宏1()
Dim iCount As Long
iCount = 0
    Selection.HomeKey Unit:=wdStory
    Selection.Find.ClearFormatting
    Selection.Find.Replacement.ClearFormatting
    With Selection.Find
        .Text = "答案"
        .Replacement.Text = "解析"
        .Forward = True
        .Wrap = wdFindContinue
        .Format = False
        .MatchCase = False
        .MatchWholeWord = False
        .MatchByte = True
        .MatchWildcards = False
        .MatchSoundsLike = False
        .MatchAllWordForms = False
    End With
    With Selection
        Do While .Find.Execute
        iCount = iCount + 1
        If iCount = 3 Or iCount = 6 Or iCount = 9 Then
            If .Find.Forward = True Then
                .Collapse Direction:=wdCollapseStart
                Else
                .Collapse Direction:=wdCollapseEnd
            End If
        .Find.Execute Replace:=wdReplaceOne
            If .Find.Forward = True Then
                .Collapse Direction:=wdCollapseEnd
            Else
                .Collapse Direction:=wdCollapseStart
            End If
        End If
        Loop
    End With
End Sub

hao_jk

https://zhuanlan.zhihu.com/p/66569211，可以参考一下