[开_151]随机小学生加法计算式

xwcxks48 · 发表于 2017-5-25 16:29

本帖最后由 xwcxks48 于 2017-5-26 10:39 编辑

1

=TEXT(LARGE(IF(ROW($10:$89)+COLUMN($J:$CK)<100,ROW($10:$89)*100+COLUMN($J:$CK)),RANDBETWEEN(1,3160)),"00+00=")

复制代码

字数还是有点多。。。

2

=TEXT(LARGE(RANDBETWEEN(10,ROW($10:$89))*100+99-ROW($10:$89),RANDBETWEEN(1,80)),"00+00=")

复制代码

3

=CONCAT(RANDBETWEEN(10,ABS({99;0}-CHOOSE({1;1},RANDBETWEEN(10,89))))&{"+";"="})

复制代码

最外层函数只在论坛中见过，无法验证，如有office365麻烦帮忙验证一下。。

ailebao · 发表于 2017-5-25 16:34

=TEXT(SUM(FREQUENCY(ROW($1:$99),RANDBETWEEN({1,1},98))*{100;1;0}),"00+00=")

sayhi95 · 发表于 2017-5-25 17:14

本帖最后由 sayhi95 于 2017-5-26 12:21 编辑

火车，还不知道对不对，搞不懂随机，汗~~~好像就是不对。。。

=TEXT(INDEX(RANDBETWEEN(ROW(10:89)&10,ROW(10:89)&(90-ROW(1:80))),RANDBETWEEN(1,80)),"0+00=")

复制代码

免强改到90以内了，估计还是有问题

=TEXT(INDEX(RANDBETWEEN(ROW(10:89)&10,ROW(10:89)&(90-ROW(1:80))),INT(RAND()*80)),"0+00=")

复制代码

再改一下

=TEXT(INDEX(RANDBETWEEN(ROW(10:89)&10,ROW(10:89)&(90-ROW(1:80))),RAND()*80+1),"0+00=")

复制代码

pureshadow · 发表于 2017-5-25 17:33

本帖最后由 pureshadow 于 2017-5-26 17:13 编辑

=TEXT(MID(CONCAT(RANDBETWEEN(10,{8,91}+ROW(1:9)*{9,-9})),RIGHT(RAND())*4-3,4),"0+00=")

复制代码

上面这个公式被批评了，那试试这个吧：

=INDEX(INT(RAND()*ROW(1:80)+10)&"+"&RANDBETWEEN(10,90-ROW(1:80))&"=",RAND()*81)

复制代码

估计再挤挤还能挤出点水份。
然后，又被批评了T_T，想拿个分分怎么就这么难捏？T_T

=INDEX(INT(RAND()*ROW(1:80)+10)&"+"&RANDBETWEEN(10,90-ROW(1:80))&"=",RAND()*80+1)

复制代码

这样子呢？

piny · 发表于 2017-5-25 17:53

本帖最后由 piny 于 2017-5-26 08:57 编辑

=TEXT(RIGHT(SMALL(ROW(10:89)*10100+COLUMN(J:CK)*10001,RANDBETWEEN(1,3240)),4),"00+00=")

复制代码

jsgj2023 · 发表于 2017-5-25 19:55

本帖最后由 jsgj2023 于 2017-5-25 22:08 编辑

>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>

一剑惊心 · 发表于 2017-5-25 20:40

思路很守旧，估计有点卡
=TEXT(LARGE((ROW($1:80)+COLUMN(1:1)<91)*(ROW($10:89)&COLUMN(1:1)),RAND()*3239+1),"0+00=")

dengjq2000 · 发表于 2017-5-25 22:33

本帖最后由 dengjq2000 于 2017-5-26 07:50 编辑

我来几个，较长的公式（87字长）：

=TEXT(IFERROR(SUM(RANDBETWEEN(10,ABS(100^{0,1}-INT(RAND()*89)))*{100,1}),1830),"0+00=")

复制代码

效果见工作表“RAND”
适应于 “,” 改成：“;”
=TEXT(IFERROR(SUM(RANDBETWEEN(10,ABS(100^{0;1}-INT(RAND()*89)))*{100;1}),1830),"0+00=")

再来一个相对较短的（77字长，效果见工作表“RANDBETWEEN”）：

=TEXT(SUM(RANDBETWEEN(10,ABS(100^{0;1}-RANDBETWEEN(11,89)))*{100;1}),"0+00=")

复制代码

同理
适应于“;” 改成： “,”
=TEXT(SUM(RANDBETWEEN(10,ABS(100^{0,1}-RANDBETWEEN(11,89)))*{100,1}),"0+00=")

2017-05-26 再缩简几个字符（74字长，其他也可类似修改，不再说明）。

=TEXT(SUM(RANDBETWEEN(10,ABS({0;99}-RANDBETWEEN(10,89)))*{100;1}),"0+00=")

复制代码

mps777 · 发表于 2017-5-25 22:34

本帖最后由 mps777 于 2017-5-25 22:38 编辑

噢，不齐全，再想

一剑惊心 · 发表于 2017-5-26 07:59

本帖最后由一剑惊心于 2017-5-26 08:01 编辑

换了个思路再来一个普通公式
=TEXT(INDEX(ROW($10:89)&INT(RAND()*(90-ROW($10:89))+10),RAND()*79+1),"0+00=")
=TEXT(INDEX(ROW(A:A)&INT(RAND()*(90-ROW(A:A))+10),RAND()*79+10),"0+00=")(这个相对卡了些）

		自动登录	找回密码
密码			免费注册

[Excel 函数与公式] [开_151]随机小学生加法计算式

评分

评分

评分

评分

评分

评分

评分

评分

评分