word中如何用宏实现替换功能

jsrgexcelhome · 发表于 2019-5-1 10:35

各位大师：一张试卷排版的时候，总是想把文章中的字母替换成Times New Roman斜体，还有把出现Cambria Math的字体替换Times New Roman，能不能通过宏的形式来实现，要不然每次替换很麻烦。
同时如果把纸张设为A4，左右上下页边距设为2cm，页脚插入自动图文集第x页，共y页，段落设为单倍行距，所有文字（数字和字母除外）设为五号宋体，一起加进去就更好了！恳请哪位大师帮帮忙啊！

jiangxiaoyun · 发表于 2019-5-1 11:09

自己在这里选就是了。

jsrgexcelhome · 发表于 2019-5-1 17:30

谢谢，这个是用替换功能，每套试卷都有这样做，比较麻烦，能不能把它编辑成宏，然后只要运行宏就能完成这么复杂的过程就好了

413191246se · 发表于 2019-5-2 01:17

Sub aaaa试卷排版()
'使用方法：在 Word 界面，按 Alt + F8 打开宏名列表，找到本宏双击（或点击“运行”按钮）即可！也可以设置热键。
With ActiveDocument
'回车符/手动换行符=>段落标记
.Content.Find.Execute "[^13^11]", , , 1, , , , , , "^p", 2
'删除所有域
.Fields.Unlink
'列表编号/LISTNUM域转文本
.ConvertNumbersToText
'半角括号转全角（此部分酌情处理）
' With .Content.Find
' .Execute "(", , , , , , , , , "（", 2
' .Execute ")", , , , , , , , , "）", 2
' End With
'删除空行
Dim i As Paragraph
For Each i In .Paragraphs
If Asc(i.Range) = 13 Then i.Range.Delete
Next
'全选/清除格式/首行缩进2字符
.Select
With Selection
.ClearFormatting
.ParagraphFormat.CharacterUnitFirstLineIndent = 2
End With
'首行设为标题一样式/居中
With .Paragraphs(1).Range
.Style = wdStyleHeading1
.ParagraphFormat.Alignment = wdAlignParagraphCenter
End With
'全文查找英文和字母设置为斜体
With .Content.Find
.ClearFormatting
.Text = "[^1-^12^14-^127]"
.Forward = True
.MatchWildcards = True
Do While .Execute
With .Parent
.Font.Italic = True
.Font.Color = wdColorRed '红色（本行代码可删除！如果不删除，打印时要设全文为黑色！）
.Start = .End
End With
Loop
End With
'页面设置
Dim s As Section
For Each s In .Sections
With s.PageSetup
If .Orientation = wdOrientPortrait Then
.TopMargin = CentimetersToPoints(2)
.BottomMargin = CentimetersToPoints(2)
.LeftMargin = CentimetersToPoints(2)
.RightMargin = CentimetersToPoints(2)
.PageWidth = CentimetersToPoints(21)
.PageHeight = CentimetersToPoints(29.7)
Else
.TopMargin = CentimetersToPoints(2)
.BottomMargin = CentimetersToPoints(2)
.LeftMargin = CentimetersToPoints(2)
.RightMargin = CentimetersToPoints(2)
.PageWidth = CentimetersToPoints(29.7)
.PageHeight = CentimetersToPoints(21)
End If
.HeaderDistance = CentimetersToPoints(1.5)
.FooterDistance = CentimetersToPoints(1.75)
End With
Next
End With
'页码设置
With Selection
ActiveWindow.ActivePane.View.SeekView = wdSeekCurrentPageFooter
.ParagraphFormat.Alignment = wdAlignParagraphCenter
NormalTemplate.AutoTextEntries("第 X 页共 Y 页").Insert Where:=Selection.Range, RichText:=True
ActiveWindow.ActivePane.View.SeekView = wdSeekMainDocument
.HomeKey Unit:=wdStory
End With
End Sub

复制代码

相见是缘8 · 发表于 2019-5-2 11:25

本帖最后由相见是缘8 于 2019-5-2 11:27 编辑

413191246se 发表于 2019-5-2 01:17

With ActiveDocument
With .Paragraphs(1).Range
.ParagraphFormat.Alignment = wdAlignParagraphCenter
End With

第一段作为文章的标题，居中后想变为红色加粗，代码怎么改？请老师指教，谢谢！

daibao88 · 发表于 2019-5-2 12:40

相见是缘8 发表于 2019-5-2 11:25
With ActiveDocument
With .Paragraphs(1).Range
.ParagraphFormat.Alignment = wdAlignPar ...

With ActiveDocument
  With .Paragraphs(1).Range
      .ParagraphFormat.Alignment = wdAlignParagraphCenter
      .Font.ColorIndex = wdRed
      .Font.Bold = True
End With
End With
录个宏，就明白了

相见是缘8 · 发表于 2019-5-2 15:14

daibao88 发表于 2019-5-2 12:40
With ActiveDocument
With .Paragraphs(1).Range
.ParagraphFormat.Alignment = wdAlignPar ...

感谢老师指教！谢谢！

jsrgexcelhome · 发表于 2019-5-2 15:41

谢谢老师，辛苦了，我运行了一下就是字母出现了斜体，符合要求但是数字也出现斜体，能不能数字还是time New Roman但不是斜体，同时加上 Cambria Math的字体替换Times New Roman就好了，首行的字体能不能设置成四号楷体居中，第二行设置成小三黑体居中行距设为单倍行距就完美了，能不能再修改一下！

