VB程序运行过程，想优化

longming3

循环嵌套太多，速度自然慢。可以k对k1循环，先记下重复的位置，然后c对c1循环，记下重复位置，两个位置重复，就添加颜色标注，这样的思路应该就快很多了

山菊花

Sub 核对()
    Dim r&, r1&, k&, k1& '声明变量
    Dim s$, s1$
    Dim Arr(), Brr() '声明数组变量
    Dim Rng As Range
    Dim ds As Object
    Set ds = CreateObject("Scripting.Dictionary") '定义字典
   
    r = Range("a1048576").End(xlUp).Row
    Arr = Range("a1:b" & r).Value '将单元格数据装入数组
    r1 = Range("h1048576").End(xlUp).Row
    Brr = Range("h1:i" & r1).Value
    Range("a:b").Interior.ColorIndex = 0
   
    For k1 = 1 To r1
        For c1 = 1 To 2
            If Brr(k1, c1) <> "" Then ds(CStr(Brr(k1, c1))) = "" '将数组的值装入字典（供下一步查询）
        Next
    Next
   
    For k = 1 To r
        For c = 1 To 2
            If ds.exists(Mid(Cells(k, c), 2, 3)) Then '如果字典中存在指定的值（三位数）
                If Rng Is Nothing Then
                    Set Rng = Cells(k, c) '将单元格保存到变量Rng
                Else
                    Set Rng = Union(Rng, Cells(k, c)) '将单元格合并到变量Rng
                End If
            End If
        Next c
    Next k
    If Rng Is Nothing Then Exit Sub
   
    Application.ScreenUpdating = False
    Rng.Interior.ColorIndex = 3 '给单元格（区域）填充颜色
    Application.ScreenUpdating = True
End Sub

朱文明611

山菊花 发表于 2018-6-30 14:01
Sub 核对()
    Dim r&, r1&, k&, k1& '声明变量
    Dim s$, s1$

非常感谢啊