如何设置一个Range，等于第一页全部内容？

xiaoyouxi01

如图所示，不管文档一共有几页，我希望获取到第一页的Range。

如果第一页最后一个段落是跨页的，则只选到第一页末的位置。

Dim r as Range
Set r = 第一页

我只要获取到这个Range就可以，这个代码要怎么写比较简洁？求助大家！
test.rar (41.94 KB, 下载次数: 1)

2019-7-5 22:33 上传

点击文件名下载附件

duquancai

1. Sub main()
   
2.     Dim doc As Document, r As Range
   
3.     Set doc = ActiveDocument
   
4.     doc.Range(0, 0).Select
   
5.     Set r = doc.Bookmarks("\Page").Range
   
6. End Sub

复制代码

loquat

1. Function myRange(oDoc As Document, lngPage&) As Range
   
2.     Dim lngStart&, lngEnd&, lngCount&
   
3.     lngCount = oDoc.ComputeStatistics(wdStatisticPages)
   
4.     With oDoc
   
5.         lngStart = .GoTo(wdGoToPage, wdGoToAbsolute, lngPage).Start
   
6.         If lngPage = lngCount Then
   
7.             lngEnd = .Content.End - 1
   
8.         Else
   
9.             lngEnd = .GoTo(wdGoToPage, wdGoToAbsolute, lngPage + 1).Start - 1
   
10.         End If
    
11.         Set myRange = .Range(lngStart, lngEnd)
    
12.     End With
    
13. End Function

复制代码

413191246se

* 楼主 要 Range，我没有；但是提供 3 个小宏，请测试：

1. Sub SelectPage1()
   
2.     If ActiveDocument.Content.Information(wdActiveEndPageNumber) > 1 Then
   
3.         Selection.GoTo What:=wdGoToPage, Which:=wdGoToNext, Name:="2"
   
4.         Selection.HomeKey Unit:=wdStory, Extend:=wdExtend
   
5.     End If
   
6. End Sub
   
7. Sub SelectPage1a()
   
8.     Selection.HomeKey Unit:=wdStory
   
9.     ActiveDocument.Bookmarks("\page").Range.Select
   
10. End Sub
    
11. Sub 选定当前页()
    
12. '假设有第 4 页
    
13.     Selection.GoTo What:=wdGoToPage, Which:=wdGoToNext, Name:="4" '光标跳转到第 4 页
    
14.     ActiveDocument.Bookmarks("\page").Range.Select '选定第 4 页
    
15. End Sub

复制代码

xiaoyouxi01

duquancai 发表于 2019-7-5 23:17

杜老师这段代码很好很简洁！只是存在一个BUG。。。。

如果文档仅1页，就无法选中页末的段落标记，如下图所示：


如果末尾有空行，但是有个shape比如文本框，其锚点在页末处，如下图所示：


此时用这段代码ActiveDocument.Bookmarks("\Page").Range.Select，就无法选中这个文本框。



1-仅1页.rar (12.86 KB, 下载次数: 2)

2019-7-6 10:10 上传

点击文件名下载附件

xiaoyouxi01

loquat 发表于 2019-7-5 23:35

loquat老师的这个函数很好！把页数参数化了，可以选任意页。

但是我有个问题，在计算lngEnd时，为什么有两个“-1”？是出于什么考虑呢？

我实测之后，页末最后一个字符总是没选中。


去掉两个“-1”就正确了。。。

xiaoyouxi01

413191246se 发表于 2019-7-6 00:10
* 楼主 要 Range，我没有；但是提供 3 个小宏，请测试：

谢谢413191246se老师~~没有Range，用Selection也可以~

SelectPage1宏的思路不错，用于多页文档，先到第2页再往回选！

但如果文档只有1页，只能用SelectPage1a宏。而这个宏，跟杜老师的代码一样，存在“没选中最后一个字符”的问题。

duquancai

xiaoyouxi01 发表于 2019-7-6 10:10
杜老师这段代码很好很简洁！只是存在一个BUG。。。。

如果文档仅1页，就无法选中页末的段落标记，如下 ...

对不起，已经没兴趣了。在末尾只增加一句代码就行了。

sylun

楼主如是想学习研究，可查看一下VBA对各个预定义书签的解释。文档最后一个标记是文档结束标记，有特殊作用。将图形对象锚点定位于结束标记会导致不可预知的问题，没有必要，就算是只有一个段落。
也可以查看一下Rectangles集合对象的用法。
另外，对于跨页的表格或域结果，一页的range范围可能有异常，特别是用Select方法时，可能会触发有关对象边界，其显示的选定范围与原来的Range范围可能不一致

xiaoyouxi01

我综合了一下上面几位老师的代码，给出两种的解决方案，可以解决页末字符漏选的问题。
请几位老师帮忙再看看，是否还有什么不足或可以改进的地方。。


方案一：使用Selection，缺点是光标位置会变。

1. Sub SelectFirstPage1()
   
2.     With Selection
   
3.         .HomeKey wdStory
   
4.         .Bookmarks("\Page").Range.Select
   
5.         .Expand wdLine
   
6.     End With
   
7. End Sub

复制代码

方案二：使用Range，不会改变光标位置。

1. Sub SelectFirstPage2()
   
2.     Dim r As Range
   
3.     With ActiveDocument
   
4.         Set r = IIf(.ComputeStatistics(wdStatisticPages) = 1, .Content, .Range(0, .GoTo(wdGoToPage, wdGoToAbsolute, 2).Start))
   
5.         r.Select
   
6.     End With
   
7. End Sub

复制代码

还可以把这段代码做成一个Function，方便调用 ↓↓↓

1. Function GetRangeOfFirstPage() As Range
   
2.     With ActiveDocument
   
3.         Set GetRangeOfFirstPage = IIf(.ComputeStatistics(wdStatisticPages) = 1, .Content, .Range(0, .GoTo(wdGoToPage, wdGoToAbsolute, 2).Start))
   
4.     End With
   
5. End Function
   
6. 
   
7. Sub test()
   
8.     Dim r As Range
   
9.     Set r = GetRangeOfFirstPage
   
10.     r.Select
    
11. End Sub

复制代码