[原创]IIF函数的应用：

gues1688

1、说明： 根据表达式的值，来返回两部分中的其中一个。 2、语法 IIf(expr, truepart, falsepart) IIf 函数的语法含有下面这些命名参数： 部分 描述 expr 必要参数。用来判断真伪的表达式。 truepart 必要参数。如果 expr 为 True，则返回这部分的值或表达式。 falsepart 必要参数。如果 expr 为 False，则返回这部分的值或表达式。 3、说明 由于 IIf 会计算 truepart 和 falsepart，虽然它只返回其中的一个。因此要注意到这个副作用。例如，如果 falsepart 产生一个被零除错误，那么程序就会发生错误，即使 expr 为 True。 4、示例： 如果你有一段这样的代码： If x = 1 Then y = "Yes" Else y = "No" End If 那么，利用IIF函数可以将这段代码改写如下： y = IIf(x = 1, "Yes", "No") 怎么样？呵呵，很简练吧！ 我的应用代码示例：http://club.excelhome.net/dispbbs.asp?boardID=23&ID=140011&page=1

gues1688

再来一段五彩纷呈的文字实现代码：

Sub colorChar()
Dim myR As Range, i As Byte, iMax As Byte
Dim colorArray As Variant
Application.ScreenUpdating = False
ActiveDocument.Content.Text = "=rand(2,45)" '自动产生虚拟文本
Application.Activate
SendKeys "{end}{enter}", True
colorArray = Array(wdColorDarkRed, wdColorRed, wdColorDarkGreen, wdColorOliveGreen, _
wdColorBrown, wdColorOrange, wdColorGreen, wdColorDarkYellow, _
wdColorLightOrange, wdColorLime, wdColorGold, wdColorBrightGreen, _
wdColorYellow, wdColorDarkTeal, wdColorPlum, wdColorSeaGreen, _
wdColorDarkBlue, wdColorViolet, wdColorTeal, wdColorIndigo, _
wdColorBlueGray, wdColorTan, wdColorLightYellow, wdColorRose, _
wdColorAqua, wdColorLightGreen, wdColorBlue, wdColorPink, _
wdColorLightBlue, wdColorLavender, wdColorSkyBlue, wdColorPaleBlue, _
wdColorTurquoise, wdColorLightTurquoise)
i = 0
iMax = UBound(colorArray)
For Each myR In ActiveDocument.Characters
myR.Select
Selection.Font.Color = colorArray(i)
i = IIf(i < iMax, i + 1, 0) '这里使用了IIf函数
Next
Application.ScreenUpdating = True
Application.Activate
End Sub

konggs

这个程序很特别，如果按F5可以正常看到效果。

如果按

F8则不行。不信，兄台可以试试，看来是sendkeys在起作用。

守柔

楼主专研精神可赞，只是这些应用，我想，论坛上太多了，另外，你的例子中，总离不开SENDKEY，离不开SELECT，对WORD编程意义不是特别大。

至于是否原创，我也觉得没有必要。

gues1688

以下是引用[I]守柔[/I]在2005-12-15 17:04:40的发言：[BR]

楼主专研精神可赞，只是这些应用，我想，论坛上太多了，另外，你的例子中，总离不开SENDKEY，离不开SELECT，对WORD编程意义不是特别大。

至于是否原创，我也觉得没有必要。

谢谢守柔老师 sendkeys 是从您的拼音指南中首次知道的，在想不出其它办法的时候，只好用它了。 我会认真学习您的代码，还有论坛的答复的帖子，努力提高掌握VBA的水平

守柔

注意：

何时使用哪个函数或者语句，需要根据实际情况而定。

比如：IIF函数，程序将对其中的两个条件都要进行判断；而使用IF THEN语句时，程序只判断其中满足条件的条件语句。也就是说，如果IIF中两个条件中，有一个是出错的，则这个函数会出错。

如：

Sub Example1()
Dim a As Integer
Dim b As Integer
Dim c
a = -1
b = 0
If a > 0 Then
c = a / b
Else
c = a * b
End If
MsgBox c
End Sub
Sub Example2()
Dim a As Integer
Dim b As Integer
Dim c
a = -1
b = 0
c = VBA.IIf(a > 0, a / b, a * b)
MsgBox c
End Sub

同样，关于CHOOSE，Switch函数，对于其中的条件过多时，其可读性就差，不如SELECT CASE 语句更灵活方便。

因此，写程序必须具体问题具体分析，不能一概而论，程序的好坏简易还与被处理的对象（文档）的大小有关，如果文档很大，则必须考虑程序运行的效率，反之，则不易体现。

gues1688

谢谢守柔老师的指点