料号拆分

shufeabb

料号拆分.rar (6.46 KB, 下载次数: 21)

2021-7-3 16:34 上传

点击文件名下载附件

shufeabb

let
    源 = Excel.CurrentWorkbook(){[Name="Table1"]}[Content],
    更改的类型 = Table.TransformColumnTypes(源,{{"料号", type text}}),
    已添加自定义 = Table.AddColumn(更改的类型, "自定义", each Text.BeforeDelimiter(Text.BeforeDelimiter([料号],","),"-",{0,RelativePosition.FromEnd})),
    已添加自定义1 = Table.AddColumn(已添加自定义, "自定义.1", each Text.Split(Text.Replace(Text.Middle([料号],Text.Length([自定义]),9999),"-",""),",")),
    #"展开的“自定义.1”" = Table.ExpandListColumn(已添加自定义1, "自定义.1"),
    已添加自定义2 = Table.AddColumn(#"展开的“自定义.1”", "自定义.2", each [自定义]&"-"&[自定义.1])
in
    已添加自定义2

shufeabb

多一个条件，如果是thr就需要连续的料号，这要怎么处理？ 料号拆分.rar (17.49 KB, 下载次数: 12)

2021-7-3 17:10 上传

点击文件名下载附件

kirete

let
    源 = Excel.CurrentWorkbook(){[Name="Table15"]}[Content],
    自定义1 =
        Table.AddColumn(
            源,
            "q",
            each
                let
                    a =
                        List.Accumulate( { { ",-", "," }, { " thr -", ".." } }, [料号], (x,y)=> Text.Replace( x, y{0}, y{1} ) ),
                    b =
                        Splitter.SplitTextByPositions( { 0, Text.PositionOf( a, "-", 1 ) + 1 } )( a ),
                    c =
                        List.Transform( Expression.Evaluate( "{" & b{1} & "}" ), (x)=> b{0} & Text.From( x ) )
                in
                    c
        ),
    #"展开的“q”" = Table.ExpandListColumn(自定义1, "q")
in
    #"展开的“q”"