Word VBA如何把所有表格设置为三线图？

Yorphone

我用录制宏得到了“把选中表格设置为三线表的代码”
可是不知道怎么用循环把每一个都进行相同的设置~
求大礼帮忙解答一下~
下面是我录制宏得到的代码

Sub 单个三线图()
    ' 三线表格式设置
    Selection.Borders(wdBorderTop).LineStyle = wdLineStyleNone
    Selection.Borders(wdBorderLeft).LineStyle = wdLineStyleNone
    Selection.Borders(wdBorderBottom).LineStyle = wdLineStyleNone
    Selection.Borders(wdBorderRight).LineStyle = wdLineStyleNone
    Selection.Borders(wdBorderHorizontal).LineStyle = wdLineStyleNone
    Selection.Borders(wdBorderVertical).LineStyle = wdLineStyleNone
    Selection.Borders(wdBorderDiagonalDown).LineStyle = wdLineStyleNone
    Selection.Borders(wdBorderDiagonalUp).LineStyle = wdLineStyleNone

'    上边框1.5磅
    Options.DefaultBorderLineWidth = wdLineWidth150pt
    With Selection.Borders(wdBorderTop)
        .LineStyle = Options.DefaultBorderLineStyle
        .LineWidth = Options.DefaultBorderLineWidth
        .Color = Options.DefaultBorderColor
    End With

'    上边框1.5磅
    Options.DefaultBorderLineWidth = wdLineWidth150pt
    With Selection.Borders(wdBorderBottom)
        .LineStyle = Options.DefaultBorderLineStyle
        .LineWidth = Options.DefaultBorderLineWidth
        .Color = Options.DefaultBorderColor
    End With

'    中间边框0.5磅
    Options.DefaultBorderLineWidth = wdLineWidth050pt
    With Selection.Rows(1).Borders(wdBorderBottom) '第一行的底边框
        .LineStyle = Options.DefaultBorderLineStyle
        .LineWidth = Options.DefaultBorderLineWidth
        .Color = Options.DefaultBorderColor
    End With

End Sub

ming0018

论坛里面搜一下，应该有例子。

Yorphone

ming0018 发表于 2020-4-10 15:15
论坛里面搜一下，应该有例子。

我乱搞了一下，一起出Bug，这样成功了，
谢谢大神的回复呀~
不知道这代码怎么写能够简便一点呢~

1. Sub 表格自动三线表()
   
2.     Dim t As Table
   
3.     For Each t In ActiveDocument.Tables
   
4.         With t
   
5.             '去除所有边框
   
6.             .Borders(wdBorderTop).LineStyle = wdLineStyleNone
   
7.             .Borders(wdBorderLeft).LineStyle = wdLineStyleNone
   
8.             .Borders(wdBorderBottom).LineStyle = wdLineStyleNone
   
9.             .Borders(wdBorderRight).LineStyle = wdLineStyleNone
   
10.             .Borders(wdBorderHorizontal).LineStyle = wdLineStyleNone
    
11.             .Borders(wdBorderVertical).LineStyle = wdLineStyleNone
    
12.             .Borders(wdBorderDiagonalDown).LineStyle = wdLineStyleNone
    
13.             .Borders(wdBorderDiagonalUp).LineStyle = wdLineStyleNone
    
14.                
    
15.             '设置上下边框
    
16.             Options.DefaultBorderLineWidth = wdLineWidth150pt
    
17.             .Borders(wdBorderTop).LineStyle = Options.DefaultBorderLineStyle
    
18.             .Borders(wdBorderTop).LineWidth = Options.DefaultBorderLineWidth
    
19.             .Borders(wdBorderTop).Color = Options.DefaultBorderColor
    
20.             
    
21.             .Borders(wdBorderBottom).LineStyle = Options.DefaultBorderLineStyle
    
22.             .Borders(wdBorderBottom).LineWidth = Options.DefaultBorderLineWidth
    
23.             .Borders(wdBorderBottom).Color = Options.DefaultBorderColor
    
24. 
    
25. '            设置中间边框
    
26.             Options.DefaultBorderLineWidth = wdLineWidth050pt
    
27.             .Cell(1, 1).Select
    
28.             With Selection
    
29.                 .SelectRow
    
