请教如何通过代码统计文档中每个单词出现的频次？

tangqingfu · 发表于 2021-3-2 13:34

想统计文档中每个单词出现的频次？统计结果按出现频次从高到低进行排序，单词不区分大、小写字母（WHAT、What、what作为同一个单词进行统计），请教能否通过VBA代码实现？
如：
are 50次
do 48次
does 12次
America 1次

ming0018 · 发表于 2021-3-2 14:27

遍历每个单词，用字典记录，最后再从大到小排序。

tangqingfu · 发表于 2021-3-2 14:42

ming0018 发表于 2021-3-2 14:27
遍历每个单词，用字典记录，最后再从大到小排序。

能否请ming0018兄出手，帮忙写下代码？

shenjianrong163 · 发表于 2021-3-2 22:03

Sub WordFrequency() '不考虑单词缩写情况
Dim c$, s$, d, k, i&, j&, temp$, reg, Match, Matches
s = ActiveDocument.Content.Text
Set d = CreateObject("Scripting.Dictionary")
d.CompareMode = 1
Set reg = CreateObject("VBScript.RegExp")
With reg
.Pattern = "[A-Za-z]+"
.Global = True
Set Matches = .Execute(s)
For Each Match In Matches
With Match
If d.Exists(.Value) Then d(.Value) = d(.Value) + 1 Else d.Add .Value, 1
End With
Next
k = d.Keys
For i = 0 To UBound(k) - 1
For j = i + 1 To UBound(k)
If d(k(i)) < d(k(j)) Then
temp = k(i)
k(i) = k(j)
k(j) = temp
End If
Next
Next
For i = 0 To UBound(k)
c = c & k(i) & vbTab & d(k(i)) & "次" & Chr(13)
Next
Documents.Add.Content.Text = "共有" & d.Count & "个英文单词（含频次）：" & Chr(13) & c
End With
End Sub

复制代码

tangqingfu · 发表于 2021-3-3 10:03

本帖最后由 tangqingfu 于 2021-3-3 10:40 编辑

shenjianrong163 发表于 2021-3-2 22:03

谢谢shenjianrong163兄的帮助！
请教能否将这些单词及其出现的频次分别导入到一个Exel工作表的A、B两列中（按出现频次从高到低进行排序），导入后，调用”单词表“中名为“全部‘的工作表的数据，若导入的单词存在于名为“全部‘的工作表（A列）中，则在C、D、E列中添加对应的“中文”、“音标”及”课本来源“，若不存在，则为空，请教如何实现？
如：
单词频次             中文                         音标    课文来源
the       154次 art.这/那个；这/那些             [eə]          七上
to    63次  prep.到，对，向，在…之前       [tuː]          七上

shenjianrong163 · 发表于 2021-3-3 22:34

tangqingfu 发表于 2021-3-3 10:03
谢谢shenjianrong163兄的帮助！
请教能否将这些单词及其出现的频次分别导入到一个Exel工作表的A、B两列 ...

Sub 统计各单词出现的次数() '将Word文档与Excel文件放同一目录
Dim c$, s$, d, d1, k, i&, j&, temp$, reg, Match, Matches, arr, brr(), wb
s = ActiveDocument.Content.Text
Set d = CreateObject("Scripting.Dictionary")
Set d1 = CreateObject("Scripting.Dictionary")
Set wb = CreateObject("Excel.Application")
d.CompareMode = vbTextCompare '不区分大小写
Set reg = CreateObject("VBScript.RegExp")
With reg
.Pattern = "[A-Za-z]+"
.Global = True
Set Matches = .Execute(s)
For Each Match In Matches
With Match
If d.Exists(.Value) Then d(.Value) = d(.Value) + 1 Else d.Add .Value, 1
End With
Next
k = d.Keys
For i = 0 To UBound(k) - 1
For j = i + 1 To UBound(k)
If d(k(i)) < d(k(j)) Then
temp = k(i)
k(i) = k(j)
k(j) = temp
End If
Next
Next
ReDim brr(1 To UBound(k) + 2, 1 To 5)
j = 1
brr(j, 1) = "单词": brr(j, 2) = "频次": brr(j, 3) = "中文": brr(j, 4) = "音标": brr(j, 5) = "课文来源"
For i = 0 To UBound(k)
j = j + 1
brr(j, 1) = k(i)
brr(j, 2) = d(k(i)) & "次"
Next
End With
With wb.WorkBooks.Open(ActiveDocument.Path & "\单词表.xls")
With .Sheets("全部")
arr = .UsedRange.Value
For i = 2 To UBound(arr)
d1(LCase(arr(i, 1))) = Array(arr(i, 2), arr(i, 3), arr(i, 4))
Next
End With
With .Sheets("Sheet1")
.UsedRange.ClearContents
For i = 2 To UBound(brr)
If d1.Exists(LCase(brr(i, 1))) Then
brr(i, 3) = d1(LCase(brr(i, 1)))(0)
brr(i, 4) = d1(LCase(brr(i, 1)))(1)
brr(i, 5) = d1(LCase(brr(i, 1)))(2)
End If
Next
.[A1].Resize(UBound(brr), 5) = brr
End With
.Close True
End With
wb.Quit
Set wb = Nothing
MsgBox "单词频次统计完成!"
End Sub

复制代码

shenjianrong163 · 发表于 2021-3-3 22:36

tangqingfu 发表于 2021-3-3 10:03
谢谢shenjianrong163兄的帮助！
请教能否将这些单词及其出现的频次分别导入到一个Exel工作表的A、B两列 ...

附件供参考：

Word频次统计.rar (662.58 KB, 下载次数: 23)

tangqingfu · 发表于 2021-3-4 09:04

本帖最后由 tangqingfu 于 2021-3-4 09:05 编辑

感谢shenjianrong163大侠的再次帮助，效果更理想了！
对于文档中的复数名词（如bike→bikes)、动词过去式、过去分词、现在分词（如walk→walked，walk→walking)，形容词的比较级、最高级(如small→smaller→smallest)，因为与单词表中的单词不同，无法获取单词相关的“中文”、“音标”及”课文来源“数据
请教能否做到：在“sheet 1"工作表中，若F列的任意单元格输入的单词存在于“全部"工作表的A列中，则自动在C、D、E列中添加对应的“中文”、“音标”及”课文来源“？
对于这些变化的单词，大侠可有更理想的、更智能的处理办法？

tangqingfu · 发表于 2021-3-4 09:07

shenjianrong163 发表于 2021-3-3 22:36
附件供参考：

感谢shenjianrong163大侠的再次帮助，效果更理想了！
对于文档中的复数名词（如bike→bikes)、动词过去式、过去分词、现在分词（如walk→walked，walk→walking)，形容词的比较级、最高级(如small→smaller→smallest)，因为与单词表中的单词不同，无法获取单词相关的“中文”、“音标”及”课文来源“数据
请教能否做到：在“sheet 1"工作表中，若F列的任意单元格输入的单词存在于“全部"工作表的A列中，则自动在C、D、E列中添加对应的“中文”、“音标”及”课文来源“？
对于这些变化的单词，大侠可有更理想的、更智能的处理办法？

shenjianrong163 · 发表于 2021-3-4 13:16

tangqingfu 发表于 2021-3-4 09:04
感谢shenjianrong163大侠的再次帮助，效果更理想了！
对于文档中的复数名词（如bike→bikes)、动词过去式 ...

对于变化的单词，暂时想不到处理方法。

		自动登录	找回密码
密码			免费注册

[求助] 请教如何通过代码统计文档中每个单词出现的频次？

评分

评分