SUMIFS函数从日期中提取月份并按月分类汇总

讲古派

数据区域						计算区域
付款日期	类别	公司名称	收入	辅助列		应收款	4月	5月	6月	7月
2018/4/28	应收款	张总	22000	4月		陈总	0	3960	58629.8	0
2018/4/30	应收款	刘总	20000	4月		赵总	0	8700.9	1114.4	0
2018/5/2	应收款	陈总	3960	5月		张总	22000	12941.5	574	0
2018/5/28	应收款	赵总	8700.9	5月		刘总	20000	30197	2156	0
2018/5/31	应收款	张总	12941.5	5月		SUMIFS($D:$D,$C:$C,$G6,$E:$E,H$2)
2018/5/31	应收款	刘总	30197	5月
2018/6/7	应收款	陈总	58629.8	6月		有没有办法把左边的辅助列去掉，直接调用A列日期
2018/6/8	应收款	赵总	1114.4	6月
2018/6/8	应收款	张总	574	6月
2018/6/8	应收款	刘总	2156	6月
			MONTH(A12)&"月"

左表是数据源，  右表我想通过SUMIFS 来实现按月汇总，  目前水平有限，只能通过辅助列来实现，有没有办法直接调用A列的日期来实现呢。

gykg-excel

=SUMPRODUCT(($C$2:$C$11=$G2)*(MONTH($A$2:$A$11)=--LEFT(H$1,1))*$D$2:$D$11)

ttyong

=SUMPRODUCT(($C$2:$C$20=$G2)*(MONTH($A$2:$A$20)=--SUBSTITUTE(H$1,"月",""))*$D$2:$D$20)

问山

一定要SUMIFS的话
SUMIFS($D$2:$D$11,$C$2:$C$11,$G2,$A$2:$A$11,">="&DATE(2018,SUBSTITUTE(H$1,"月",),1),$A$2:$A$11,"<="&DATE(2018,SUBSTITUTE(H$1,"月",)+1,0))

袁勇

H2：

1. =SUMIFS($D:$D,$C:$C,$G3,$A:$A,">="&DATE(2018,SUBSTITUTE(H$2,"月",),1),$A:$A,"<="&DATE(2018,SUBSTITUTE(H$2,"月",)+1,0))

复制代码

123-456789

=SUMIFS($D$2:$D$11,$C$2:$C$11,$G3,$A$2:$A$11,">="&DATE(2018,SUBSTITUTE(H$2,"月",),1),$A$2:$A$11,"<="&EOMONTH(DATE(2018,SUBSTITUTE(H$2,"月",),1),0))       其实不必要用函数来做，简单的一个数据透视表不就搞定了吗？

讲古派

感谢楼上5位，你们的公式都达到了我的要求，由其是这个函数SUMPRODUCT，又让我学了一招。

2801959927

123-456789 发表于 2018-11-9 15:52
=SUMIFS($D$2:$D$11,$C$2:$C$11,$G3,$A$2:$A$11,">="&DATE(2018,SUBSTITUTE(H$2,"月",),1),$A$2:$A$11,"

问一下，数据透视表如果不加辅助列，怎样按照月份来汇总？

2801959927

直接用Sum函数也是可以的
=SUM((MONTH($A$2:$A$11)=1*LEFT(H$1,1))*($C$2:$C$11=$G2)*$D$2:$D$11)

aaaadddddd

gykg-excel 发表于 2018-11-9 14:44
=SUMPRODUCT(($C$2:$C$11=$G2)*(MONTH($A$2:$A$11)=--LEFT(H$1,1))*$D$2:$D$11)

--LEFT(H$1,1),这个方法确实好用，但是“--“”这两个减号是什么意思，没理解