power query 制作工资条

fxl447098457

常见的需求写一写,基本注释大都有标注：

1. let
   
2.     源 = Excel.CurrentWorkbook(){[Name="表1"]}[Content],
   
3. 
   
4.     data=Table.ToRows(源),    //工资数据的列表
   
5. 
   
6.     header=Table.ColumnNames(源),    //取得标题的列表
   
7.     col=List.Count(header),    //标题的列数,用于后面扩展null的列数
   
8. 
   
9.     res=List.TransformMany({header},each data,(x,y)=>#table(x,{x,y,List.Repeat({null},col)})),
   
10. 
    
11.     //遍历每行数据结合header,生成分表。x代表标题,y代表data的每个元素.最后List.Repeat({null},col)填充一个空行.
    
12.    
    
13.     res1=Table.Skip(Table.Combine(res),1)    //第一行由于多了一个标题,跳过一行
    
14. in
    
15.     res1

复制代码

制作工资条.zip (21.01 KB, 下载次数: 181)

2019-1-13 12:46 上传

点击文件名下载附件

jiangxiaoyun

学习一下，mark

飞天篮球猪

在你的基础上改一下List.TransformMany里的写法
可以把最后两步，res和res1，合并成一步，

1. = #table(col,List.TransformMany(data,each {header,_,List.Repeat({null},col)},(x,y)=>y))

复制代码

fxl447098457

飞天篮球猪 发表于 2019-1-13 14:29
在你的基础上改一下List.TransformMany里的写法
可以把最后两步，res和res1，合并成一步，

嗯，你这个更精炼。。

157947372

let
    源 = Excel.CurrentWorkbook(){[Name="工资表"]}[Content],
    自定义1 = Table.TransformRows( 源,each Table.Transpose(Record.ToTable(_))),
    转换为表 = Table.FromList(自定义1, Splitter.SplitByNothing(), null, null, ExtraValues.Error),
    #"展开的“Column1”" = Table.ExpandTableColumn(转换为表, "Column1", {"Column1", "Column2", "Column3", "Column4", "Column5", "Column6", "Column7", "Column8"}, {"Column1.1", "Column2", "Column3", "Column4", "Column5", "Column6", "Column7", "Column8"})
in
    #"展开的“Column1”"

libo5563

let
    源 = Excel.CurrentWorkbook(){[Name="表1"]}[Content],
    降级的标题 = Table.DemoteHeaders(源),
    更改的类型 = Table.TransformColumnTypes(降级的标题,{{"Column1", type text}, {"Column2", type text}, {"Column3", type text}, {"Column4", type text}, {"Column5", type any}, {"Column6", type any}, {"Column7", type any}, {"Column8", type any}, {"Column9", type any}, {"Column10", type any}}),
    已添加自定义 = Table.AddColumn(更改的类型, "自定义", each _),
    删除的其他列 = Table.SelectColumns(已添加自定义,{"自定义"}),
    已添加自定义1 = Table.AddColumn(删除的其他列, "自定义.1", each {1..3}),
    aa = Table.ExpandListColumn(已添加自定义1, "自定义.1"),
    已添加自定义2 = Table.AddColumn(aa, "自定义.2", each if [自定义.1]=1 then aa[自定义]{0} else if [自定义.1]=2  then [自定义] else null),
    删除的其他列1 = Table.SelectColumns(已添加自定义2,{"自定义.2"}),
    #"展开的“自定义.2”" = Table.ExpandRecordColumn(删除的其他列1, "自定义.2", {"Column1", "Column2", "Column3", "Column4", "Column5", "Column6", "Column7", "Column8", "Column9", "Column10"}, {"Column1", "Column2", "Column3", "Column4", "Column5", "Column6", "Column7", "Column8", "Column9", "Column10"}),
    删除的顶端行 = Table.Skip(#"展开的“自定义.2”",3),
    提升的标题 = Table.PromoteHeaders(删除的顶端行, [PromoteAllScalars=true]),
    更改的类型1 = Table.TransformColumnTypes(提升的标题,{{"工号", type text}, {"部门", type text}, {"姓名", type text}, {"职务", type text}, {"底薪", type any}, {"平时加班", type any}, {"节假日加班", type any}, {"应发金额", type any}, {"扣除", type any}, {"实发金额", type any}})
in
    更改的类型1

补充内容 (2020-11-24 17:31):
突然看到自己写的丑代码，不忍再看下去了

libo5563

自己以前写的老代码实在没法看

shaowu459

libo5563 发表于 2020-11-24 20:31
自己以前写的老代码实在没法看

原来是点的代码一年涨的很厉害了（大拇指）

1059417122

1059417122