msgbox无法正常显示单元格中的内容如何处理？

renahu

把英[fɪʃ]美[fɪʃ] 放入cells(1,1)
msgbox cells(1,1)

renahu

英[fɪʃ]美[fɪʃ]   无解吗？

joforn

新增一个模块，把下面的代码粘贴进去，然后再运行你自己的代码测试：

1. 
   
2. Option Explicit
   
3. '>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
   
4. '>>>>>>>>   Author:     Joforn                            <<<<<<<<<<<<<<<<<<
   
5. '>>>>>>>>   Email:      Joforn@sohu.com                   <<<<<<<<<<<<<<<<<<
   
6. '>>>>>>>>   QQ:         42978116                          <<<<<<<<<<<<<<<<<<
   
7. '>>>>>>>>   Last time : 10/31/2015                        <<<<<<<<<<<<<<<<<<
   
8. '<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
   
9. 
   
10. 
    
11. #If VBA7 Then
    
12.   Private Declare PtrSafe Function MessageBoxTimeout Lib "user32" Alias "MessageBoxTimeoutW" ( _
    
13.     ByVal hWnd As Long, ByVal lpText As LongPtr, _
    
14.     ByVal lpCaption As LongPtr, ByVal wType As Long, _
    
15.     ByVal wLange As Long, ByVal dwTimeout As Long) As Long
    
16. #Else
    
17.   Private Declare Function MessageBoxTimeout Lib "user32" Alias "MessageBoxTimeoutW" ( _
    
18.     ByVal hWnd As Long, ByVal lpText As Long, _
    
19.     ByVal lpCaption As Long, ByVal wType As Long, _
    
20.     ByVal wLange As Long, ByVal dwTimeout As Long) As Long
    
21. #End If
    
22. Private lngTimeOut As Long
    
23. 
    
24. Public Property Let MsgboxTimeOutSecond(ByVal TimeOut As Long)
    
25.   On Error GoTo LetSecondError
    
26.   If TimeOut < 0 Then
    
27.     lngTimeOut = 0
    
28.   Else
    
29.     lngTimeOut = TimeOut * 1000
    
30.   End If
    
31.   Exit Property
    
32. LetSecondError:
    
33.   lngTimeOut = &H7FFFFFFF
    
34. End Property
    
35. 
    
36. Public Property Let MsgboxTimeOut(ByVal TimeOut As Long)
    
37.   If TimeOut < 0 Then
    
38.     lngTimeOut = 0
    
39.   Else
    
40.     lngTimeOut = TimeOut
    
41.   End If
    
42. End Property
    
43. 
    
44. Public Property Get MsgboxTimeOut() As Long
    
45.   MsgboxTimeOut = lngTimeOut
    
46. End Property
    
47. 
    
48. Public Function Msgbox(ByVal Prompt As String, Optional ByVal Buttons As VbMsgBoxStyle = vbOKOnly, _
    
49.                  Optional ByVal Title As String = vbNullString, Optional ByVal TimeOut As Long = -1&, _
    
50.                  Optional ByVal LangeId As Long = 0&) As VbMsgBoxResult
    
51.   'TimeOut以毫秒为单位，1 second = 1000 ms,TimeOut值为0时表示不自动返回,为负值时表示使用全局默认值
    
52.   '如果信息框弹出后，用户未点击任何按钮，将返回3200,但如果Buttons的按钮值为VbOkOnly时，返回VbOk
    
53.   
    
54.   If TimeOut < 0 Then TimeOut = lngTimeOut
    
55.   If Len(Title) < 1 Then Title = Application.Caption
    
56.   Msgbox = MessageBoxTimeout(Application.hWnd, StrPtr(Prompt), StrPtr(Title), Buttons Or &H2000&, LangeId, TimeOut)
    
57. End Function
    

复制代码

renahu

joforn 发表于 2018-7-29 21:37
新增一个模块，把下面的代码粘贴进去，然后再运行你自己的代码测试：

这里使用API，不错，只是中间的三个函数起什么作用呢？去掉也能用，还有就是就是使用过程中表中的其他控件会自动被屏蔽掉，点击确定msgbox关闭后才重新显示出来，不知能否不屏蔽其他控件？再有就是我发现使用textbox控件也会出现特殊字符无法显示问题，只不过是点击控件正常显示，再点击表格就无法正常显示，不知能否解决？

joforn

renahu 发表于 2018-7-30 08:00
这里使用API，不错，只是中间的三个函数起什么作用呢？去掉也能用，还有就是就是使用过程中表中的其他控 ...

前面三个函数是为了全局配置所有Msgbox自动关闭时间（因为一般的代码中Msgbox后两个参数都未被使用到），当在使用MsgboxTimeOutSecond=2后，所有的Msgbox都会在显示两秒后自动退出，而不用再去修改每一个Msgbox参数成Msgbox "提示信息","标题",2000。
另外，Msgbox最后一个参数是语言ID。

另外TextBox不能用这种简单的方式。

renahu

renahu

joforn 发表于 2018-7-30 08:31
前面三个函数是为了全局配置所有Msgbox自动关闭时间（因为一般的代码中Msgbox后两个参数都未被使用到）， ...

谢谢，关于api运行期间其他控件被屏蔽的问题是不是也不好解决？

joforn

renahu 发表于 2018-7-30 09:05
谢谢，关于api运行期间其他控件被屏蔽的问题是不是也不好解决？

请上传的附件测试，没有测试，不好给你建议。

renahu

joforn 发表于 2018-7-30 09:27
请上传的附件测试，没有测试，不好给你建议。

这个网站这两天有问题，发图发附件都发不出来，等会儿看看能不能发

renahu

终于发上来了