如何采用嵌套循环将多个一维数组合并成二维数组

VivD

在用循环赋值的时候遇到了问题
我用不同的方式分别给15个一维数组赋了值
15个数组的元素数量相同 但是采用的是选取方式录入元素 所以元素个数不确定
分别是arr1(),arr2(),...,arr15()

在这里我想讲15个数组合并成一个二维数组arr16()
其中 数组的元素个数为新数组的行数  数组数量为新数组的列数
于是有了下面的代码

For i = 1 to x step1 (这里x是之前数组含有的元素数量)
For t = 1 to 15 （已有的一维数组个数）
arr16(i,t)=arr & t & (i)
Next t
Next i

当我这么写时 会提示arr未定义
于是我换了种写法
把
arr16(i,t)=arr & t & (i)
改成了
arr16(i,t)="arr" & t & "("& i & ")"
这个时候arr16赋值的内容就变成了文本 而不是对应数组的元素

所以我想问下各位大佬 如何采用嵌套循环的方式将多个一维数组合并成二维数组

大灰狼1976

你想用字符串来表示变量的名称？上传一个附件吧，不一定非要这么处理。如果非要这么处理，可以使用CallByName，参考以下贴子的3楼。
http://club.excelhome.net/thread-1501449-1-1.html

VivD

大灰狼1976 发表于 2019-11-15 10:54
你想用字符串来表示变量的名称？上传一个附件吧，不一定非要这么处理。如果非要这么处理，可以使用CallByNa ...

附件的话，我传不出来，我可以大概说一下
是一个模块文件，带有用户界面，点击不同的按钮选取不同区域给不同数组赋值
不同按钮采用的都是click来调用模块里的sub过程
最后再点击整合按钮将所有数组合并为一个二维数组
模块和用户界面 可以导出

大灰狼1976

你不给我一个示例，我就给你一个示例，但是不会涉及你复杂的要求，只有关键部分（以字符串为名称调用数组，并把多个一维数组合并成二维数组）的处理，附件也不需要，只给你代码。

1. Public arr1, arr2, arr3, arr4
   
2. 
   
3. Sub test()
   
4. Dim arrRst(7, 1 To 4), arrTmp
   
5. Dim i&, j&
   
6. arr1 = Array(1, 2, 3, 4)
   
7. arr2 = Array(5, 6, 7, 8)
   
8. arr3 = Array(9, 10, 11, 12)
   
9. arr4 = Array(13, 14, 15, 16, 17, 18, 19, 20)
   
10. For i = 1 To 4
    
11.   arrTmp = CallByName(Me, "arr" & i, VbGet)
    
12.   For j = 0 To UBound(arrTmp)
    
13.     arrRst(j, i) = arrTmp(j)
    
14.   Next j
    
15. Next i
    
16. [a2].Resize(8, 4) = arrRst
    
17. End Sub

复制代码

VivD

大灰狼1976 发表于 2019-11-15 13:13
你不给我一个示例，我就给你一个示例，但是不会涉及你复杂的要求，只有关键部分（以字符串为名称调用数组， ...

十分感谢
我的之前回复的意思是
其他部分都写好了 但是在循环那部分卡住了
所以来论坛里求助
看了以后发现感觉理论上应该只有CallByName能处理的比较符合我的预想

另外也再次感谢大佬的帮助
在之前你在二楼发的链接中我也看到了3L关于CallByName 的部分示例，只是确实无法Get到用法
看了在4L的示例后大概明白了意思
非常感谢

lss001

提供另一思路！！！
Sub 合并一维组成二维()
    ar1 = Array(1, 2)
    ar2 = Array(3, 4, 5)
    ar3 = Array(6, 7, 8, 9)
    hb = Array(ar1, ar2, ar3) '合并一维
    t = UBound(hb)
    ReDim Ur(t)
    For i = 0 To t: Ur(i) = UBound(hb(i)): Next
    s = Application.Max(Ur)
    ReDim arr(s, t) '转二维
    For i = 0 To t
      For j = 0 To UBound(hb(i))
        arr(j, i) = hb(i)(j)
      Next
    Next
    [a1].Resize(s + 1, t + 1) = arr
End Sub