求助大神，绘制折线图，SUB调用时出现“1004”错误

John1990

请教大神，根据指定日期的开始和结束时间段，绘制折线图时碰到1004错误问题
说明
1、draw是根据指定区域绘制折线图，X轴和Y轴的区域数据是输入参数
2、main过程，使用range的已知区域数据代入，没问题，但是使用Cells表示的区域数据代入时，报“1004”错误
3、之所以使用cells代表区域数据，是因为cells内的行、列数据是需要经过计算的，是可变的，这个可变的部分还没代入，用一般数据代入就报错了


请大神指导下，谢谢

Sub draw(rng1, rng2 As Range)
Dim ch As ChartObject
Dim S1 As String
S1 = Range("A13")
On Error GoTo err:
Worksheets("sheet1").ChartObjects("动态").Delete   '确保这是唯一的图
err:
Set ch = Worksheets("主页").ChartObjects.Add(80, 185, 1200, 380)  '定义位置及大小
ch.Name = "动态"    '图表定名

With ch.Chart
            .ChartType = xlLine
            .SeriesCollection.NewSeries
            .SeriesCollection(1).Values = rng2
            .SeriesCollection(1).XValues = rng1
            .SeriesCollection(1).Name = S1   '"姓名"
           
End With
   
   ch.Chart.SeriesCollection(1).AxisGroup = 1
   ch.Chart.SeriesCollection(1).MarkerStyle = xlNone

With ch.Chart.Axes(xlCategory).TickLabels     '定义x轴即分类轴的字体和格式
        .Font.Size = 8
        .NumberFormatLocal = "m-d"
End With
Set rng1 = Nothing
Set rng2 = Nothing
Set rng3 = Nothing
Set ch = Nothing
End Sub

Sub main()
'Call draw(Worksheets("sheet1").Range("CP1:CY1"), Worksheets("sheet1").Range("CP10:CY10"))
Call draw(Worksheets("sheet1").Range(Cells(1, 80), Cells(1, 104)), Worksheets("sheet1").Range(Cells(2, 80), Cells(2, 104)))
End Sub

ivccav

2个问题：
1.draw(rng1, rng2 As Range)这种写法是错误的，rng1这样写就是variant类型，不是range，
改为draw(rng1 As Range, rng2 As Range)

2.Call draw(Worksheets("sheet1").Range(Cells(1, 80), Cells(1, 104)), Worksheets("sheet1").Range(Cells(2, 80), Cells(2, 104)))写法有问题。Cells也需要工作表前缀啊。你改为如下试试：

with worksheets("sheet1")
Call draw(.Range(.Cells(1, 80), .Cells(1, 104)), .Range(.Cells(2, 80), .Cells(2, 104)))
end with

注意Cells前面有点号

John1990

可以了，多谢多谢