设置页码

jiangxiaoyun · 发表于 2021-1-7 18:13

现代物流公司2020年度经营业绩考核述职会材料(3)(1)(2)(1)(1).zip (1012.87 KB, 下载次数: 198) 请教，如何从此页（页面的第7页）开始设置页码，起始页码为14，然后下一页为15，直到最后。

word真的不太会，请大神帮助。。。。。
如有gif更加好，有文字谢谢步骤也行。

413191246se · 发表于 2021-1-7 20:11

Sub SectionPageNumber()
With ActiveDocument.Sections(5)
.Range.Select
With Selection
.EndKey 6, 1
.Find.Execute "^12", , , 0, , , , , , "", 2
.Sections(1).Footers(wdHeaderFooterPrimary).Range.Text = ""
End With
With .Footers(wdHeaderFooterPrimary).PageNumbers
.NumberStyle = wdPageNumberStyleArabic
' .NumberStyle = wdPageNumberStyleNumberInDash '-1-
.RestartNumberingAtSection = True
.StartingNumber = 14
.Add PageNumberAlignment:=wdAlignPageNumberCenter, FirstPage:=True
End With
End With
End Sub

复制代码

413191246se · 发表于 2021-1-7 22:56

* 蒋老师：新年快乐！——文中分节符太多了！另外，应该用《删除空行》宏删除一些空行；在每个述职报告标题前面应加上一个分页符（当然分节符也可）。因为没有章节，所以，页码连续部分最好是一个节。* * 下面的宏比上楼的更好，请试用：

Sub SectionPageNumber_Better()
Dim i&, j&
With ActiveDocument
j = .Sections.Count
For i = 6 To j
With .Sections(i).Footers(wdHeaderFooterPrimary)
.LinkToPrevious = True
.PageNumbers.RestartNumberingAtSection = False
.Range.Delete
End With
Next
With .Sections(5).Footers(wdHeaderFooterPrimary).PageNumbers
.Parent.LinkToPrevious = False
.NumberStyle = wdPageNumberStyleArabic
' .NumberStyle = wdPageNumberStyleNumberInDash '-1-
.RestartNumberingAtSection = True
.StartingNumber = 14
.Add PageNumberAlignment:=wdAlignPageNumberCenter, FirstPage:=True
'Extra Format/Can delete!
With .Parent.Range.Font
.NameAscii = "Times New Roman"
.Size = 36
.Bold = True
.ColorIndex = wdRed
End With
End With
End With
End Sub

复制代码

jiangxiaoyun · 发表于 2021-1-8 11:08

413191246se 发表于 2021-1-7 22:56
* 蒋老师：新年快乐！——文中分节符太多了！另外，应该用《删除空行》宏删除一些空行；在每个述职报告标题 ...

十分感谢。我昨天弄了大半天代码，没弄出来。我想的是这样：
1：删除word文档中的分页符分节符。
2：直接指定从第几页设定页码，页码起始可以是1，或者指定的数字。
3：目前还在弄这个代码。。。。
真的十分感谢你。我先去折腾一会。word的东东我都是临时抱佛脚。

jiangxiaoyun · 发表于 2021-1-8 12:45

Sub SectionPageNumber_Better()
Dim i&, j&, inum&, spage
With ActiveDocument
j = .Sections.Count
For i = 1 To j
With .Sections(i).Footers(wdHeaderFooterPrimary)
.LinkToPrevious = True
.PageNumbers.RestartNumberingAtSection = False
.Range.Delete
End With
Next
inum = 2
Dim sr As String
sr = InputBox("请输入页码起始页,默认为2" + Chr(13) + Chr(13), 2)
spage = InputBox("请输入页码开始数,默认为1" + Chr(13) + Chr(13), 1)
If sr = "" Then Exit Sub
If sr <> "1" Then
Selection.GoTo what:=wdGoToPage, which:=wdGoToNext, Name:=sr
Selection.InsertBreak Type:=wdSectionBreakNextPage
End If
With .Sections(inum).Footers(wdHeaderFooterPrimary).PageNumbers
.Parent.LinkToPrevious = False
.NumberStyle = wdPageNumberStyleArabic
' .NumberStyle = wdPageNumberStyleNumberInDash '-1-
.RestartNumberingAtSection = True
.StartingNumber = spage
.Add PageNumberAlignment:=wdAlignPageNumberCenter, FirstPage:=True
'Extra Format/Can delete!
With .Parent.Range.Font
.NameAscii = "Times New Roman"
.Size = 36
.Bold = True
.ColorIndex = wdRed
End With
End With
End With
End Sub

复制代码

此代码经测试能够实现从指定页开始设置页码。
如下图：从第3也开始设置页码，页码起始数为8.这两个都可以自定义输入。
更复杂的word文档没有测试，仅供参考。

413191246se · 发表于 2021-1-8 13:16

本帖最后由 413191246se 于 2021-1-8 13:23 编辑

蒋老师，我发现你的文档，共有 11 个节！这么多的节，如果手动多麻烦啊！还是得用 VBA 把页码相同的节设置为链接为 TRUE。其实，我一周前就折腾过页脚，当时感觉怎么录制宏都没用，还是得直接用 ActiveDocument 对象；另外，也参考了微软VBA官方帮助文档关于 PageNumbers 对象/属性的知识。其实，蒋老师在许多方面都比我强，我得向你学习啊！（比如：我对函数、数组都不大会，稀里糊涂的。第30行以后的代码，仅为了观看方便，蒋老师可以全部删除或屏蔽。其实有时是 ActiveDocument，有时是 Selection，我也弄不清，得多试试。——对了，其实昨晚，第2个代码，一开始我也未成功，因为每个页脚出现了双页码；开始也是与前向链接也未成功，反复试验，终于成功。第2个代码，我并未删除一个分节符/分页符，我认为，不管有多少节，它都会成功的。）

413191246se · 发表于 2021-1-8 13:31

蒋老师：我再罗嗦一句，像“封面+目录+正文”这种文档，要是手动分节，设置页码，我没有问题；但是要想用 VBA 来自动设置，就一时半会搞不定，得反复试验，不过，我觉得此中过程也很有趣，有苦有乐（现在我比较倾向于能用代码自动就不手动，一键搞定这才爽）。

jiangxiaoyun · 发表于 2021-1-8 14:12

413191246se 发表于 2021-1-8 13:31
蒋老师：我再罗嗦一句，像“封面+目录+正文”这种文档，要是手动分节，设置页码，我没有问题；但是要想用 V ...

我对word真的不太熟悉。偶尔遇到问题写个代码来折腾。谢谢了。

413191246se · 发表于 2021-1-9 13:12

蒋老师：我觉得咱们都应该把微软VBA帮助文档吃透，有些对象/方法/属性/示例代码，都未学好。

jiangxiaoyun · 发表于 2021-1-9 17:47

413191246se 发表于 2021-1-9 13:12
蒋老师：我觉得咱们都应该把微软VBA帮助文档吃透，有些对象/方法/属性/示例代码，都未学好。

年纪大了，脑瓜没那个能力（年轻也没有这个能力）。
还得买菜煮饭。

还是你们折腾吧。。。。。

		自动登录	找回密码
密码			免费注册

[求助] 设置页码

评分

评分