优化表格的思维拓展题

mmlzh

丢丢表格 发表于 2017-11-16 19:06
其实各位老师 还放不开手脚 ， 可以动动表格，让它更简单一些。因为这是一张工作中的实例表，不是竞赛，而 ...

这算不算
=SUM((E$3:N$3>0)*(LEFT(E11:N11)+RIGHT(D11:M11)))

丢丢表格

mmlzh 发表于 2017-11-16 19:36
这算不算
=SUM((E$3:N$3>0)*(LEFT(E11:N11)+RIGHT(D11:M11)))

思路很好， 就是原数据表改得有点大，不太直观。 尽量改动条件表。

丢丢表格

ling12345678 发表于 2017-11-16 19:46
27.29是什么意思，不都是8的倍数吗？

夜班是跨两天的   （21：00~5：00），  当日 是 3 个小时， 次日 是5 个小时。 如果当日是节日 ，那么 3个小时 就算今天的， 要是明天还是节日 ，那 夜班的次日 5个小时，就要放到 次日计算了 。。。
   你明白了没有？！

mmlzh

那就是把"节"改成1，再用18楼的公式了。
=SUM(D$3:N$3*((D4:N4<>"休息")*8-(D4:N4="夜班")*5+(C4:M4="夜班")*5))

丢丢表格

mmlzh 发表于 2017-11-16 20:41
那就是把"节"改成1，再用18楼的公式了。
=SUM(D$3:N$3*((D4:N4"休息")*8-(D4:N4="夜班")*5+(C4:M4="夜班") ...

非常好                          。

sdc3211772

休息、早班、中班、夜班依次为0、8、8、3
=SUM(IF($D$3:$N$3="节",HLOOKUP(T(IF({1},D4:N4)),$T$2:$W$4,3,)+(C4:M4="夜班")*5))
三键 节日加班小时.zip (10.09 KB, 下载次数: 4)

2017-11-16 22:20 上传

点击文件名下载附件

nsxlyj

=SUM(D$19:N$19*((D20:N20<>"休")*8-(D20:N20="夜")*5+(C20:M20="夜")*5))
三键结束

丢丢表格

节日  加班小时统计

把原条件表 可改在  如 条件1表、条件2表。

Q列 是引用条件1表的公式，这个公式比较紧凑

=SUM(COUNTIFS(OFFSET(D$3:N$3,,{0;1}),"节",D4:N4,U$2:W$2)*U$4:W$5)

如没有S4:W5 这两行的话，那公式只能写成：

=SUM(COUNTIFS(OFFSET(D$3:N$3,,{0;1}),"节",D4:N4,U$2:W$2)*{8,8,3;0,0,5})

R列 是引用条件2表的公式，公式也比较直观。

=SUM(((D4:N4=Y$4:Y$6)*Z$4:Z$6+5/3*(C4:M4="夜班"))*(D$3:N$3>0))