已经完美应助----求助杜老师，修改代码，谢谢！

wdpfox

杜老师，在把word文档中的文字，如：20km^2等“^2”形式的批量转化为上标2（删除了^号），您写了实现的代码。最近发现您写的这个代码把^C、^vb等形式的^删除了。因水平较低，求赐教，谢谢！        
Sub test()
    With ActiveDocument.Range(0, 0)
        Do While .MoveUntil("^")
            .Delete
            If .MoveEndWhile("0123456789") Then
                .Font.Superscript = True
                .Start = .End
            End If
        Loop
    End With
End Sub

老师应助的代码已经解决上标问题，我想再完美些：
加入两个判断语句：if (^前字母大写) then 设置上标形式1
else 设置上标形式2        
先谢为敬！

duquancai

Sub test()
    With ActiveDocument.Range(0, 0)
        Do While .MoveUntil("^")
            .Move , 1
            If .MoveEndWhile("0123456789") Then
                .End = .Start: .Start = .Start - 1: .Text = Empty
                .MoveEndWhile "0123456789"
                .Font.Superscript = True
                .Start = .End
            End If
        Loop
    End With
End Sub

wdpfox

谢谢杜老师回复，预祝杜老师及论坛里的老师和朋友们新年快乐！能否加上判断^前的字母的大小写条件，弄了一晚上，没有成功，关键是零基础VBA。谢谢！

duquancai

wdpfox 发表于 2017-12-30 09:05
谢谢杜老师回复，预祝杜老师及论坛里的老师和朋友们新年快乐！能否加上判断^前的字母的大小写条件，弄了一 ...

不要用这种“挤牙膏式”的提问！这是最后一次为你提供服务！
Sub test()
    With ActiveDocument.Content.Find
        Do While .Execute("[a-zA-Z]^94[0-9]{1,3}", , , -1)
            With .Parent
                If .Characters.First Like "[A-Z]" Then
                    .Start = .Start + 1: .End = .Start: .Delete
                    .MoveEndWhile "0123456789", 3
'                    设置上标形式1
                    .Start = .End
                Else
                    .Start = .Start + 1: .End = .Start: .Delete
                    .MoveEndWhile "0123456789", 3
'                    设置上标形式2
                    .Start = .End
                End If
            End With
        Loop
    End With
End Sub

wdpfox

谢谢杜老师回复，测试通过。祝老师2018健康吉祥如意！