30个大文件，合并到1个excel表里面请问有什么好办法？

一把小刀闯天下

'所有有数据的表格都进行了汇总

Option Explicit

Sub test()
  Dim filename(), pth, mark, row, i, sht, arr
  pth = ThisWorkbook.Path: mark = Split(".xls .xlsx")
  If Not getfilename(filename, pth, mark) Then MsgBox "!": Exit Sub
  For i = 1 To UBound(filename)
    If InStr(filename(i), "汇总") = 0 Then
      With GetObject(filename(i))
        For Each sht In .Worksheets
          arr = .Sheets(sht.Name).UsedRange
          If IsArray(arr) Then
            row = Cells(Rows.Count, "a").End(xlUp).row
            Cells(row + 1, "a").Resize(UBound(arr, 1), UBound(arr, 2)) = arr
          End If
        Next
      End With
    End If
  Next
End Sub

Function getfilename(filename, pth, mark) As Boolean
  Dim f, n, i
  If Right(pth, 1) <> "\" Then pth = pth & "\"
  f = Dir(pth & "*.*")
  Do While Len(f) > 0
    For i = 0 To UBound(mark)
      If LCase(Right(f, Len(mark(i)))) = LCase(mark(i)) Then
        n = n + 1: ReDim Preserve filename(1 To n)
        filename(n) = pth & f
      End If
    Next
    f = Dir
  Loop
  If n > 0 Then getfilename = True
End Function

liboa2004

谢谢，测试成功，请问要汇总当前文件夹及子文件夹下所有excel文件内容，该如何改一下呢？

jjmysjg

liboa2004 发表于 2018-3-28 17:34
谢谢，测试成功，请问要汇总当前文件夹及子文件夹下所有excel文件内容，该如何改一下呢？

20万的数据，你上传20个的，不能传吗

opiona

liboa2004 发表于 2018-3-28 17:34
谢谢，测试成功，请问要汇总当前文件夹及子文件夹下所有excel文件内容，该如何改一下呢？

http://club.excelhome.net/thread-1170256-1-1.html

SQL汇总方法，见二楼