word里如何自动识别字母和数字，识别后再插入其他内容

铁马1980

路过的大神帮帮忙，我整理试卷遇到个问题，我想应该能用vba解决的，但明天就要交稿，没时间从头研究了
要解决的问题：1、将选项ABCDE纵向排列，每个选项一行。
2、在每道题前面加上一串字符和一行文字，再题号后加上“题干”两个字。
完成后的示例如下：

######
题型：单选
6.题干：阳明经头痛的引经药应选用
A.黄芩、蔓荆子
B.柴胡、川芎
C.葛根、白芷
D.羌活、川芎




再次感谢。

小花鹿

查找替换应该能解决                                                                                                            

413191246se

1. Sub aa试卷选项_纵向排列_插入文字()
   
2.     With ActiveDocument
   
3.         '回车符/手动换行符=>段落标记
   
4.         .Content.Find.Execute "[^13^11]", , , 1, , , , , , "^p", 2
   
5. 
   
6.         '删除所有域
   
7.         .Fields.Unlink
   
8. 
   
9.         '列表编号/LISTNUM域转文本
   
10.         .ConvertNumbersToText
    
11. 
    
12.         '半角括号转全角
    
13.         With .Content.Find
    
14.             .Execute "(", , , , , , , , , "（", 2
    
15.             .Execute ")", , , , , , , , , "）", 2
    
16.         End With
    
17. 
    
18.         '全角数字转半角
    
19.         With .Content.Find
    
20.             .ClearFormatting
    
21.             .Text = "^13[0-9０-９]@[、.．]"
    
22.             .Forward = True
    
23.             .MatchWildcards = True
    
24.             Do While .Execute
    
25.                 With .Parent
    
26.                     .Characters.Last.Text = "．"
    
27.                     .CharacterWidth = wdWidthHalfWidth
    
28.                     .Start = .End
    
29.                 End With
    
30.             Loop
    
31.         End With
    
32. 
    
33.         With .Content.Find
    
34.             .Parent.InsertBefore Text:=vbCr
    
35.             .Execute "([!^13])([ABCDE])[.．、]", , , 1, , , , , , "\1^p\2．", 2
    
36.             .Execute "([^13])([ABCDE])[.．、]", , , 1, , , , , , "\1\2．", 2
    
37.             .Execute "([^13])([0-9]@)[.．、]", , , 1, , , , , , vbCr & vbCr & "######" & vbCr & "【题型：单选】\1\2．〖题干〗：", 2
    
38.         End With
    
39. 
    
40. 
    
41. '''以下加粗部分可以屏蔽！
    
42. '''
    
43.         '查找和替换(加粗/黑体)
    
44.         With .Content.Find
    
45.             .ClearFormatting
    
46.             .Text = "题型：单选"
    
47.             With .Replacement
    
48.                 .ClearFormatting
    
49.                 .Font.Bold = True
    
50.                 .Font.Name = "黑体" '本行代码可删除！
    
51.             End With
    
52.             .Execute , Format:=True, Replace:=wdReplaceAll
    
53.         End With
    
54. 
    
55. '''
    
56.         '查找和替换(加粗/黑体)
    
57.         With .Content.Find
    
58.             .ClearFormatting
    
59.             .Text = "〖题干〗："
    
60.             With .Replacement
    
61.                 .ClearFormatting
    
62.                 .Font.Bold = True
    
63.                 .Font.Name = "黑体" '本行代码可删除！
    
64.             End With
    
65.             .Execute , Format:=True, Replace:=wdReplaceAll
    
66.         End With
    
67. 
    
68. '''
    
69.         '查找和替换(加粗/黑体)
    
70.         With .Content.Find
    
71.             .ClearFormatting
    
72.             .Text = "######"
    
73.             With .Replacement
    
74.                 .ClearFormatting
    
75.                 .Font.Bold = True
    
76.                 .Font.Name = "黑体" '本行代码可删除！
    
77.             End With
    
78.             .Execute , Format:=True, Replace:=wdReplaceAll
    
79.         End With
    
80. 
    
81.         .Content.Font.NameAscii = "Times New Roman"
    
82. 
    
83.     End With
    
84. End Sub

复制代码

铁马1980

小花鹿 发表于 2019-6-19 22:49
查找替换应该能解决                                                                                   ...

谢谢，好多套这样的试卷，替换得不停地点来点去

铁马1980

413191246se 发表于 2019-6-20 02:23

谢谢，我试试

铁马1980

413191246se 发表于 2019-6-20 02:23

太好啦，太全了，连全半角标点、排版格式都替我想到了，之前都是一点点替换的，真的很感谢。