word vba怎样才能选择不包含表格的文字

haha12339 · 发表于 2018-11-18 09:52

在word中同时包含有文字和表格，表格可用ActiveDocument.Tables选择，但表格以外的文字部分如何选择？并且对该部分文字选择后进行修改又不会影响到表格内的文字？刚学word vba，请高人指点，谢谢！！！

413191246se · 发表于 2018-11-18 23:51

* 楼主，你好！刚学 VBA 如果使用的是 Word2003 的话，强烈建议反复研读《Microsoft Office Word 2003 Visual Basic 参考》，即：微软官方 Word2003VBA 帮助这个文档，它的文件名是：VBAWD10.CHM，具体位置：C:\Program Files\Microsoft Office\OFFICE11\2052 文件夹中；或搜索网络也可得到。
* 关于你提出的问题，我有一个解决方案，供你参考，另外，你看没看到我的帖子《Word2003VBA通用模板宏》，如果你也使用 Word2003 版本，建议下载我的宏代码，会帮助到你的。
* 楼主，如果你使用的是 Word2003/2007，请按 ALT+F11 复制本代码到你的 VBE 中，按 F8 键可逐语句调试。
* 下面是 Word2003VBA 公文自动排版（一键）部分代码，请新建包含文本和表格的文档试用之：

Sub 公文()
Dim doc As Document, t As Table, j As Long, k As Long
Set doc = ActiveDocument
ActiveWindow.View.Type = wdPrintView
With doc
With .Content.Find
.Execute "^13", , , , , , , , , "^p", 2
.Execute "^11", , , , , , , , , "^p", 2
.Parent.ListFormat.ConvertNumbersToText
End With
If .Tables.Count = 0 Then
.Select
正文样式
Else
'取消环绕
For Each t In .Tables
With t.Range
With .Rows
.WrapAroundText = False
.Alignment = wdAlignRowCenter
End With
.Font.Name = "仿宋_GB2312"
.Font.Color = wdColorPink
End With
Next
'首表上方
If .Paragraphs(1).Range.Information(wdWithInTable) = False Then
.Range(Start:=0, End:=.Tables(1).Range.Start).Select
正文样式
End If
'表间循环
k = .Tables.Count
For j = 1 To k
If j = k Then Exit For
.Range(Start:=.Tables(j).Range.End, End:=.Tables(j + 1).Range.Start).Select
正文样式
Next j
'末表下方
.Range(Start:=.Tables(k).Range.End, End:=.Content.End).Select
正文样式
'表下加空
For Each t In .Tables
With t.Range.Next
If Asc(.Text) <> 13 Then .InsertParagraphBefore: .MoveEnd 1, -1
.Font.Size = 4
End With
Next
End If
End With
Selection.HomeKey Unit:=wdStory
End Sub
Sub 正文样式()
Dim i As Paragraph, r As Range
With Selection
.ClearFormatting
CommandBars.FindControl(ID:=122).Execute
CommandBars.FindControl(ID:=123).Execute
With .Font
.Name = "仿宋_GB2312"
.Size = 16
.Color = wdColorBlue
.Kerning = 0
.DisableCharacterSpaceGrid = True
End With
With .ParagraphFormat
.LineSpacing = LinesToPoints(1.5)
.CharacterUnitFirstLineIndent = 2
.AutoAdjustRightIndent = False
.DisableLineHeightGrid = True
End With
Set r = .Range
For Each i In r.Paragraphs
If Asc(i.Range) = 13 Then i.Range.Delete
Next
End With
End Sub

复制代码

ming0018 · 发表于 2018-11-19 08:52

选择所有表格之后，反选。

413191246se · 发表于 2018-11-19 17:07

楼上老师，反选用哪条语句？

ming0018 · 发表于 2018-11-19 17:55

413191246se 发表于 2018-11-19 17:07
楼上老师，反选用哪条语句？

.SelectAllEditableRanges (wdEditorEveryone) '选择所有可编辑区域
.DeleteAllEditableRanges (wdEditorEveryone) '删除所有可编辑区域

413191246se · 发表于 2018-11-20 00:14

虽然 5 楼 ming0018 老师提供的代码已经包含在《表格全选》宏中，我也有这个宏，但是，经不断尝试，竟然误打误撞成功解决了《表外文字选定》这个专项问题（虽然是循环遍历所有段落，但竟然比我 2 楼的代码“块”选择快了一些），但不知可靠不可靠，大家请试试吧！

Sub 选定表外文字()
Dim i As Paragraph
With ActiveDocument
For Each i In .Paragraphs
If Not i.Range.Information(12) Then i.Range.Editors.Add -1
Next
.SelectAllEditableRanges -1
.DeleteAllEditableRanges -1
End With
'Sub 正文样式()
With Selection
.ClearFormatting
CommandBars.FindControl(ID:=122).Execute
CommandBars.FindControl(ID:=123).Execute
With .Font
.Name = "仿宋_GB2312"
.Size = 16
.Color = wdColorBlue
.Kerning = 0
.DisableCharacterSpaceGrid = True
End With
With .ParagraphFormat
.LineSpacing = LinesToPoints(1.5)
.CharacterUnitFirstLineIndent = 2
.AutoAdjustRightIndent = False
.DisableLineHeightGrid = True
End With
End With
End Sub

复制代码

haha12339 · 发表于 2018-11-20 10:58

413191246se 发表于 2018-11-20 00:14
虽然 5 楼 ming0018 老师提供的代码已经包含在《表格全选》宏中，我也有这个宏，但是，经不断尝试，竟然误 ...

感谢老师指点，结合您说的帮助文档，把发的代码的意思弄明白了。想再请教个问题，若是在word文档中，有文字，有表格，有图片，那么该如何去选择表外和图片外的文字呢？能否用Range.Information来判断？

haha12339 · 发表于 2018-11-20 11:57

感谢413191246se老师指点，结合您说的帮助文档，把发的代码的意思弄明白了。运行代码出现了个问题，在第二次发的代码中'Sub 正文样式()上面加入 MsgBox Selection，运行后只显示了最后一个表格下方的文字，而不是全部的表外文字，这是怎么回事？再请教个问题，若word中同时存在文字，表格，图片，该如何选择图片和表格以外的文字？

413191246se · 发表于 2018-11-21 19:36

楼主，请提供一个包含文字、表格、图片（图形）的示例文档，大家共同研究，我从未考虑包含图片这种情况，因为觉得图片也是占用一个字符的位置。

ke3088 · 发表于 2019-3-14 00:24

413191246se 发表于 2018-11-20 00:14
虽然 5 楼 ming0018 老师提供的代码已经包含在《表格全选》宏中，我也有这个宏，但是，经不断尝试，竟然误 ...

413191246se老师，好不容易找见不包含表格的代码，太感谢您啦！如果在指定段落间（如第5段至第12段之间）选择没有表格的文字，怎么修改代码？向您请教。谢谢！

		自动登录	找回密码
密码			免费注册

[求助] word vba怎样才能选择不包含表格的文字

评分