可以直接使用vba获取txt文件的多列数据吗

tiny34

想实现的功能是 有两个按钮，一个是导入数据，一个是处理 数据
1.使用VBA获取TXT文件中多行数据（并不是所有数据）
2.目前已经完成的是把txt所有数据导入到excel里面

tiny34

宏密码是sasasasa

tiny34

可以用正则表达式做吗

tiny34

能有大神给个思路吗

一把小刀闯天下

'新建一个工作薄，其中有2个工作表名称分别为"sheet1"、"sheet2"
'一个为导出的源数据表，另外一个汇总后数据表（指定列）
'表格线等自己设置

Option Explicit

Sub test()
  Dim arr, filename, i, j, t, n, pos, brr, dic, sum(1 To 3), m, tt, crr
  pos = Split("33 36 37-77 54 57 64 65")
  Set dic = CreateObject("scripting.dictionary")
  filename = ThisWorkbook.Path & "\PKTA511(20171017).txt"
  If Len(Dir(filename)) = 0 Then MsgBox filename: Exit Sub
  Open filename For Input As #1
  arr = Split(StrConv(InputB(LOF(1), 1), vbUnicode), vbNewLine)
  Close #1
  For i = 0 To UBound(arr)
    If InStr(arr(i), vbTab) Then
      n = n + 1: t = Split(arr(i), vbTab)
      If n = 1 Then ReDim brr(1 To UBound(arr) + 1, 1 To UBound(t) + 1)
      For j = 0 To UBound(t)
        brr(n, j + 1) = t(j)
      Next
    End If
  Next
  With Sheets("sheet1")
    .Cells.ClearContents
    If n = 0 Then Exit Sub
    .[a1].Resize(n, UBound(brr, 2)) = brr
  End With
  For i = 2 To n
    t = CStr(brr(i, 33))
    If Not dic.exists(t) Then m = m + 1: dic(t) = m
  Next
  ReDim crr(1 To m, 1 To 7)
  For i = 2 To n
    t = CStr(brr(i, 33))
    For j = 0 To UBound(pos)
      If j = 2 Then
        tt = Split(pos(j), "-")
        crr(dic(t), j + 1) = brr(i, tt(0)) & Space(2) & brr(i, tt(1))
      ElseIf j = 4 Or j = 6 Then
        crr(dic(t), j + 1) = crr(dic(t), j + 1) + Val(brr(i, pos(j)))
      Else
        crr(dic(t), j + 1) = brr(i, pos(j))
      End If
    Next
    sum(1) = sum(1) + Val(brr(i, pos(4))): sum(3) = sum(3) + Val(brr(i, pos(6)))
  Next
  With Sheets("sheet2")
    .Rows(2).Resize(Rows.Count - 1).ClearContents
    .[a2].Resize(UBound(crr, 1), UBound(crr, 2)) = crr
    n = .Cells(Rows.Count, "a").End(xlUp).Row
    .Cells(n + 1, 5).Resize(, UBound(sum)) = sum
  End With
End Sub

tiny34

一把小刀闯天下 发表于 2018-1-18 12:17
'新建一个工作薄，其中有2个工作表名称分别为"sheet1"、"sheet2"
'一个为导出的源数据表，另外一个汇总后 ...

运行了一下，真的特别好，谢谢你。这个我怎么送鲜花给您

一把小刀闯天下

tiny34 发表于 2018-1-18 13:40
运行了一下，真的特别好，谢谢你。这个我怎么送鲜花给您

要20分以上才能送小花的，先记在账上，哈哈哈。如果能解决问题其实已经算是双赢了，因为我在这论坛找题目学VBA。

tiny34

一把小刀闯天下 发表于 2018-1-18 15:44
要20分以上才能送小花的，先记在账上，哈哈哈。如果能解决问题其实已经算是双赢了，因为我在这论坛找题目 ...

嗯嗯，我照着你的代码改一下就差不多解决了。小花先记账上了哈，真的非常感谢

tiny34

一把小刀闯天下 发表于 2018-1-18 15:44
要20分以上才能送小花的，先记在账上，哈哈哈。如果能解决问题其实已经算是双赢了，因为我在这论坛找题目 ...

不好意思，我把作业提交给老师，还有几个问题，能再麻烦您一下吗？

任飘渺

留名学习2233333