Split拆分结果如何写入数组？

IVYQQQQQ

想用VBA代码实现：数据用Split函数拆分结果写入数组，再将数组输出到单元格区域B1:C13。
有花送哦！

cflood

用分列不行吗

xd3210

不用写入数组，用split函数会直接生成数组：myarr=split(mystr)

xiangbaoan

Sub test()
Dim Arr, Brr, Crr(), r&
    With Sheet1
       . [b:c] = ""
        Arr = .Range("a1:a" & .Cells(.Rows.Count, 1).End(xlUp).Row)
        ReDim Crr(1 To UBound(Arr), 1 To 2)
        For r = 1 To UBound(Arr)
            Brr = Split(Arr(r, 1), "/")
            Crr(r, 1) = Brr(0)
            Crr(r, 2) = Brr(1)
        Next
         .[b1].Resize(UBound(Crr), 2) = Crr
    End With
End Sub

kldxlb

1. Sub 分割()
   
2.     Dim arr, brr, crr
   
3.     arr = Range("A1:A" & Range("A1").End(xlDown).Row)
   
4.     ReDim brr(1 To UBound(arr, 1), 1 To 1)
   
5.     ReDim crr(1 To UBound(arr, 1), 1 To 1)
   
6.     For i = 1 To UBound(arr, 1)
   
7.         brr(i, 1) = Split(arr(i, 1), "/")(0)
   
8.         crr(i, 1) = Split(arr(i, 1), "/")(1)
   
9.     Next
   
10.     Range("B1").Resize(UBound(brr, 1), 1) = brr
    
11.     Range("C1").Resize(UBound(crr, 1), 1) = crr
    
12. End Sub
    

复制代码

紫星丫头

应该还是用分列最简单方便吧

1. Sub spilt()
   
2.     Dim arr, i&, j&
   
3.     Range("b:c").ClearContents
   
4.     For i = 1 To Range("a1").CurrentRegion.Rows.Count
   
5.         arr = Split(Cells(i, 1).Value, "/")
   
6.         j = j + 1
   
7.         Range(Cells(j, 2), Cells(j, 3)) = arr
   
8.     Next
   
9.         
   
10. End Sub

复制代码

IVYQQQQQ

紫星丫头 发表于 2017-3-14 12:38
应该还是用分列最简单方便吧

分列当然可以，但是我想要的是用Split函数分行拆分写进数组（这个数组范围是B1:C13）,不要每行都是arr,我想要在循环之外将数组结果输出（Range("B1:C13") = arr）,我只是不知道如何将每个Split结果赋值给数组。

秋枫

dim arr()
arr=split(xxxx) 就可以了。

半百

IVYQQQQQ 发表于 2017-3-14 13:07
分列当然可以，但是我想要的是用Split函数分行拆分写进数组（这个数组范围是B1:C13）,不要每行都是arr,我 ...

Sub TEST()
ARR = [A1].CurrentRegion.Resize(, 3)
For I = 1 To UBound(ARR)
ARR(I, 2) = Split(ARR(I, 1), "/")(0)’如果有更多列的话，也可以循环
ARR(I, 3) = Split(ARR(I, 1), "/")(1)
Next
[A1].Resize(UBound(ARR), 3) = ARR
End Sub

zax010

Sub zz()
    Dim ar, br
    ar = Range("A1:A" & [a65536].End(3).Row)
    ReDim br(1 To UBound(ar), 1 To 2)
    For i = 1 To UBound(ar)
        s = Split(ar(i, 1), "/")
        br(i, 1) = s(0): br(i, 2) = s(1)
    Next
    [b1].Resize(UBound(br), 2) = br
End Sub