WORD文档批量设置格式

T-T-J

我是专门在学校帮别人打印论文的，我想用VBA设置一个标准的论文格式，论文标准格式如下：

关于XXX问题的研讨 题目居中,三号黑体字

XXX XXX XXX 作者居中, 其后标明工作单位，所在省、市，邮编，4号楷体字

摘 要:XXXXXXXXXXXXXX “摘要”两字5号黑体,其余5号宋体

关键词:XXXX XXXX(RS) YYYY “关键词”三字用5号黑体,其余宋体5号

（正文）

一、XXXXXX 一级标题用4号黑体字（序号用一、二……依此类推）

1.XXXXXXX 二级标题用4号宋体字（序号用1、2……依此类推）

⑴xxxxxxxxx 三级标题用4号宋体字（序号用⑴、⑵、⑶……依此类推）

（正文内容）

yyyyyyyyyyyyyyyyyyyyyyyyy 正文用5号宋体

参考文献: 用5号黑体字

[1]XXX,XYY,XXX，XXXX，《XXXXXXXX》，2008,（1） 5号宋体

[2]Xxx、Xxx 译，《XXXXXXXX》，XX教育出版社，1998. 5号宋体

作者简介: 作者单位、电话、传真、电子信箱、通讯地址及邮政编码 5号宋体

请哪位帮一帮忙，最好能把一个文件夹内的所有文件都批量设置

changhong8

一般人连样式和样式集都没咋用过，别提用vba去套用了

T-T-J

还是请高手，帮一帮忙

413191246se

楼主，请将你所使用电脑的操作系统版本、Word版本说明一下，另外最好提供详细的论文样本（可以隐去一些人名及关键词汇），我按照你的要求试着编了一个宏，请测试：

1. Sub 论文排版()
   
2.     Dim r As Range, a As Range, i As Paragraph, n&, x As Section
   
3. 
   
4.     ActiveWindow.ActivePane.View.Zoom.PageFit = wdPageFitBestFit
   
5. 
   
6.     With ActiveDocument
   
7.         For Each x In .Sections
   
8.             With x.PageSetup
   
9.                 If .Orientation = wdOrientPortrait Then
   
10.                     .TopMargin = CentimetersToPoints(2.54)
    
11.                     .BottomMargin = CentimetersToPoints(2.54)
    
12.                     .LeftMargin = CentimetersToPoints(3.17)
    
13.                     .RightMargin = CentimetersToPoints(3.17)
    
14.                     .PageWidth = CentimetersToPoints(21)
    
15.                     .PageHeight = CentimetersToPoints(29.7)
    
16.                 Else
    
17.                     .TopMargin = CentimetersToPoints(2.5)
    
18.                     .BottomMargin = CentimetersToPoints(2.5)
    
19.                     .LeftMargin = CentimetersToPoints(2.54)
    
20.                     .RightMargin = CentimetersToPoints(2.54)
    
21.                     .PageWidth = CentimetersToPoints(29.7)
    
22.                     .PageHeight = CentimetersToPoints(21)
    
23.                 End If
    
24.                 .HeaderDistance = CentimetersToPoints(1.5)
    
25.                 .FooterDistance = CentimetersToPoints(1.75)
    
26.             End With
    
27.         Next
    
28. 
    
29.         .CopyStylesFromTemplate Template:=.AttachedTemplate.FullName
    
30. 
    
31.         .Content.Find.Execute "[^13^11]", , , 1, , , , , , "^p", 2
    
32. 
    
33.         With .Content.Find
    
34.             .Execute "(", , , , , , , , , "（", 2
    
35.             .Execute ")", , , , , , , , , "）", 2
    
36.             .Execute "([一-﨩])(:)", , , 1, , , , , , "\1：", 2
    
37.         End With
    
38. 
    
39.         .Select
    
40.     End With
    
41. 
    
42.     With Selection
    
43.         .ClearFormatting
    
44.         CommandBars.FindControl(ID:=122).Execute
    
45.         CommandBars.FindControl(ID:=123).Execute
    
46.         .Font.Color = wdColorBlue
    
47.         .ParagraphFormat.CharacterUnitFirstLineIndent = 2
    
48.         Set r = .Range
    
49.         Set a = .Range
    
50.     End With
    
51. 
    
52.     With r
    
53.         For Each i In .Paragraphs
    
54.             If Asc(i.Range) = 13 Then i.Range.Delete
    
55.         Next
    
56. 
    
57.         With .Find
    
58.             .ClearFormatting
    
59.             .Text = "^13[0-9０-９]@[、.．]"
    
60.             .Forward = True
    
61.             .MatchWildcards = True
    
62.             Do While .Execute
    
63.                 With .Parent
    
64.                     .Characters.Last.Text = "．"
    
65.                     .CharacterWidth = wdWidthHalfWidth
    
66.                     .SetRange Start:=.End, End:=a.End
    
67.                 End With
    
68.             Loop
    
69.         End With
    
70. 
    
71.         .SetRange Start:=a.Start, End:=a.End
    
72. 
    
73.         Const s As String = "一二三四五六七八九十1234567890百零〇○"
    
74.         For Each i In .Paragraphs
    
75.             With i.Range
    
76.                 n = 1
    
77.                 Do While InStr(s, .Characters(n)) > 0
    
