与指定行对比重复个数

hzg312

       “数据”表50行数据，每行数据分别与“对比”表指定的3行（序号为1、5、7的行，用黄色标识）数据重复对比完后，将对比结果依次自动填入“结果”表对应的单元格，宏如何编写。请各位老师帮忙看一下啊。谢谢各位了！！

xiangbaoan

Option Explicit
Sub test()
Dim ar, br, t, d As Object, i&, j&, k&, x&, y&
Set d = CreateObject("Scripting.Dictionary")
ar = Sheet1.Range("b3").Resize(50, 6) '2000
br = Sheet2.Range("b3").Resize(10, 18) '500
t = Array(1, 5, 7)
ReDim cr(1 To UBound(ar), 1 To 10)
For i = 1 To UBound(ar)
    For y = 0 To UBound(t)
        d.RemoveAll
        k = 0
        For x = 1 To UBound(br, 2)
            d(br(t(y), x)) = ""
        Next
        For j = 1 To UBound(ar, 2)
            If d.Exists(ar(i, j)) Then k = k + 1
        Next
        cr(i, t(y)) = k
    Next
Next
Sheet3.Range("b3").Resize(i - 1, 10) = cr
Set d = Nothing
End Sub

vic9

Sub j()
Dim i, r, j, Arr1, Arr2, Arr3, d(2), n, k, m
Arr1 = Sheets("数据").Range("a1:g" & Sheets("数据").Cells(Rows.Count, 1).End(xlUp).Row)
Arr2 = Sheets("对比").Range("a1:s" & Sheets("对比").Cells(Rows.Count, 1).End(xlUp).Row)
Arr3 = Sheets("结果").Range("a1:k" & Sheets("结果").Cells(Rows.Count, 1).End(xlUp).Row)

For i = 0 To 2
    Set d(i) = CreateObject("scripting.dictionary")
Next

For r = 1 To 3
    n = Choose(r, 3, 7, 9)
    For i = 2 To UBound(Arr2, 2)
        d(r - 1)(Arr2(n, i)) = ""
    Next
Next

For i = 3 To UBound(Arr1)
    For j = 0 To 2
        m = Choose(j + 1, 2, 6, 8)
        For r = 2 To UBound(Arr1, 2)
            If d(j).exists(Arr1(i, r)) Then
                k = k + 1
            End If
        Next
        Arr3(i, m) = k
        k = 0
    Next
Next

Sheets("结果").[a1].Resize(UBound(Arr3), UBound(Arr3, 2)) = Arr3
End Sub

hzg312

