请问如何让批注中自动记录变更记录

wtujcf123

各位老师，请问如何让单元格的批注中自动记录本单元格修改的内容及时间呢？
1.在单元格变化时,自动将本单元格之前已存在的内容复制到批注中去，并记录变更时间及日期
2.批注框的大小随内容的多少而变化，
3.因表格涉及到多人修改，如果能加上修改人就最好了。


再次谢谢各位老师。

小fisher

在sheet1模块中加入以下代码：

1. Private Sub Worksheet_Change(ByVal Target As Range)
   
2.     If Target.Address = "$B$2" Then
   
3.         Target.Comment.Text vbCrLf & Format(Now, "YYYY-MM-DD hh:mm") & "单元格内容被" & Application.UserName & "修改为：" & Target.Value, Len(Target.Comment.Text)
   
4.         Target.Comment.Shape.TextFrame.AutoSize = True
   
5.     End If
   
6. End Sub

复制代码

注意这个代码记录的是每次修改之后的内容，也可以看作下次修改之前的

wtujcf123

小fisher 发表于 2021-2-8 09:40
在sheet1模块中加入以下代码：

注意这个代码记录的是每次修改之后的内容，也可以看作下次修改之前的

老师，不知道怎么弄，放进去后，没动静。能麻烦再详细指导一下吗？ 显示的是这个东西。

小fisher

wtujcf123 发表于 2021-2-8 20:51
老师，不知道怎么弄，放进去后，没动静。能麻烦再详细指导一下吗？显示的是这个东西。

1. Private Sub Worksheet_Change(ByVal Target As Range)
   
2.     If Target.Address = "$B$2" Then
   
3.         If Target.Comment Is Nothing Then
   
4.             Target.AddComment Format(Now, "YYYY-MM-DD hh:mm") & "单元格内容被" & Application.UserName & "修改为：" & Target.Value
   
5.         Else
   
6.             Target.Comment.Text vbCrLf & Format(Now, "YYYY-MM-DD hh:mm") & "单元格内容被" & Application.UserName & "修改为：" & Target.Value, Len(Target.Comment.Text) + 1
   
7.         End If
   
8.         Target.Comment.Shape.TextFrame.AutoSize = True
   
9.     End If
   
10. End Sub

复制代码

wtujcf123

小fisher 发表于 2021-2-9 08:18

谢谢老师了。可以运行了，能再麻烦一下您吗？想整个一列的单元格均能自动记录，并且，批注里记录的顺序是倒序的。

准提部林

Dim SelTxt$

Private Sub Worksheet_Change(ByVal Target As Range)
Dim TT$, NewTxt$
With Target
     If .Count > 1 Or .Column <> 2 Or .Row < 2 Then Exit Sub
     NewTxt = .Text
     If NewTxt = SelTxt Then Exit Sub
     SelTxt = NewTxt
     If NewTxt = "" Then NewTxt = "<空白>"
     TT = Format(Now, "yyyy-mm-dd hh:mm:ss_") & NewTxt & "_(by." & Application.UserName & ")"
     .NoteText TT & IIf(.NoteText = "", "", vbCrLf & .NoteText)
     .Comment.Shape.TextFrame.AutoSize = True
End With
End Sub

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
Dim xR As Range
With Target
     If .Count = 1 And .Column = 2 And .Row > 1 Then SelTxt = .Text
End With
End Sub

1) 操作牽涉著其它問題--如複製粘貼, 多格操作, 下拉右拉--無法一一防止
2) 只能針對"單一格"處理, 在選取單元格時先取得原來內容, 有改變再記錄,
    例如:原來值是123, 重新輸入123, 則不算改變單元格
3) 原來有值, 被清除了, 記錄, 並標示<空白>

測試時, 先將原有的註解清除~~

wtujcf123

准提部林 发表于 2021-2-18 11:01
Dim SelTxt$

Private Sub Worksheet_Change(ByVal Target As Range)

谢谢老师，您的三点意见我会注意。
经测试，
1.复制粘贴时，会将原来的批注内容清空，比较危险，我设想了两种解决方案：
    1）是参照我在csdn上下载了“幻欢子”制作的一个文件，他的想法是将每次的修改内容记录到另一个表格中,然后从对应单元格中提取信息，但他文件的弊端也很明显，就是单元格的操作会受影响。请见附件。
    2）是禁止该列的粘贴操作。以上两种方案能麻烦老师帮我修改一下吗？
2.我在测试的时候发现当变动超过6次时，批注的内容就不会再增加了，但从程序中看不到相关的限制，是因为excel本身的限制吗？

感谢老师的回答，祝老师新年快乐。我对计算机有些兴趣，但未系统学习相关知识，只能修改非常基础的东西，还请老师费心了。

准提部林

wtujcf123 发表于 2021-2-18 16:55
谢谢老师，您的三点意见我会注意。
经测试，
1.复制粘贴时，会将原来的批注内容清空，比较危险，我 ...

1) 文本都有文字長度的限制, 無法將所有輸入的記錄下來, 且經年累月, 資料太多, 佔空間,
    無論放在註解或另一工作表, 都一樣受限
2) 防止被粘貼或清除全部, 在單元格開放可輸入下, 是沒辦法防護的

也許去研究"追蹤修訂"或"文件共用"是否適用于你的情況,
但這要自己找使用方法~~我不會教

wtujcf123

准提部林 发表于 2021-2-20 10:33
1) 文本都有文字長度的限制, 無法將所有輸入的記錄下來, 且經年累月, 資料太多, 佔空間,
    無論放在註 ...

好的，谢谢老师了，我自己再找找了。

smiletwo

B列数修改时自动增加批注记录信息

1. Private Sub Worksheet_Change(ByVal Target As Range)
   
2.   If Target.Column = 2 Then
   
3.     If Target.Comment Is Nothing Then
   
4.         Target.AddComment Format(Now, "YYYY-MM-DD hh:mm") & "单元格内容被" & Application.UserName & "修改为：" & Target.Value
   
5.     Else
   
6.         Target.Comment.Text Format(Now, "YYYY-MM-DD hh:mm") & "单元格内容被" & Application.UserName & "修改为：" & Target.Value & vbCrLf & Target.Comment.Text
   
7.     End If
   
8.     Target.Comment.Shape.TextFrame.AutoSize = True
   
9.   End If
   
10. End Sub

复制代码