正则无果：删除段首多余空格

weiyingde

Sub 删除段首多余空格() '由空格键生成的多余空格
Dim regx, S$, Strnew$
Set regx = CreateObject("vbscript.regexp")
   For Each i In ActiveDocument.Paragraphs
   S = i.Range.Text
   regx.Pattern = "^\s+"
   regx.Global = True
Strnew = regx.Replace(S, "")
Next
End Sub

loquat

Sub wdTrimParagraph()
Dim rng As Range
Dim txt$
Set rng = ActiveDocument.Content
With rng.Find
    .MatchWildcards = True
    .Text = "(^13)[ ]@(*^13)"
    Do While .Execute
        Set rng = .Parent
        rng.MoveStart wdCharacter, 1
        rng.MoveEnd wdCharacter, -1
        txt = rng.Text
        txt = VBA.Trim$(txt)
        rng.Text = txt
        rng.SetRange rng.End, rng.End
    Loop
End With
End Sub

duquancai

Sub shishi()
    ActiveDocument.Content.Find.Execute "^13^32{1,}", , , 1, , , , , , "^p", 2
End Sub

weiyingde

duquancai 发表于 2017-3-19 11:47
Sub shishi()
    ActiveDocument.Content.Find.Execute "^13^32{1,}", , , 1, , , , , , "^p", 2
End Su ...

好简洁。
大侠好多过程中都用这种模式的表达式，我不懂特别是： "^13^32{1,}", , , 1, , , , , , "^p", 2
红字部分中的逗号及其中的数字，表达的含义是什么。
能给我启蒙吗？

jiminyanyan

能上传个附件么………………

weiyingde

jiminyanyan 发表于 2017-3-19 14:58
能上传个附件么………………

这是duquancai 给我的代码，很好，但我红字的本部分不懂，请解释一下。
Sub W_移形换位()
    Dim reg As Object, mt, mh, oDOC As Document
    Set oDOC = ActiveDocument
    With oDOC.Content.Find
        .Execute "([\(（])^32{1,}", , , 1, , , , , , "\1", 2        
        .Execute "^32{1,}([\)）])", , , 1, , , , , , "\1", 2
        .Execute "^32{1,}", , , 1, , , , , , "^32", 2
   End With
    Set reg = CreateObject("vbscript.regexp")
    reg.Global = True: reg.Pattern = "[\(（][^）\)]+[\)）]"
    For Each mt In reg.Execute(oDOC.Content)
        m = mt.FirstIndex: n = mt.Length
        With oDOC.Range(m, m + n)
            reg.Pattern = " ": t = reg.Execute(.Text).Count + 1
            .Start = .Start - t
            .Find.Execute "([一-﨩]{" & t & "})([\(（])(*)([\)）])", , , 1, , , , , , "\3\2\1\4", 1            
            reg.Pattern = "[\(（][^）\)]+[\)）]"
            For Each mh In reg.Execute(.Text)
                f = mh.FirstIndex: l = mh.Length
                With oDOC.Range(.Start + f, .Start + f + l)
                    .Start = .Start + 1: .End = .End - 1
                    .Font.Color = RGB(255, 255, 255)
                End With
            Next
        End With
    Next
End Sub

代码如下

weiyingde

jiminyanyan 发表于 2017-3-19 14:58
能上传个附件么………………

4楼的附件如下：
问题已经解决，解释一下代码。
Sub shishi()
    ActiveDocument.Content.Find.Execute "^13^32{1,}", , , 1, , , , , , "^p", 2
End Sub

loquat

等价于
Sub shishi()
    ActiveDocument.Content.Find.Execute FindText:="^13^32{1,}", MatchWildcards:=True, ReplaceWith:="^p", Replace:=wdReplaceAll
End Sub

loquat

也等价于
Sub shishi()
With ActiveDocument.Content.Find
    .Text = "^13^32{1,}"
    .MatchWildcards = True
    .Replacement.Text = "^p"
    .Execute Replace:=wdReplaceAll
End With
End Sub

weiyingde

loquat 发表于 2017-3-19 17:39
也等价于
Sub shishi()
With ActiveDocument.Content.Find

能否完整列举findtext参数？