求助：羽毛球循环小组赛自动排名计算

apoul119

竞赛办法:小组循环赛通过计算胜次排定名次。如遇两队胜次相同，相互间胜者名次列前。如遇三队或三队以上积分相同，则按各队在小组赛中的净胜（盘、局、分）决定名次，净胜多者列前。如三队或以上净胜一样，则通过抽签决定名次。
求助 如何根据比分，胜次，净胜，自动计算名次？用函数还是VBA都可以，请各位大神指点一二？

D组5个参赛队伍	1	2	3	4	5		胜次	净胜	名次
D1		1:2	0:3	0:3	3:0		1	-4	4
D2	2:1		1:2		3:0		2	3	2
D3	3:0	2:1		2:1			3	5	1
D4	3:0		1:2		3:0		2	5	2
D5	0:3	0:3		0:3			0	-9	5
C组6个参赛队伍	1	2	3	4	5	6	胜次	净胜	名次
C1		0:3	1:2	1:2	1:2		0	-6	6
C2	3:0			2:1	2:1	2:1	4	6	1
C3	2:1			2:1	1:2	2:1	3	2	3
C4	2:1	1:2	1:2			0:3	1	-4	5
C5	2:1	1:2	2:1			2:1	3	2	2
C6		1:2	1:2	3:0	1:2		1	0	4

zpy2

遇两队胜次相同，相互间胜者名次列前。

2队这种有可能，3队胜次一样很少出现的。

micch

1. =MID(REPT(INDIRECT("r"&COLUMN()&"c"&ROW(),)&":",2),3,3)

复制代码

我对比分倒置挺感兴趣的，就是总觉得公式写复杂了
胜次？？？

1. =SUM(N(LEFT(B2:G2)>RIGHT(B2:G2)))

复制代码

净胜

1. =SUM((0&LEFT(B2:G2))-(0&RIGHT(B2:G2)))

复制代码

名次，区域数组

1. =MATCH(ROW(1:5),MOD(LARGE(H2:H6/1%%+(I2:I6+33)/1%+ROW(1:5),ROW(1:5)),10),)

复制代码

这个名次，想用海鲜版主那个frequency技巧，但是整半天弄不出来，还是太笨了

apoul119

micch 发表于 2019-5-17 11:20
我对比分倒置挺感兴趣的，就是总觉得公式写复杂了
胜次？？？
净胜名次，区域数组这个名次，想用海鲜 ...

谢谢大神回复，可否帮忙看看名次？因为要考虑胜负关系，不知道从何下手，这个太小众，网上找不到相关例子，请大神费心帮帮忙？感谢

apoul119

zpy2 发表于 2019-5-17 11:05
遇两队胜次相同，相互间胜者名次列前。

2队这种有可能，3队胜次一样很少出现的。

谢谢老师回复

micch

apoul119 发表于 2019-5-17 11:35
谢谢大神回复，可否帮忙看看名次？因为要考虑胜负关系，不知道从何下手，这个太小众，网上找不到相关例子 ...

主要是不懂羽毛球规则，按模拟结果写的。比分没有两位数可用。净胜球不超过33可用，名次那个是区域数组

apoul119

micch 发表于 2019-5-17 11:37
主要是不懂羽毛球规则，按模拟结果写的。比分没有两位数可用。净胜球不超过33可用，名次那个是区域数组

比赛规则:
小组循环赛通过计算胜次排定名次。
如遇两队胜次相同，相互间胜者名次列前。
如遇三队或三队以上积分相同，则按各队在小组赛中的净胜（盘、局、分）决定名次，净胜多者列前。
大神看看这样行吗，表格里不是模拟数据，都是我手动录进去的比赛数据。

micch

apoul119 发表于 2019-5-17 11:45
比赛规则:
小组循环赛通过计算胜次排定名次。
如遇两队胜次相同，相互间胜者名次列前。

太难了，相互之间胜者，这个条件太难了，想不出什么好办法，用净胜球数排还行，我写的公式没考虑相同胜场的情况下，相互的输赢的情况，直接就考虑净胜球数了。漏题了
以D组为例，D2,D4胜场相同，应该比较相互的输赢，但是这两个还没有比赛呢，所以只好比净胜球数了。如果这俩比赛有结果了，就需要考虑输赢情况了，即使没有平局的可能，只判断输赢都挺难的。如果有3个胜场相同，再比较相互输赢，那就不是复杂了，那就是噩梦了，根本没法比较，因为可能出现循环输赢的情况，感觉就是用代码都无法判断。

apoul119

micch 发表于 2019-5-17 11:51
太难了，相互之间胜者，这个条件太难了，想不出什么好办法，用净胜球数排还行，我写的公式没考虑相同胜场 ...

好的谢谢大神 连大神都这么说了那我就手动录吧 哈哈 感谢

丢丢表格

micch 发表于 2019-5-17 11:20
我对比分倒置挺感兴趣的，就是总觉得公式写复杂了
胜次？？？
净胜名次，区域数组这个名次，想用海鲜 ...

名次

海鲜写法：
=FREQUENCY(H2/1%+I2-H$2:H$6/1%-I$2:I$6,0)
改进写法：
=FREQUENCY(H2/1%+I2-H$2:H$6/1%-I$2:I$6,-1%%)+1