怎么用VBA实现跨工作簿匹配

wuxuezj

怎么用VBA实现跨工作簿匹配

chxw68

楼主同一问题又新开一贴是什么意思？

3190496160

原来的帖子中很多坛友灰给了你代码，你置之不理，有新开一贴，什么意思嘛？这是对别人不尊重，以后还想别人帮你吗

xiangbaoan

1. Option Explicit
   
2. 
   
3. Sub test1()
   
4.   Dim f$
   
5.   'f = ThisWorkbook.Path & Application.PathSeparator & "1.xlsx"  '指定 工作簿
   
6.   With Application.FileDialog(msoFileDialogOpen)                 '选择 工作簿
   
7.     .InitialFileName = ThisWorkbook.Path
   
8.     With .Filters
   
9.       .Clear
   
10.       .Add "Excel Files", "*.xls?"
    
11.     End With
    
12.     .AllowMultiSelect = False
    
13.     If .Show Then f = .SelectedItems(1) Else Exit Sub
    
14.   End With
    
15.   Dim Cn As Object, Sq$(2)
    
16.   Set Cn = CreateObject("ADODB.Connection")
    
17.   Cn.Open "Provider=Microsoft.ACE.OLEDB.12.0;Extended Properties='Excel 12.0;HDR=no';Data Source=" & ThisWorkbook.FullName
    
18.   Sq(0) = "[" & ActiveSheet.Name & "$E2:E" & Cells(Rows.Count, 5).End(xlUp).Row & "]a"
    
19.   Sq(1) = "[Excel 12.0;HDR=no;Database=" & f & "].[$A2:Y]b"
    
20.   Sq(2) = "SELECT b.f1,b.f2,b.f3,b.f4 FROM " & Sq(0) & " LEFT JOIN " & Sq(1) & " ON a.f1=b.f19"
    
21.   Range("F2").CopyFromRecordset Cn.Execute(Sq(2))
    
22.   Cn.Close: Set Cn = Nothing
    
23.   MsgBox " ok!", 64
    
24. End Sub

复制代码

hjahua

各位大哥大姐我刚开始接触VBA我想知道4楼师傅的代码里修改哪里可以变化另一个工作簿里匹配列位置，修改哪里可以改变本工作簿咧列位置，原来使用公式看的懂，这个我真的看不懂
Option Explicit

Sub test1()
  Dim f$
  'f = ThisWorkbook.Path & Application.PathSeparator & "1.xlsx"  '指定 工作簿
  With Application.FileDialog(msoFileDialogOpen)                 '选择 工作簿
    .InitialFileName = ThisWorkbook.Path
    With .Filters
      .Clear
      .Add "Excel Files", "*.xls?"
    End With
    .AllowMultiSelect = False
    If .Show Then f = .SelectedItems(1) Else Exit Sub
  End With
  Dim Cn As Object, Sq$(2)
  Set Cn = CreateObject("ADODB.Connection")
  Cn.Open "Provider=Microsoft.ACE.OLEDB.12.0;Extended Properties='Excel 12.0;HDR=no';Data Source=" & ThisWorkbook.FullName
  Sq(0) = "[" & ActiveSheet.Name & "$E2:E" & Cells(Rows.Count, 5).End(xlUp).Row & "]a"
  Sq(1) = "[Excel 12.0;HDR=no;Database=" & f & "].[$A2:Y]b"
  Sq(2) = "SELECT b.f1,b.f2,b.f3,b.f4 FROM " & Sq(0) & " LEFT JOIN " & Sq(1) & " ON a.f1=b.f19"
  Range("F2").CopyFromRecordset Cn.Execute(Sq(2))
  Cn.Close: Set Cn = Nothing
  MsgBox " ok!", 64
End Sub

zpy2

hjahua 发表于 2021-9-20 10:07
各位大哥大姐我刚开始接触VBA我想知道4楼师傅的代码里修改哪里可以变化另一个工作簿里匹配列位置，修改哪里 ...

Sq(0) = "[" & ActiveSheet.Name & "$E2:E" & Cells(Rows.Count, 5).End(xlUp).Row & "]a"
  Sq(1) = "[Excel 12.0;HDR=no;Database=" & f & "].[$A2:Y]b"
  Sq(2) = "SELECT b.f1,b.f2,b.f3,b.f4 FROM " & Sq(0) & " LEFT JOIN " & Sq(1) & " ON a.f1=b.f19"
可能是这里，具体位置，需要上传附件的。

穷极一生为理想

xiangbaoan 发表于 2020-8-15 20:58

大神这三个sql能不能给下注释，想学习看不太懂

cmo9020

这段程序代码是一个用于 Excel VBA 的 SQL 查询语句，它的主要作用是将两个数据表连接起来进行查询，其中：


Sq(0) = "[" & ActiveSheet.Name & "$E2:E" & Cells(Rows.Count, 5).End(xlUp).Row & "]a"：
定义了第一个数据表的范围，它包括了当前工作表的 E 列（从第 2 行到最后一行）。

Sq(1) = "[Excel 12.0;HDR=no;Database=" & f & "].[$A2:Y]b"：
定义了第二个数据表的范围，它是一个外部的 Excel 档案，文件名储存在变量 f 中，范围包括了从 A2 到 Y 列的所有数据。

Sq(2) = "SELECT b.f1,b.f2,b.f3,b.f4 FROM " & Sq(0) & " LEFT JOIN " & Sq(1) & " ON a.f1=b.f19"：
这是一个 SQL 语句，它使用了两个数据表进行连接，并选择了一些字段进行查询。
其中，"SELECT b.f1,b.f2,b.f3,b.f4" 表示选择第二个数据表中的 f1、f2、f3 和 f4 四个字段，"FROM " & Sq(0) & " LEFT JOIN " & Sq(1) & " ON a.f1=b.f19" 表示从两个数据表进行左连接，并以第一个数据表中的 f1 字段和第二个数据表中的 f19 字段进行连接。最后，整个 SQL 语句被储存在 Sq(2) 这个变量中。