word中如何让组合文本框中的文字格式设为指定样式？

xseyuan

没有组合之前的文本框已经搞定，组合后的文本框，查找到不到下百是没有组合之前的代码，如何修改，可以在组合后也能改样式
Sub WBK()
    Dim oDoc As Document
    Set oDoc = Word.ActiveDocument
    Dim oSP As Shape
    With oDoc
       For Each oSP In .Shapes
        With oSP
            '如果类型是文本框则...
            If .Type = msoTextBox Then
                 '修改文本框中格式为“五号中”
                .TextFrame.TextRange.Style = ActiveDocument.Styles("五号中")
            End If
        End With
       Next
    End With
End Sub
[url=]附件[/url]

xseyuan

如和批量更改文本框里字体的大小或颜色？？
http://club.excelhome.net/thread-701779-1-1.html
(出处: ExcelHome技术论坛)
这里面有改excel的，组合前后都没问题，到word中只能组合前改，组合后就不行了

cuanju

Sub d1()
    Rem 批量修改word组合图形中的文本框格式
    Application.ScreenUpdating = False
    On Error Resume Next
    Dim arr()
    k = 0
    For Each oShp In ActiveDocument.Shapes
        ReDim Preserve arr(k)
        arr(k) = oShp.Name
        k = k + 1
    Next
    For j = 0 To UBound(arr)
        sName = arr(j)
        Set oShp = ActiveDocument.Shapes(sName)
        If oShp.Type = msoGroup Then '操作组合图形（也适用于组合图形下的子组合图形）
            For i = 1 To oShp.GroupItems.Count
                If oShp.GroupItems(i).Type = msoTextBox Then
                    With oShp.GroupItems(i).TextFrame.TextRange
                        .Style = ActiveDocument.Styles("五号中")
                    End With
                End If
            Next
        End If
    Next
    Application.ScreenUpdating = True
End Sub

xseyuan

cuanju 发表于 2020-7-13 07:23
Sub d1()
    Rem 批量修改word组合图形中的文本框格式
    Application.ScreenUpdating = False

收到，多谢了，和前面非组合的结合起来，可以完美解决所有文框的格式