30.                 .Borders(wdBorderBottom).LineStyle = Options.DefaultBorderLineStyle
    
31.                 .Borders(wdBorderBottom).LineWidth = Options.DefaultBorderLineWidth
    
32.                 .Borders(wdBorderBottom).Color = Options.DefaultBorderColor
    
33.             End With
    
34.        End With
    
35.     Next
    
36. End Sub

复制代码

ming0018

Yorphone 发表于 2020-4-10 17:26
我乱搞了一下，一起出Bug，这样成功了，
谢谢大神的回复呀~
不知道这代码怎么写能够简便一点呢~

使用range对象，不要用selection对象就行了。

sylun

可以试试利用表格样式来设置，如：

1. Sub test()
   
2.     Dim aTable As Table
   
3.    
   
4.     Application.ScreenUpdating = False
   
5.     With ActiveDocument.Styles("简明型 1").Table.Condition(wdFirstRow)
   
6.         With .Borders(wdBorderTop)
   
7.             .LineStyle = wdLineStyleSingle
   
8.             .LineWidth = wdLineWidth150pt
   
9.         End With
   
10.         With .Borders(wdBorderBottom)
    
11.             .LineStyle = wdLineStyleSingle
    
12.             .LineWidth = wdLineWidth050pt
    
13.         End With
    
14.     End With
    
15.     With ActiveDocument.Styles("简明型 1").Table.Condition(wdLastRow)
    
16.         .Borders(wdBorderTop).LineStyle = wdLineStyleNone
    
17.         With .Borders(wdBorderBottom)
    
18.             .LineStyle = wdLineStyleSingle
    
19.             .LineWidth = wdLineWidth150pt
    
20.         End With
    
21.     End With
    
22.     For Each aTable In ActiveDocument.Tables
    
23.         aTable.Style = "简明型 1"
    
24.     Next
    
25.     Application.ScreenUpdating = True
    
26. End Sub

复制代码

Yorphone

sylun 发表于 2020-4-10 21:28
可以试试利用表格样式来设置，如：

好的，太感谢大神啦~我来试试

Yorphone

sylun 发表于 2020-4-10 21:28
可以试试利用表格样式来设置，如：

哇，我看懂了，真的简便好多！！我太感谢了~

Yorphone

ming0018 发表于 2020-4-10 17:42
使用range对象，不要用selection对象就行了。

好的，感谢大神指导~

cuanju

我也写一个，使用Sylun老师的"简明型 1"表格样式。
Sub d()
Rem word三线表表格样式
    Dim aTable As Table
    Application.ScreenUpdating = False
    '整体表格边框线设置
    With ActiveDocument.Styles("简明型 1").Table.Borders
        .OutsideLineStyle = False
        .InsideLineStyle = False
    End With
    With ActiveDocument.Styles("简明型 1").Table.Borders(wdBorderBottom)
        .LineStyle = wdLineStyleSingle
        .LineWidth = wdLineWidth150pt
    End With
    '标题行边框线设置
    With ActiveDocument.Styles("简明型 1").Table.Condition(wdFirstRow)
        With .Borders(wdBorderTop)
            .LineStyle = wdLineStyleSingle
            .LineWidth = wdLineWidth150pt
        End With
        With .Borders(wdBorderBottom)
            .LineStyle = wdLineStyleSingle
            .LineWidth = wdLineWidth050pt
            .Color = wdColorAutomatic
        End With
    End With
    '汇总行边框线设置
    With ActiveDocument.Styles("简明型 1").Table.Condition(wdLastRow).Borders(wdBorderBottom)
        .LineStyle = wdLineStyleSingle
        .LineWidth = wdLineWidth050pt
    End With
    For Each aTable In ActiveDocument.Tables
        aTable.Style = "简明型 1"
    Next
   Application.ScreenUpdating = True
End Sub

cuanju

Yorphone 发表于 2020-4-10 17:26
我乱搞了一下，一起出Bug，这样成功了，
谢谢大神的回复呀~
不知道这代码怎么写能够简便一点呢~

        .Cell(1, 1).Select
        With Selection
            .SelectRow
           '…………………………………………
        End With
=============================
其实这几句代码非常巧妙，如果表格标题行占据2行的，可以选中这2行作为标题行，非常智能（因为很多表格的标题行不一定是第1行）。