vic9 发表于 2020-6-10 21:37
Sub j()
Dim i, r, j, Arr1, Arr2, Arr3, d(2), n, k, m
Arr1 = Sheets("数据").Range("a1:g" & Sheets(" ...

     谢谢啊，老师辛苦了
     
      如果，不限于这指定的三行，而是“对比”表的全部十行数据都参与对比，该修改那几个参数啊。（我想增加“对比”表参与对比的行数，不太会，没修改成功。。。。）

vic9

Sub jr()
Application.ScreenUpdating = False
Dim i, r, j, Arr1, Arr2, Arr3, d(1 To 500), dic(1 To 500), M, N, p, q, x, Z, d1, d2, Tim
Tim = Timer
Arr1 = Sheets("数据").Range("a1:i" & Sheets("数据").Cells(Rows.Count, 1).End(xlUp).Row)
Arr2 = Sheets("对比").Range("a1:ai" & Sheets("对比").Cells(Rows.Count, 1).End(xlUp).Row)
Arr3 = Sheets("结果").Range("a1:v" & UBound(Arr1))
Set d1 = CreateObject("scripting.dictionary")
Set d2 = CreateObject("scripting.dictionary")

For Z = 1 To UBound(Arr3, 2)
    d1(Arr3(3, Z)) = Z
Next

For i = 1 To 500
    Set d(i) = CreateObject("scripting.dictionary")
    Set dic(i) = CreateObject("scripting.dictionary")
Next

For i = 3 To UBound(Arr2)
    For r = 2 To 19
        d(i - 2)(Arr2(i, r)) = ""
    Next
   
    For j = 20 To 35
        dic(i - 2)(Arr2(i, j)) = ""
    Next
Next

For i = 4 To UBound(Arr1)
    For M = 1 To 500
        For r = 2 To 7
            If d(M).exists(Arr1(i, r)) Then
                p = p + 1
            End If
        Next
        
        For x = 8 To 9
            If dic(M).exists(Arr1(i, x)) Then
                q = q + 1
            End If
        Next
        
        d2(p & "-" & q) = d2(p & "-" & q) + 1
        p = 0: q = 0
    Next
    For N = 0 To d2.Count - 1
        Arr3(i, d1(d2.keys()(N))) = d2.items()(N)
    Next
    d2.RemoveAll
Next
Sheets("结果").[a1].Resize(UBound(Arr3), UBound(Arr3, 2)) = Arr3
Application.ScreenUpdating = True
MsgBox Format(Timer - Tim, "0.0000")
End Sub

vic9

hzg312 发表于 2020-6-11 07:55
谢谢啊，老师辛苦了
     
      如果，不限于这指定的三行，而是“对比”表的全部十行 ...

Sub jooo()
Dim i, r, j, Arr1, Arr2, Arr3, d(9), n, k, m
Arr1 = Sheets("数据").Range("a1:g" & Sheets("数据").Cells(Rows.Count, 1).End(xlUp).Row)
Arr2 = Sheets("对比").Range("a1:s" & Sheets("对比").Cells(Rows.Count, 1).End(xlUp).Row)
Arr3 = Sheets("结果").Range("a1:k" & Sheets("结果").Cells(Rows.Count, 1).End(xlUp).Row)
m = 1
For i = 0 To 9
    Set d(i) = CreateObject("scripting.dictionary")
Next

For r = 3 To UBound(Arr2)
    For i = 2 To UBound(Arr2, 2)
        d(r - 3)(Arr2(r, i)) = ""
    Next
Next
For i = 3 To UBound(Arr1)
    For j = 0 To 9
        For r = 2 To UBound(Arr1, 2)
            If d(j).exists(Arr1(i, r)) Then
                k = k + 1
            End If
        Next
         m = m + 1
        Arr3(i, m) = k
        k = 0
    Next
    m = 1
Next

Sheets("结果").[a1].Resize(UBound(Arr3), UBound(Arr3, 2)) = Arr3
End Sub

hzg312

vic9 发表于 2020-6-11 11:25
Sub jooo()
Dim i, r, j, Arr1, Arr2, Arr3, d(9), n, k, m
Arr1 = Sheets("数据").Range("a1:g" & She ...

厉害！！！
谢谢啊,一步到位解决问题。。。

hzg312

vic9 发表于 2020-6-11 11:25
Sub jooo()
Dim i, r, j, Arr1, Arr2, Arr3, d(9), n, k, m
Arr1 = Sheets("数据").Range("a1:g" & She ...

      没基础，不知道参数意义，修改vba参数真的挺难。。。。
     试着修改“数据”表为5列（B至F列，减少了1列），“对比”表为33列（B至AH列,增加了15列），其它不变。改了半天。。。都改不成功。。。。都不好意思请教美女老师了。。。。

hzg312

hzg312 发表于 2020-6-11 12:07
厉害！！！
谢谢啊,一步到位解决问题。。。

第一种情况：“对比”表增加15列数据（截至到AH列），其它不变。


第二种情况：“数据”表减少1列数据（截至到F列），“对比”表增加17列数据（截至到AJ列）。

vic9

Sub jooo试改()
Dim i, r, j, Arr1, Arr2, Arr3, d(39), n, k, m
Arr1 = Sheets("数据").Range("a1:g" & Sheets("数据").Cells(Rows.Count, 1).End(xlUp).Row)
Arr2 = Sheets("对比").Range("a1:ah" & Sheets("对比").Cells(Rows.Count, 1).End(xlUp).Row)
Arr3 = Sheets("结果").Range("a1:ao" & Sheets("结果").Cells(Rows.Count, 1).End(xlUp).Row)
m = 1
For i = 0 To 39
    Set d(i) = CreateObject("scripting.dictionary")
Next

For r = 3 To UBound(Arr2)
    For i = 2 To UBound(Arr2, 2)
        If Len(Arr2(r, i)) > 0 Then
            d(r - 3)(Arr2(r, i)) = ""
        End If
    Next
Next

For i = 3 To UBound(Arr1)
    For j = 0 To 39
        For r = 2 To UBound(Arr1, 2)
            If d(j).exists(Arr1(i, r)) Then
                k = k + 1
            End If
        Next
         m = m + 1
        Arr3(i, m) = k
        k = 0
    Next
    m = 1
Next

Sheets("结果").[a1].Resize(UBound(Arr3), UBound(Arr3, 2)) = Arr3
End Sub