excel 2016 如何生成 access 2000类型 文件

spiritsniper

求助各位大大，2016版的excel 使用
CatlogObject.Create ("provider = Microsoft.ACE.OLEDB.12.0;data source=" & f) '创建的是access 07-16类型的数据库文件

使用
CatlogObject.Create ("provider = Microsoft.ACE.OLEDB.4.0;data source=" & f) '想用OLEDB 4.0创建access 2000类型mdb文件，却提示类未注册
已经引入Microsoft ADO Ext. 2.8 for DDL Security，对组件如何生效这块不太理解
系统是64位的，跟这个有关系么？
求助各位大大 @zhaogang1960

xyxcc177

64位系统不支持oledb

spiritsniper

xyxcc177 发表于 2018-9-16 09:50
64位系统不支持oledb

我用oledb 12 正常

spiritsniper

解决方案没找到，只能用其他方案替代一下
桌面右键新建一个access 2000类型文件，每次更新数据，删除里面所有信息，再写入新的信息，不新建整个数据库文件

zhaogang1960

请参考：

Sub setDatabase()
    Dim CatlogObject As New ADOX.Catalog
    Dim Mypath As String
    Dim myTable As String
    Dim SQL As String
    Mypath = ThisWorkbook.Path & "\测试数据库.mdb"
    myTable = "测试数据表"
    If Dir(Mypath) <> "" Then Kill Mypath
    CatlogObject.Create "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Mypath
'    CatlogObject.Create "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Mypath & ";Jet OLEDB:Database Password=123;" '带密码
'以下是创建数据表，可选
    SQL = "CREATE TABLE " & myTable _
        & "(员工编号 long not null primary key,姓名 text(20) not null," _
        & "性别 text(1) not null,民族 text(20) not null,部门 text(20) not null,职务 text(20)," _
        & "电话 text(20),学历 text(20),出生日期 date not null,籍贯 text(20),简历 longtext,照片 longbinary)"
    CatlogObject.ActiveConnection.Execute SQL
    MsgBox "创建数据库成功！" & vbCrLf _
         & "数据库文件名为：" & Mypath & vbCrLf & "数据表名称为：" & myTable & vbCrLf _
         & "保存位置：" & ThisWorkbook.Path, vbOKOnly + vbInformation, "创建数据库"
    Set CatlogObject = Nothing
End Sub




下面程序用来测试新建数据库文件中的表信息
Sub getTables() '获取数据库所有表的信息
    Dim CatlogObject As New ADOX.Catalog
    Dim myTb As ADOX.Table
    Dim Mypath As String
    Dim i As Integer
    Mypath = ThisWorkbook.Path & "\测试数据库.mdb"
    CatlogObject.ActiveConnection = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Mypath
'    CatlogObject.ActiveConnection = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Mypath & ";Jet OLEDB:Database Password=123;" '带密码
    Cells.ClearContents
    Cells(1, 1) = "数据表名"
    Cells(1, 2) = "类型"
    i = 1
    For Each myTb In CatlogObject.Tables
        i = i + 1
        Cells(i, 1) = myTb.Name
        Cells(i, 2) = myTb.Type
    Next
    Set myTb = Nothing
    Set CatlogObject = Nothing
End Sub

zhaogang1960

刚才上传代码，提示需要审核，制作了一个Excel2016文件，请测试：
动态创建Access2000数据库文件.rar (18.55 KB, 下载次数: 40)

2018-10-14 20:38 上传

点击文件名下载附件