如何调用工作表SUMIF函数

huaxia5qiannian

Sub gj23w98()
Dim d, sht As Worksheet, arr, i As Long, s As String   '定义变量
    Set d = CreateObject("scripting.dictionary")    '创建字典
    For Each sht In Sheets    '循环
         If sht.Name <> ActiveSheet.Name And InStr(sht.Name, "-") Then '判断工作表是否为当前活动工作表且遍历包含带有"-"的工作表
            With sht
                arr = .[a1].CurrentRegion   '获取带有"-"工作表的已用区域
                For i = 2 To UBound(arr)   '循环
                    s = arr(i, 1) & arr(i, 7)  '合并带有"-"工作表的A列和G列的值
                    d(s) = arr(i, 9) '向字典存入数据
                Next
            End With
        End If
    Next
    brr = [a1].CurrentRegion  '获取活动工作表的已用区域
    For i = 4 To UBound(brr)
        For j = 16 To UBound(brr, 2)
            s = brr(3, j) & brr(i, 2) '合并活动工作表的B4和P3的值
            If d.exists(s) Then brr(i, j) = d(s) '判断带有"-"工作表合并后的值是否被包含在活动工作表的B4和P3的值内
        Next
    Next
    [a1].CurrentRegion = brr
End Sub
说明：目前我的代码已经实现了“生产7月”工作表每天的入库量与 以日期命名的工作表对应日期和对应工单单号的引用，但是加入以日期命名的工单的工单单号有多比是重复的，我想达到将这重复的多笔工单对应的入库数量累加起来，再引用到“生产7月”工作表里的相应日期列，请教大神：代码该如何优化？

chis3

WorksheetFunction.SumIf
??

huaxia5qiannian

chis3 发表于 2018-7-23 10:57
WorksheetFunction.SumIf
??

是的，可是我不知道代码要怎么写！

huaxia5qiannian

huaxia5qiannian 发表于 2018-7-23 10:58
是的，可是我不知道代码要怎么写！

请大神帮忙添加一下代码

蓝桥玄霜

把d(s) = arr(i, 9)改为：
d(s) = d(s)+arr(i, 9)
即可。

huaxia5qiannian

蓝桥玄霜 发表于 2018-7-23 11:07
把d(s) = arr(i, 9)改为：
d(s) = d(s)+arr(i, 9)
即可。

先谢谢老师，我测试一下！

chis3

huaxia5qiannian 发表于 2018-7-23 10:58
是的，可是我不知道代码要怎么写！

這不叫作調用
是實現sumif的效果啊

huaxia5qiannian

蓝桥玄霜 发表于 2018-7-23 11:07
把d(s) = arr(i, 9)改为：
d(s) = d(s)+arr(i, 9)
即可。

非常感谢蓝桥老师，太强大了，赞一个！

huaxia5qiannian

chis3 发表于 2018-7-23 11:21
這不叫作調用
是實現sumif的效果啊

我是小白一个，刚接触VBA，只知道这个思路，但不知道要怎么编程！谢谢，老师们的耐心解答，万分感谢！

lsc900707

qq收到，只要修改一下：

1. Sub gj23w98()
   
2. Dim d, sht As Worksheet, arr, i As Long, s As String   '定义变量
   
3.     Set d = CreateObject("scripting.dictionary")    '创建字典
   
4.     For Each sht In Sheets    '循环
   
5.          If sht.Name <> ActiveSheet.Name And InStr(sht.Name, "-") Then '判断工作表是否为当前活动工作表且遍历包含带有"-"的工作表
   
6.             With sht
   
7.                 arr = .[a1].CurrentRegion   '获取带有"-"工作表的已用区域
   
8.                 For i = 2 To UBound(arr)   '循环
   
9.                     s = arr(i, 1) & arr(i, 7)  '合并带有"-"工作表的A列和G列的值
   
10.                     d(s) = d(s) + arr(i, 9) '向字典存入数据
    
11.                 Next
    
12.             End With
    
13.         End If
    
14.     Next
    
15.     brr = [a1].CurrentRegion  '获取活动工作表的已用区域
    
16.     For i = 4 To UBound(brr)
    
17.         For j = 16 To UBound(brr, 2)
    
18.             s = brr(3, j) & brr(i, 2) '合并活动工作表的B4和P3的值
    
19.             If d.exists(s) Then brr(i, j) = d(s) '判断带有"-"工作表合并后的值是否被包含在活动工作表的B4和P3的值内
    
20.         Next
    
21.     Next
    
22.     [a1].CurrentRegion = brr
    
23. End Sub
    

复制代码