SQL跨工作薄,模糊查询多个工作表-求助

zeng333333333

各位VBA高手：
   需要在要工作薄(SQL跨工作薄多工作表模糊搜索)查询出保修期限工作薄内的所有工作表的内容出来。

    附件只是例子，模糊查询显示在(SQL跨工作薄多工作表模糊搜索)表中
  现在只能查询一个工作表,不能多工作表查询?????

    谢谢各位了！！
代码:修改那里可以跨工作薄,多工作表模糊查询...................


Sub 工作簿外查询() '工作簿外查询
On Error Resume Next

    Range("a4:t1048576").ClearContents '清空a4至t65536数据
    Dim cnn As New ADODB.Connection
    With cnn
        .Provider = "Microsoft.Jet.OLEDB.4.0"
        .ConnectionString = "Data Source=" & ActiveWorkbook.Path & "\保修期限.xls" & ";Extended Properties=Excel 8.0"
        .CursorLocation = adUseClient
        .Open
    End With

    Dim RST As New ADODB.Recordset
    Dim Sql As String
    Dim uname As String
    uname = "%" & [b2] & "%"
    sqlstr = "select * from [" & mySheet & "$a:t] where 备件名称 like '" & uname & "'"
    RST.Open sqlstr, cnn
    [a4].CopyFromRecordset RST

    Set RST = Nothing
    Set cnn = Nothing
End Sub

魂断蓝桥

Sub 工作簿外查询() '
Dim rs As Object, MyTable As Object, s$, cnn
        Set cnn = CreateObject("adodb.connection")
        MYFILE = ThisWorkbook.Path & "\保修期限.xls"
        cnn.Open "Provider=Microsoft.JET.OleDb.4.0;Extended Properties='Excel 8.0;HDR=NO'; Data Source=" & MYFILE
        Set rs = cnn.OpenSchema(20)
        Do Until rs.EOF
         If rs.Fields("TABLE_TYPE") = "TABLE" Then
        s = rs("TABLE_NAME").Value
        If Right(s, 1) = "$" Then
            Sql = Sql & "SELECT * FROM [" & s & "A4:T] WHERE F4 LIKE '%" & [B2] & "%' UNION ALL "
        End If
    End If
    rs.MoveNext
Loop
Sql = Left(Sql, Len(Sql) - 11)
Range("a4:t65536").ClearContents
[A4].CopyFromRecordset cnn.Execute(Sql)
cnn.Close
Set cnn = Nothing
End Sub

此用户被禁言

魂断蓝桥 发表于 2017-9-22 15:24
Sub 工作簿外查询() '
Dim rs As Object, MyTable As Object, s$, cnn
        Set cnn = CreateObject(" ...

请教一下老师。为什么用这种方法打开后。循环里面的表。它会生成好多其它名称的表。而且这种就是不需要的。。所以你才要判断 If Right(s, 1) = "$"

LMY123

Do Until rs.EOF

zeng333333333

谢谢:魂断蓝桥老师
还想问下老师:如果是2007工作表查询,是不是把
MYFILE = ThisWorkbook.Path & "\保修期限.xls"
改为
MYFILE = ThisWorkbook.Path & "\保修期限.xlsx"
就可以吗?