把B列大于0的数字连续出现大于9个小于21个的，在对应的C列位置分别显示5，谢谢！

hcm19522

=IF(B2,TEXT(MIN(--TEXT(MATCH(,0/(B3:B$32=0),)+ROW()-LOOKUP(1,0/(B$2:B2=0),ROW(B$2:B2))-11,"[<11]5!0;!0;!0"),5),"0;!0"),)
連續 10~20
請教大師們  ,以 TEXT 可簡化 ?

丢丢表格

hcm19522 发表于 2016-12-12 15:26
=IF(B2,TEXT(MIN(--TEXT(MATCH(,0/(B3:B$32=0),)+ROW()-LOOKUP(1,0/(B$2:B2=0),ROW(B$2:B2))-11,"[

判断是否范围内值时，还是用减均值 平方法好 ，
如 取 11~21 值时  =（A1-16）^2<26

hcm19522

丢丢表格 发表于 2016-12-12 16:44
判断是否范围内值时，还是用减均值 平方法好 ，
如 取 11~21 值时  =（A1-16）^2

謝謝指教 只是想了解 TEXT(~,"[?];[?]") 含意

AmoKat

hcm19522 发表于 2016-12-12 17:02
謝謝指教 只是想了解 TEXT(~,"[?];[?]") 含意

=TEXT(A1,"[>21]!0;[>9]!5;!0")

10~20 之間的數字會以 "5" 顯示。其他為 "0"

先判斷第1個 [>21] 是否成立，
    是，= "0"
    否，再判斷第2個 [>9] 是否成立，
        是，= "5"

AmoKat

hcm19522 发表于 2016-12-12 17:02
謝謝指教 只是想了解 TEXT(~,"[?];[?]") 含意

TEXT(..., "[>21]!0;[>9]!5;!0") 範例參考

C2:C30 範圍陣列(組數)

=IF(B2:B30,LOOKUP(ROW(2:30),ROW(2:30)/(B1:B29=0),TEXT(FREQUENCY(-ROW(2:30),-ROW(1:30)*(B$1:B$30=0))-1,"[>21]!0;[>9]!5;!0")),)

q8254733

我来个简单思路的，C2单元格：
=IF(AND(C1=5,A2<>0),5,IF(AND(COUNTIF(A2:A11,">0")>9,COUNTIF(A2:A22,">0")<21),5,0))

TTZXX2016

丢丢表格 发表于 2016-12-12 12:03
信息收到：

C2

实在是不好意思老麻烦老师了，但是这个问题没人来帮我解决，老师您看看能不能帮我写个公式？
http://club.excelhome.net/thread-1317399-1-1.html

TTZXX2016

q8254733 发表于 2016-12-13 14:20
我来个简单思路的，C2单元格：
=IF(AND(C1=5,A20),5,IF(AND(COUNTIF(A2:A11,">0")>9,COUNTIF(A2:A22,">0")

非常非常感谢老师，公式非常好用，鲜花明天为您献上。