真奇妙！为什么这个“批量转换为内嵌图片”的代码运行一次只能转换一个图片呢？

FENGJUN

为什么运行一次只能转换一个图片呢？

Sub Shapes2oInlineShapes()
'批量转换为内嵌图片
    Dim oshap As Shape

    '转换前
    Debug.Print ActiveDocument.Shapes.Count

    For Each oShape In ActiveDocument.Shapes
        oShape.ConvertToInlineShape
    Next

    '转换后
    Debug.Print ActiveDocument.InlineShapes.Count

End Sub

duquancai

Sub Shapes2oInlineShapes()
    With ActiveDocument
        For i = .Shapes.Count To 1 Step -1
            .Shapes(i).ConvertToInlineShape
        Next
    End With
End Sub

FENGJUN

多谢，可以解决问题。但我的语句我的语句不成功的原因是什么呢？还有如下写法也不行：
Sub Shapes2InlineShapes()
'批量转换为内嵌图片
    Dim oshap As Shape
    '转换前
    Debug.Print ActiveDocument.Shapes.Count
    With ActiveDocument
        For i = 1 To .Shapes.Count
            .Shapes(i).ConvertToInlineShape
        Next
    End With

    '转换后
    Debug.Print ActiveDocument.InlineShapes.Count
End Sub

loquat

word的问题，具体什么原因说不上，但是倒序处理是经典解决方案。

dafanshu1

FENGJUN 发表于 2017-5-13 10:26
多谢，可以解决问题。但我的语句我的语句不成功的原因是什么呢？还有如下写法也不行：
Sub Shapes2InlineS ...

楼主可以试试在在 .Shapes(i).ConvertToInlineShape前面加多句.Shapes(i).Select，再按F8逐句执行，就可清楚地看到每次循环VBA是怎样执行的。在此我做了一个简单附件，以便观察研究。

对于for循环，其实可以这样理解：当执行了第1次后进入第2次，i 就由1变成2了，因原Shapes(1)已变成嵌入型，所以现时文档中的Shapes(1)就是执行前原文档的Shapes(2)，但此时是对当前文档的第2个对象Shapes(2)执行，从而就把现时文档的Shapes(1)落下了，再到下次循环就依此类推，因此最终 i 会超出当前文档的Shapes数量而出错。

对于for each循环，也可以在oShape.ConvertToInlineShape前加一句oShape.Select，按F8逐句执行来观察，发现其执行规律与for循环完全一样，只不过是不会像for循环那样死板地循环至出错，一超出范围就自动跳出循环。

duquancai

dafanshu1 发表于 2017-5-13 23:38
楼主可以试试在在 .Shapes(i).ConvertToInlineShape前面加多句.Shapes(i).Select，再按F8逐句执行，就 ...

你解释很到位！用do循环和倒序for循环就能解决此类问题：

Sub do1()
    With ActiveDocument
        Do While .Shapes.Count <> 0
            .Shapes(1).ConvertToInlineShape
        Loop
    End With
End Sub
Sub for1()
    With ActiveDocument
        For i = .Shapes.Count To 1 Step -1
            .Shapes(i).ConvertToInlineShape
        Next
    End With
End Sub

FENGJUN

dafanshu1 发表于 2017-5-13 23:38
楼主可以试试在在 .Shapes(i).ConvertToInlineShape前面加多句.Shapes(i).Select，再按F8逐句执行，就 ...

多谢解答。只是个坑，很多人还不知道

dafanshu1

duquancai 发表于 2017-5-14 10:19
你解释很到位！用do循环和倒序for循环就能解决此类问题：

Sub do1()

谢谢杜兄！
我在工作中常用到的却是对所选中的多个图形转换为嵌入型，利用杜兄的宏，本想只是将ActiveDocument改成Selection，将Shapes改成ShapeRange就行了，但实际发生了意外：

执行do1宏，对doc文档可行，而对docx文档却只能转换第1个图形。

执行for1宏，对doc文档，会将其他未选中的图形转换成嵌入型，已选中的却未转换，但按F8逐语句执行反而达到正确效果，真奇怪！对docx文档就直接弹出错误了。

不知杜兄有何高见？