413191246se · 发表于 2019-5-3 01:10

Sub aaaa试卷排版_v2019_5_3()
'使用方法：在 Word 界面，按 Alt + F8 打开宏名列表，找到本宏双击（或点击“运行”按钮）即可！也可以设置热键。
With ActiveDocument
'回车符/手动换行符=>段落标记
.Content.Find.Execute "[^13^11]", , , 1, , , , , , "^p", 2
'删除所有域
.Fields.Unlink
'列表编号/LISTNUM域转文本
.ConvertNumbersToText
'半角括号转全角（此部分酌情处理）
' With .Content.Find
' .Execute "(", , , , , , , , , "（", 2
' .Execute ")", , , , , , , , , "）", 2
' End With
'删除空行
Dim i As Paragraph
For Each i In .Paragraphs
If Asc(i.Range) = 13 Then i.Range.Delete
Next
'全选/清除格式/首行缩进2字符
.Select '全选
With Selection
.ClearFormatting '清除格式（全部字符变为五号字体，汉字变为宋体，字母和数字变为 Times New Roman）
'取消网格
With .Font
.Kerning = 0
.DisableCharacterSpaceGrid = True
End With
With .ParagraphFormat
.CharacterUnitFirstLineIndent = 2 '首行缩进2字符
.AutoAdjustRightIndent = False
.DisableLineHeightGrid = True
End With
End With
'首行：四号/楷体/居中
With .Paragraphs(1).Range
.Style = wdStyleHeading1
With .Font
.NameFarEast = "楷体_GB2312" '如果是Win7系统，请将字体改为“楷体”（即删除“_GB2312”）
.Size = 14 '四号（14磅）
End With
.ParagraphFormat.Alignment = wdAlignParagraphCenter '居中
End With
'次行：小三/黑体/居中/单倍行距
With .Paragraphs(2).Range
.Style = wdStyleSubtitle
With .Font
.NameFarEast = "黑体"
.Size = 15 '小三（15磅）
.Bold = False '不加粗（如果想加粗，删除本行即可）
End With
With .ParagraphFormat
.Alignment = wdAlignParagraphCenter '居中
.Space1 '单倍行距
End With
End With
'取消第1/2段落的段落间距
With .Range(Start:=0, End:=.Paragraphs(2).Range.End).ParagraphFormat
.SpaceBefore = 0
.SpaceAfter = 0
End With
'字母设为斜体（全文查找）
With .Content.Find
.ClearFormatting
.Text = "[^1-^12^14-^47^58-^127]"
.Forward = True
.MatchWildcards = True
Do While .Execute
With .Parent
.Font.Italic = True
.Font.Color = wdColorRed '红色（本行代码可删除！如果不删除，打印时要设全文为黑色！）
.Start = .End
End With
Loop
End With
'页面设置
Dim s As Section
For Each s In .Sections
With s.PageSetup
If .Orientation = wdOrientPortrait Then
.TopMargin = CentimetersToPoints(2)
.BottomMargin = CentimetersToPoints(2)
.LeftMargin = CentimetersToPoints(2)
.RightMargin = CentimetersToPoints(2)
.PageWidth = CentimetersToPoints(21)
.PageHeight = CentimetersToPoints(29.7)
Else
.TopMargin = CentimetersToPoints(2)
.BottomMargin = CentimetersToPoints(2)
.LeftMargin = CentimetersToPoints(2)
.RightMargin = CentimetersToPoints(2)
.PageWidth = CentimetersToPoints(29.7)
.PageHeight = CentimetersToPoints(21)
End If
.HeaderDistance = CentimetersToPoints(1.5)
.FooterDistance = CentimetersToPoints(1.75)
End With
Next
End With
'页码设置
With Selection
ActiveWindow.ActivePane.View.SeekView = wdSeekCurrentPageFooter
.ParagraphFormat.Alignment = wdAlignParagraphCenter
NormalTemplate.AutoTextEntries("第 X 页共 Y 页").Insert Where:=Selection.Range, RichText:=True
ActiveWindow.ActivePane.View.SeekView = wdSeekMainDocument
.HomeKey Unit:=wdStory
End With
'''
'''
'''
'Cambria Math字体全部替换为 Times New Roman 字体
'其实先前的《清除格式 .ClearFormatting》命令已经把所有西文变为 Times New Roman 字体，但是，楼主既然要求替换字体
'我就用下面的代码完成替换了，但是，我认为其实下面的代码是不必要的！另外，我的电脑上无此字体。
With ActiveDocument.Content.Find
.ClearFormatting
.Font.Name = "Cambria Math"
With .Replacement
.ClearFormatting
.Font.Name = "Times New Roman"
End With
.Execute FindText:="", ReplaceWith:="", Format:=True, Replace:=wdReplaceAll
End With
End Sub

复制代码

jsrgexcelhome · 发表于 2019-5-4 18:23

谢谢老师，我运行了一下已经很不错了，以后试卷的排版很方便了，就是不知道第一行设的是楷体，为什么运行了还是黑体，这个当然是个小问题啦，真是万分感谢老师的指导！

		自动登录	找回密码
密码			免费注册

[求助] word中如何用宏实现替换功能

评分