78.                     n = n + 1
    
79.                     If .Characters(n).Text = "、" Then
    
80.                         .Style = wdStyleHeading1
    
81.                         With .Font
    
82.                             .NameFarEast = "黑体"
    
83.                             .NameAscii = "Arial"
    
84.                             .Size = 14
    
85.                             .Bold = True
    
86.                             .Color = wdColorRed
    
87.                         End With
    
88.                         .ParagraphFormat.CharacterUnitFirstLineIndent = 1.5
    
89.                         Exit Do
    
90.                     End If
    
91.                     If .Characters(n).Text = "．" Then
    
92.                         .Style = wdStyleHeading2
    
93.                         With .Font
    
94.                             .NameFarEast = "宋体"
    
95.                             .NameAscii = "Times New Roman"
    
96.                             .Size = 14
    
97.                             .Bold = True
    
98.                             .Color = wdColorPink
    
99.                         End With
    
100.                         .ParagraphFormat.CharacterUnitFirstLineIndent = 1.5
     
101.                         Exit Do
     
102.                     End If
     
103.                 Loop
     
104.                 If .Text Like "[⑴⑵⑶⑷⑸⑹⑺⑻⑼⑽⑾⑵⑶⑷⑸⑹⑺⑻⑼⑽]*" Then
     
105.                     .Style = wdStyleHeading3
     
106.                     With .Font
     
107.                         .NameFarEast = "宋体"
     
108.                         .NameAscii = "Times New Roman"
     
109.                         .Size = 14
     
110.                         .Bold = True
     
111.                         .Color = wdColorGreen
     
112.                     End With
     
113.                     .ParagraphFormat.CharacterUnitFirstLineIndent = 1.5
     
114.                 ElseIf .Text Like "摘*要[：:]*" Or .Text Like "关键词[：:]*" Or .Text Like "参考文献[：:]*" Then
     
115.                     With ActiveDocument.Range(Start:=.Start, End:=.Characters(InStr(.Text, "：")).End)
     
116.                         With .Font
     
117.                             .NameFarEast = "黑体"
     
118.                             .Bold = True
     
119.                             .Color = wdColorOrange
     
120.                         End With
     
121.                     End With
     
122.                 End If
     
123.             End With
     
124.         Next
     
125.     End With
     
126. 
     
127.     With Selection
     
128.         With .Font
     
129.             .Kerning = 0
     
130.             .DisableCharacterSpaceGrid = True
     
131.         End With
     
132.         With .ParagraphFormat
     
133.             .SpaceBeforeAuto = False
     
134.             .SpaceAfterAuto = False
     
135.             .SpaceBefore = 0
     
136.             .SpaceAfter = 0
     
137.             .LineSpacing = LinesToPoints(1.5)
     
138.             .AutoAdjustRightIndent = False
     
139.             .DisableLineHeightGrid = True
     
140.             .KeepWithNext = False
     
141.             .KeepTogether = False
     
142.         End With
     
143. 
     
144.         .HomeKey 6
     
145.     End With
     
146. 
     
147.     With ActiveDocument
     
148.         With .Paragraphs(1).Range
     
149.             With .Font
     
150.                 .NameFarEast = "黑体"
     
151.                 .Size = 16
     
152.                 .Bold = True
     
153.                 .Color = wdColorAutomatic
     
154.             End With
     
155.             With .ParagraphFormat
     
156.                 .SpaceBefore = 24
     
157.                 .SpaceAfter = 6
     
158.             End With
     
159.         End With
     
160.         With .Paragraphs(2).Range
     
161.             With .Font
     
162.                 .NameFarEast = "楷体_GB2312"
     
163.                 .Size = 14
     
164.                 .Bold = True
     
165.                 .Color = wdColorBrown
     
166.             End With
     
167.             With .ParagraphFormat
     
168.                 .SpaceBefore = 6
     
169.                 .SpaceAfter = 24
     
170.             End With
     
171.         End With
     
172. 
     
173.         With .Range(Start:=0, End:=.Paragraphs(2).Range.End).ParagraphFormat
     
174.             .CharacterUnitFirstLineIndent = 0
     
175.             .FirstLineIndent = CentimetersToPoints(0)
     
176.             .Alignment = wdAlignParagraphCenter
     
177.         End With
     
178. 
     
179. '        .Content.Font.Color = wdColorAutomatic'去掉注释全文变自动色
     
180.     End With
     
181. End Sub

复制代码

T-T-J

谢谢，非常满意

T-T-J

还请能补充一下标准的页面设置不

T-T-J

我的电脑是WIN7操作系统，office 2010

413191246se

楼主，4 楼代码中，07-27这些行即为 页面设置 代码（默认A4纵向），可以自行修改。
如果想要公文一字线代码，可下载我的《集成版》代码，里面有《插入页码_公文一字线》宏。
另外，代码可以按 F8 键一行一行地自行调试。如有字体、段落格式不明白的地方，录制宏即可。

413191246se

如果常用某宏，可以设置热键 F8 等。

413191246se

楼主，我的《Word2003 & 2007 VBA 自动排版宏》（集成版）2019-7-9，我建议你也可以试着使用其中的代码，可以先试用 2003 的，再试用 2007 的，然后可以自行修改。