同一工作簿中的多个工作表合并到一个工作表的代码（通用代码）

lrh788

Sub 同簿多表合并成一表赋表名()
    Dim brr(1 To 100000, 1 To 10)
    For Each sht In Sheets
        If sht.Name <> ActiveSheet.Name Then
            arr = sht.[a1].CurrentRegion
            For i = 2 To UBound(arr)
                m = m + 1
                brr(m, 1) = sht.Name
                For j = 2 To 10
                    brr(m, j) = arr(i, j - 1)
                Next
            Next
        End If
    Next
    [a1].CurrentRegion.Offset(1).ClearContents
    [a2].Resize(m, 10) = brr
End Sub

iris00

引用时如何剔除分表中的空白行？比如1表中固定格式有25行，只有5行用到有数字，其他行为空白，如何只取使用行？

huazai688

16楼代码比较通用，收藏学习，谢谢！

总量控制

留个记号学习学习

szqhb

lrh788 发表于 2018-4-7 10:14
Sub 同薄多表合并()
    Dim i As Long
    On Error Resume Next

经测试，不用减4

lrh788

Sub 多表合并()
    Dim arr()
    a = Range("a1").End(xlToRight).Column
    For Each sh In Sheets
        If sh.Name <> "汇总" Then
            arr1 = sh.Range("a2").Resize(sh.UsedRange.Rows.Count - 1, a)
            act = act + UBound(arr1)
            ReDim Preserve arr(1 To a, 1 To act)   '
            For j = 1 To UBound(arr1)
                n = n + 1
                For i = 1 To a
                    arr(i, n) = arr1(j, i)
                Next i
            Next j
        End If
    Next
    Sheets("汇总").[a2].Resize(n, a) = Application.Transpose(arr)
End Sub

lrh788

Sub 合并当前工作簿下的所有工作表()  '数组法，程序表头，以sub开头，以end sub结尾，固定格式；  “汇总*”为程序名字，
    Dim arr, i%, m%, r%, r1%, bm, t        '变量数据类型定义，以关键字dim 开始定义，英文逗号分隔多个变量；
    Dim sh As Worksheet, sht As Worksheet       '定义为工作表
    On Error Resume Next
    Application.ScreenUpdating = False
    Application.DisplayAlerts = False
    t = Timer
    Set sh = Worksheets("总表")
    sh.Cells.Clear:  sh.Cells.NumberFormat = "@"
    For Each sht In Worksheets          '循环本工作簿的所有工作表 ，用的是for each 循环格式
         If sht.Name <> sh.Name Then  '判断是否存放目标数据的工作表，用到了工作表的.name 属性，.name 获得工作表的工作表名
            r = sht.Cells(Rows.Count, 1).End(3).Row '通过A列来判断工作表最后一行数据的行
             bm = bm & Chr(9) & sht.Name
             m = m + 1
           If m = 1 Then
                arr = sht.Range("a1:v" & r) '将第一张表从第一行开始的数据存放在数组Arr中
              Else
                arr = sht.Range("a2:v" & r)    '将第一张表从第二行开始的以后的数据存放在数组Arr中
              End If
            End If
            r1 = sh.Cells(Rows.Count, 1).End(3).Row  '定位目标工作表最后一行位置，通过此
            sh.Range("a" & r1).Offset(1, 0).Resize(UBound(arr, 1), UBound(arr, 2)) = arr  '通过数组把数据复制到目标区域中
            Set arr = Nothing
         Next
    Application.ScreenUpdating = True
    Application.DisplayAlerts = True
    MsgBox "耗时：" & Format(Timer - t, "0.000") & "秒。" & "共汇总下列" & m & "个工作表：" & Chr(10) & bm, vbInformation, "提示"
End Sub
请教下，此代码中我加了偏移一行Offset(1, 0)运行后，汇总表的第一行始终为空，如果不加偏移Offset(1, 0)，在汇总分表时就无法提取分表的最后一行，请问怎么修改代码？

lrh788

Sub 合并同簿不同列标题的所有工作表
     Set dic = CreateObject("Scripting.Dictionary")
    Application.ScreenUpdating = False
    t = Timer
    For Each sht In Sheets
        If sht.Name <> ActiveSheet.Name Then
           bm= bm & Chr(9) & sht.Name
            arr = sht.[a1].CurrentRegion
            For j = 1 To UBound(arr, 2)
                dic(arr(1, j)) = 0
            Next
        End If
    Next
    ReDim brr(1 To Cells.Rows.Count, 1 To dic.Count ): m = 1
    For j= 1 To dic.Count
        dic(dic.keys()(j - 1)) = j
        brr(1, j) = dic.keys()(j - 1)
    Next
    For Each sht In Sheets
        If sht.Name <> ActiveSheet.Name Then
           n = n + 1
            arr = sht.[a1].CurrentRegion
            For i = 2 To UBound(arr)
                m = m + 1
                brr(m, 1) = sht.Name
              For j = 1 To UBound(arr, 2)
                    brr(m, dic(arr(1, j)) ) = arr(i, j)
                Next
            Next
        End If
    Next
    Cells.Clear:  Cells.NumberFormat = "@"
    [a1].Resize(m, UBound(brr, 2)) = brr
    [a1].Resize(m, UBound(brr, 2)).Borders.LineStyle = 1
    Application.ScreenUpdating = True
    MsgBox "用时：" & Format(Timer - t, "0.000") & "秒。" & "共汇总下列" & n & "个工作表：" & Chr(10) & bm, vbInformation, "提示"
End Sub

lrh788

我已修改成功了。
Sub 合并同簿相同格式的所有工作表()              '数组法，
    Dim arr, m%, r%, r1%, bm, t                 '定义变量数据类型
    Dim sh As Worksheet, sht As Worksheet       '定义为工作表
    Application.ScreenUpdating = False
    Application.DisplayAlerts = False
     t = Timer
     Set sh = Worksheets("总表")
     sh.Cells.Clear:  sh.Cells.NumberFormat = "@"        '清除总表数据并设置成文本格式
     For Each sht In Worksheets                          '循环本工作簿的所有工作表
         If sht.name <> sh.name Then                     '判断是否存在要合并的工作表
            r = sht.Cells(Rows.Count, 1).End(3).Row      '通过A列来判断要合并的工作表最后一行数据的行位置
            r1 = sh.Cells(Rows.Count, 1).End(3).Row      '通过A列来判断总表最后一行位置
             bm = bm & Chr(9) & sht.name                 '提取要合并的工作表名
             m = m + 1
            If m = 1 Then
                 arr = sht.Range("a1:v" & r)              '第一张表从第一行开始将所有数据存入数组中
                 sh.Range("a" & r1).Resize(UBound(arr), UBound(arr, 2)) = arr  '将存放在数组中的数据写入总表
              Else
                 arr = sht.Range("a2:v" & r)               '第二张表起去一行表头，从第二行开始将所有数据存入数组中
                 sh.Range("a" & r1).Offset(1).Resize(UBound(arr), UBound(arr, 2)) = arr  '将存放在数组中的数据写入总表
            End If
          End If
        Set arr = Nothing
      Next
     Application.ScreenUpdating = True
     Application.DisplayAlerts = True
     MsgBox "耗时：" & Format(Timer - t, "0.000") & "秒。" & "共汇总以下" & m & "个工作表：" & Chr(12) & bm, vbInformation, "提示"
End Sub

自由的清寻

lsc900707 发表于 2018-3-25 09:45
Sub bz()
      Dim sht As Worksheet, ar
      Application.ScreenUpdating = False

非常有用，谢谢题主，终于找到一个2010版本可以用的