数列循环并拓展，求函数

Michael.Deng

123数列进行循环，然后每循环一次拓展数列一次，示例如下（附件），求函数
第一次 001 002 003
第二次 001 002 003 004
第三次 001 002 003 004 005
第四次 001 002 003 004 005 006

满坛皆为吾师

三键下拉，供参考
=RIGHT(SMALL(IF(ROW($1:$99)>=COLUMN(A:CU),ROW($1:$99)*1000+COLUMN(A:CU)),ROW(A4)),3)

Michael.Deng

A1=TEXT(IF(IFERROR(MATCH(ROW(),(ROW($1:$100)^2+5*ROW($1:$100)-6)/2+3,0)+2,0),MATCH(ROW(),(ROW($1:$100)^2+5*ROW($1:$100)-6)/2+3,0)+2,A2-1),"000")
三键下拉，其中A2-1参数 如果是J列就修改为J2-1
我自己做出来了，其中还查了一下数列的求法an-a1=(n^2+5n-6)/2
真是难，找时间缩减一下吧

满坛皆为吾师

Michael.Deng 发表于 2020-7-30 14:51
="00"&IF(IFERROR(MATCH(ROW(),(ROW($1:$100)^2+5*ROW($1:$100)-6)/2+3,0)+2,0),MATCH(ROW(),(ROW($1:$100) ...

三键，下拉
=TEXT(SUM(N(ROUND((ROW($1:4)*2)^0.5,)=ROUND((ROW(A4)*2)^0.5,))),"000")

准提部林

A1=空
A2:=TEXT(MOD(A1,COUNTIF(A$1:A1,1)+2)+1,"000")
下拉 001~999

jivy1212

准提部林 发表于 2020-7-30 15:17
A1=空
A2:=TEXT(MOD(A1,COUNTIF(A$1:A1,1)+2)+1,"000")
下拉 001~999

偷师学习

1. =TEXT(IF(COUNTIF(A$1:A1,1)>A1-2,A1+1,1),"000")

复制代码

jivy1212

C2

1. =TEXT(IF(CEILING(SQRT(2*ROW())-0.5,1)=C1*1,1,C1+1),"000")

复制代码

硬凑套路，好累

daxu1906

第四行开始：=RIGHT(1000+IF(--A3>MAX(--A$1:A2),1,A3+1),3)

我走我流

Michael.Deng 发表于 2020-7-30 14:51
A1=TEXT(IF(IFERROR(MATCH(ROW(),(ROW($1:$100)^2+5*ROW($1:$100)-6)/2+3,0)+2,0),MATCH(ROW(),(ROW($1:$10 ...

用数列来做的话，可以少动脑筋，等差数列的和S =n*a1+n(n-1)*d/2
直接套上
=TEXT(IFERROR(IF(OR(3*ROW($1:$999)+(ROW($1:$999)-1)*ROW($1:$999)/2=ROW(INDIRECT("R[-1]C",))),1,INDIRECT("R[-1]C",)+1),1),"000")

shaowu459

PQ凑个数~仅供参考