[求助]怎样统计word中某一个汉字的数量?全部汉字？

山木

如题。怎样用宏统计word文件中某一个汉字，例如“的”字出现的数量？ 要是全部汉字呢？ 谢谢了。

[此贴子已经被作者于2006-3-10 12:27:44编辑过]

守柔

方法很多，试一下这个：

'* ＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋
'* Created By I LOVE YOU WORD!@ExcelHome 2006-3-4 18:32:28
'仅测试于System: Windows NT Word: 11.0 Language: 2052
'№ 0030^The Code CopyIn [ThisDocument-ThisDocument]^'
'* －－－－－－－－－－－－－－－－－－－－－－－－－－－－－
Option Explicit
Sub GetFoundCount()
Dim FoundCount As Integer, myFindText As String
myFindText = "只"
With ActiveDocument.Content.Find
.Text = myFindText
.MatchWildcards = False
.Wrap = wdFindStop
Do While .Execute
FoundCount = FoundCount + 1
Loop
End With
MsgBox "Word 找到" & FoundCount & "个与此条件相匹配的项!", vbInformation
End Sub

山木

收下了。感觉比excel的vba陌生许多。研究一下。 谢谢版主。

安子子安

sub findtext()

dim text as string

dim tt as integer

text="的"

with activedocument.content.find

do while .execute(findtext:=text)=true

tt=tt+1

loop

end with

endsub

konggs

老大，批批这个是否更快！

Sub getfoundcount1()
Dim a, b, c, d, e
d = Timer
a = ActiveDocument.Range.Text
b = Split(a, Chr(-19004))
c = UBound(b)
e = Timer - d
MsgBox "Word 找到" & c & "个与此条件相匹配的项!", vbInformation, e
End Sub

守柔

KONGGS兄的这个方法很好。其实有很多方法可以做到，我在二楼就说的，比如：

Sub GetFoundCount()
Dim strText As String, myText As String
Dim lngOld As Long, lngNew As Long
Dim Times As Single
Times = VBA.Timer
strText = ActiveDocument.Content.Text
myText = "的"
lngOld = Len(strText)
lngNew = Len(Replace(strText, myText, ""))
MsgBox "Word 找到" & lngOld - lngNew & "个与此条件相匹配的项!", vbInformation, VBA.Timer - Times
End Sub

由于我手头没有英文版WORD，我觉得可以直接从查找对话框中读出，但目前还有几个问题没有很好地解决，需要时间。

konggs

不得不说，老大您太强了。[em04][em04][em04]

辰风

老大们好利害，佩服

山木

斑竹和各位大侠的程序都收到了。使用成功。感谢了。 还有一个问题，就是如何统计出所有的汉字数量，好计算出某特定字符所占的比例。 我试了，可以算出所有字符数量，包括空格，标点，数字，字母。但我要汉字，怎么办呢？ 另外请教大侠，VBA.Timer 有什么用？

[此贴子已经被作者于2006-3-10 12:30:26编辑过]

守柔

请参考一下：

http://club.excelhome.net/viewthread.php?tid=118832&replyID=111742&skin=0